git.sur5r.net Git - cc65/blob - libsrc/c64/joy/c64-numpad.s

   1 ;
   2 ; Joystick driver using C128 number pad in 64 mode.
   3 ; May be used multiple times when linked to the statically application.
   4 ;
   5 ; Stefan Haubenthal, 2004-01-26
   6 ; Based on Ullrich von Bassewitz, 2002-12-20
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "c64.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "HEADER"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Library reference
  29
  30         .addr   $0000
  31
  32 ; Button state masks (8 values)
  33
  34         .byte   $02                     ; JOY_UP        "8"
  35         .byte   $10                     ; JOY_DOWN      "2"
  36         .byte   $20                     ; JOY_LEFT      "4"
  37         .byte   $08                     ; JOY_RIGHT     "6"
  38         .byte   $04                     ; JOY_FIRE      "5" ENTER
  39         .byte   $00                     ; JOY_FIRE2 unavailable
  40         .byte   $00                     ; Future expansion
  41         .byte   $00                     ; Future expansion
  42
  43 ; Jump table.
  44
  45         .addr   INSTALL
  46         .addr   UNINSTALL
  47         .addr   COUNT
  48         .addr   READ
  49         .addr   0                       ; IRQ entry unused
  50
  51 ; ------------------------------------------------------------------------
  52 ; Constants
  53
  54 JOY_COUNT       = 1             ; Number of joysticks we support
  55
  56
  57 ; ------------------------------------------------------------------------
  58 ; Data.
  59
  60
  61 .code
  62
  63 ; ------------------------------------------------------------------------
  64 ; INSTALL routine. Is called after the driver is loaded into memory. If
  65 ; possible, check if the hardware is present and determine the amount of
  66 ; memory available.
  67 ; Must return an JOY_ERR_xx code in a/x.
  68 ;
  69
  70 INSTALL:
  71         lda     #JOY_ERR_OK             ; Assume we have a joystick
  72         ldx     VIC_CLK_128             ; Test for a C128
  73         cpx     #$FF
  74         bne     @C128                   ; Jump if we have one
  75         lda     #JOY_ERR_NO_DEVICE      ; No C128 -> no numpad
  76 @C128:  ldx     #0                      ; Set high byte
  77
  78 ;       rts                     ; Run into UNINSTALL instead
  79
  80 ; ------------------------------------------------------------------------
  81 ; UNINSTALL routine. Is called before the driver is removed from memory.
  82 ; Can do cleanup or whatever. Must not return anything.
  83 ;
  84
  85 UNINSTALL:
  86         rts
  87
  88
  89 ; ------------------------------------------------------------------------
  90 ; COUNT: Return the total number of available joysticks in a/x.
  91 ;
  92
  93 COUNT:  lda     #JOY_COUNT
  94         ldx     #0
  95         rts
  96
  97 ; ------------------------------------------------------------------------
  98 ; READ: Read a particular joystick passed in A.
  99 ;
 100
 101 READ:   tax                     ; Clear high byte
 102         lda     #$FD
 103         ldy     #$FE
 104         sei
 105         sta     VIC_KBD_128
 106         lda     CIA1_PRB
 107         and     #%00110000
 108         eor     #%00110000
 109         lsr
 110         lsr
 111         sty     VIC_KBD_128
 112         eor     CIA1_PRB
 113         iny
 114         sty     VIC_KBD_128     ; Reset to $FF
 115         cli
 116         and     #%11111110
 117         eor     #%11111110
 118         rts
 119