git.sur5r.net Git - cc65/blob - libsrc/c64/joy/c64-stdjoy.s

   1 ;
   2 ; Standard joystick driver for the C64. May be used multiple times when linked
   3 ; to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2002-12-20
   6 ;
   7
   8         .include        "zeropage.inc"
   9
  10         .include        "joy-kernel.inc"
  11         .include        "joy-error.inc"
  12         .include        "c64.inc"
  13
  14         .macpack        generic
  15         .macpack        module
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21         module_header   _c64_stdjoy_joy
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Library reference
  29
  30         .addr   $0000
  31
  32 ; Button state masks (8 values)
  33
  34         .byte   $01                     ; JOY_UP
  35         .byte   $02                     ; JOY_DOWN
  36         .byte   $04                     ; JOY_LEFT
  37         .byte   $08                     ; JOY_RIGHT
  38         .byte   $10                     ; JOY_FIRE
  39         .byte   $00                     ; JOY_FIRE2 unavailable
  40         .byte   $00                     ; Future expansion
  41         .byte   $00                     ; Future expansion
  42
  43 ; Jump table.
  44
  45         .addr   INSTALL
  46         .addr   UNINSTALL
  47         .addr   COUNT
  48         .addr   READ
  49         .addr   0                       ; IRQ entry unused
  50
  51 ; ------------------------------------------------------------------------
  52 ; Constants
  53
  54 JOY_COUNT       = 2             ; Number of joysticks we support
  55
  56
  57 ; ------------------------------------------------------------------------
  58 ; Data.
  59
  60
  61 .code
  62
  63 ; ------------------------------------------------------------------------
  64 ; INSTALL routine. Is called after the driver is loaded into memory. If
  65 ; possible, check if the hardware is present and determine the amount of
  66 ; memory available.
  67 ; Must return an JOY_ERR_xx code in a/x.
  68 ;
  69
  70 INSTALL:
  71         lda     #<JOY_ERR_OK
  72         ldx     #>JOY_ERR_OK
  73
  74 ;       rts                     ; Run into UNINSTALL instead
  75
  76 ; ------------------------------------------------------------------------
  77 ; UNINSTALL routine. Is called before the driver is removed from memory.
  78 ; Can do cleanup or whatever. Must not return anything.
  79 ;
  80
  81 UNINSTALL:
  82         rts
  83
  84
  85 ; ------------------------------------------------------------------------
  86 ; COUNT: Return the total number of available joysticks in a/x.
  87 ;
  88
  89 COUNT:
  90         lda     #<JOY_COUNT
  91         ldx     #>JOY_COUNT
  92         rts
  93
  94 ; ------------------------------------------------------------------------
  95 ; READ: Read a particular joystick passed in A.
  96 ;
  97
  98 READ:   tax                     ; Joystick number into X
  99         bne     joy2
 100
 101 ; Read joystick 1
 102
 103 joy1:   lda     #$7F
 104         sei
 105         sta     CIA1_PRA
 106         lda     CIA1_PRB
 107         cli
 108         and     #$1F
 109         eor     #$1F
 110         rts
 111
 112 ; Read joystick 2
 113
 114 joy2:   ldx     #0
 115         lda     #$E0
 116         ldy     #$FF
 117         sei
 118         sta     CIA1_DDRA
 119         lda     CIA1_PRA
 120         sty     CIA1_DDRA
 121         cli
 122         and     #$1F
 123         eor     #$1F
 124         rts
 125
 126