git.sur5r.net Git - cc65/blob - libsrc/c64/soft80_kclrscr.s

   1
   2         .export         soft80_kclrscr
   3         .import         soft80_kplot
   4         .import         __bgcolor
   5         .importzp       ptr1
   6
   7         .include        "c64.inc"
   8         .include        "soft80.inc"
   9
  10 soft80_kclrscr:
  11
  12         lda     #<soft80_bitmap
  13         sta     ptr1
  14         lda     #>soft80_bitmap
  15         sta     ptr1+1
  16
  17         lda     #$ff
  18
  19         ldx     #$1f
  20 @lp2:
  21         ldy     #0
  22 @lp1:
  23         sta     (ptr1),y
  24         iny
  25         bne     @lp1
  26         inc     ptr1+1
  27         dex
  28         bne     @lp2
  29
  30         ;ldx     #$00
  31 @lp3:
  32         sta     soft80_bitmap+$1e40,x
  33         inx
  34         bne     @lp3
  35
  36 .if SOFT80COLORVOODOO = 1
  37         lda     __bgcolor
  38         jsr     clear           ; clear color ram
  39 .endif
  40
  41         sei
  42         ldy     $01
  43         lda     #$34            ; enable RAM under I/O
  44         sta     $01
  45
  46         lda     CHARCOLOR
  47         and     #$f0
  48         ora     __bgcolor
  49         jsr     clear           ; clear vram
  50
  51         sty     $01
  52         cli
  53
  54         ldx     #0
  55         ldy     #0
  56         clc
  57         jmp     soft80_kplot
  58
  59         ; clear loop for colram and vram
  60 clear:
  61         ;ldx     #$00
  62 @lp1:
  63         sta     soft80_colram,x
  64         sta     soft80_colram+$100,x
  65         sta     soft80_colram+$200,x
  66         sta     soft80_colram+$2e8,x
  67         inx
  68         bne     @lp1
  69         rts
  70
  71