git.sur5r.net Git - cc65/blob - libsrc/c64/soft80_kclrscr.s

   1 ;
   2 ; Groepaz/Hitmen, 12.10.2015
   3 ;
   4 ; lowlevel kclrscr for soft80 implementation
   5 ;
   6
   7         .export         soft80_kclrscr
   8         .import         soft80_kplot
   9         .import         soft80_internal_bgcolor, soft80_internal_cellcolor
  10         .importzp       ptr1
  11
  12         .include        "c64.inc"
  13         .include        "soft80.inc"
  14
  15 soft80_kclrscr:
  16
  17         lda     #<soft80_bitmap
  18         sta     ptr1
  19         lda     #>soft80_bitmap
  20         sta     ptr1+1
  21
  22         lda     #$ff
  23
  24         ldx     #$1f
  25 @lp2:
  26         ldy     #0
  27 @lp1:
  28         sta     (ptr1),y
  29         iny
  30         bne     @lp1
  31         inc     ptr1+1
  32         dex
  33         bne     @lp2
  34
  35         ;ldx     #$00
  36 @lp3:
  37         sta     soft80_bitmap+$1e40,x
  38         inx
  39         bne     @lp3
  40
  41 .if SOFT80COLORVOODOO = 1
  42         lda     soft80_internal_bgcolor
  43         jsr     clear                           ; clear color ram
  44 .endif
  45
  46         sei
  47         ldy     $01
  48         lda     #$34                            ; enable RAM under I/O
  49         sta     $01
  50
  51         lda     soft80_internal_cellcolor
  52         and     #$f0
  53         ora     soft80_internal_bgcolor
  54         jsr     clear                           ; clear vram
  55
  56         sty     $01
  57         cli
  58
  59         ldx     #0
  60         ldy     #0
  61         clc
  62         jmp     soft80_kplot
  63
  64         ; clear loop for colram and vram
  65 clear:
  66         ;ldx     #$00
  67 @lp1:
  68         sta     soft80_colram,x
  69         sta     soft80_colram+$100,x
  70         sta     soft80_colram+$200,x
  71         sta     soft80_colram+$2e8,x
  72         inx
  73         bne     @lp1
  74         rts
  75
  76