git.sur5r.net Git - cc65/blob - libsrc/cbm510/crt0.s

   1 ;
   2 ; Startup code for cc65 (CBM 500 version)
   3 ;
   4 ; This must be the *first* file on the linker command line
   5 ;
   6
   7         .export         _exit
   8         .import         initlib, donelib
   9         .import         push0, _main
  10         .import         __BSS_RUN__, __BSS_SIZE__
  11         .import         irq, nmi
  12         .import         k_irq, k_nmi, k_plot, k_udtim, k_scnkey
  13
  14         .include        "zeropage.inc"
  15         .include        "io.inc"
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Define and export the ZP variables for the CBM510 runtime
  20
  21         .exportzp       sp, sreg, regsave
  22         .exportzp       ptr1, ptr2, ptr3, ptr4
  23         .exportzp       tmp1, tmp2, tmp3, tmp4
  24         .exportzp       regbank, zpspace
  25         .exportzp       vic, sid, IPCcia, cia, acia, tpi1, tpi2
  26         .exportzp       ktab1, ktab2, ktab3, ktab4, time, RecvBuf, SendBuf
  27
  28 .zeropage
  29
  30 zpstart = *
  31 sp:             .res    2       ; Stack pointer
  32 sreg:           .res    2       ; Secondary register/high 16 bit for longs
  33 regsave:        .res    2       ; slot to save/restore (E)AX into
  34 ptr1:           .res    2
  35 ptr2:           .res    2
  36 ptr3:           .res    2
  37 ptr4:           .res    2
  38 tmp1:           .res    1
  39 tmp2:           .res    1
  40 tmp3:           .res    1
  41 tmp4:           .res    1
  42 regbank:        .res    6       ; 6 byte register bank
  43
  44 zpspace = * - zpstart           ; Zero page space allocated
  45
  46 .code
  47
  48 ; ------------------------------------------------------------------------
  49 ; BASIC header and a small BASIC program. Since it is not possible to start
  50 ; programs in other banks using SYS, the BASIC program will write a small
  51 ; machine code program into memory at $100 and start that machine code
  52 ; program. The machine code program will then start the machine language
  53 ; code in bank 0, which will initialize the system by copying stuff from
  54 ; the system bank, and start the application.
  55 ;
  56 ; Here's the basic program that's in the following lines:
  57 ;
  58 ; 10 for i=0 to 4
  59 ; 20 read j
  60 ; 30 poke 256+i,j
  61 ; 40 next i
  62 ; 50 sys 256
  63 ; 60 data 120,169,0,133,0
  64 ;
  65 ; The machine program in the data lines is:
  66 ;
  67 ; sei
  68 ; lda     #$00
  69 ; sta     $00           <-- Switch to bank 0 after this command
  70 ;
  71 ; Initialization is not only complex because of the jumping from one bank
  72 ; into another. but also because we want to save memory, and because of
  73 ; this, we will use the system memory ($00-$3FF) for initialization stuff
  74 ; that is overwritten later.
  75 ;
  76
  77 ; To make things more simple, make the code of this module absolute.
  78
  79         .org    $0001
  80 Head:   .byte   $03,$00,$11,$00,$0a,$00,$81,$20,$49,$b2,$30,$20,$a4,$20,$34,$00
  81         .byte   $19,$00,$14,$00,$87,$20,$4a,$00,$27,$00,$1e,$00,$97,$20,$32,$35
  82         .byte   $36,$aa,$49,$2c,$4a,$00,$2f,$00,$28,$00,$82,$20,$49,$00,$39,$00
  83         .byte   $32,$00,$9e,$20,$32,$35,$36,$00,$4f,$00,$3c,$00,$83,$20,$31,$32
  84         .byte   $30,$2c,$31,$36,$39,$2c,$30,$2c,$31,$33,$33,$2c,$30,$00,$00,$00
  85
  86 ; Since we need some vectors to access stuff in the system bank for our own,
  87 ; we will include them here, starting from $60:
  88
  89         .res    $60-*
  90
  91 vic:            .word   $d800
  92 sid:            .word   $da00
  93 IPCcia:         .word   $db00
  94 cia:            .word   $dc00
  95 acia:           .word   $dd00
  96 tpi1:           .word   $de00
  97 tpi2:           .word   $df00
  98 ktab1:          .word   $eab1
  99 ktab2:          .word   $eb11
 100 ktab3:          .word   $eb71
 101 ktab4:          .word   $ebd1
 102 time:           .dword  $0000
 103 RecvBuf:        .word   $0100           ; RS232 received buffer
 104 SendBuf:        .word   $0200           ; RS232 send buffer
 105
 106
 107 ; The code in the target bank when switching back will be put at the bottom
 108 ; of the stack. We will jump here to switch segments. The range $F2..$FF is
 109 ; not used by any kernal routine.
 110
 111         .res    $F8-*
 112 Back:   ldx     spsave
 113         txs
 114         lda     IndReg
 115         sta     ExecReg
 116
 117 ; The following code is a copy of the code that is poked in the system bank
 118 ; memory by the basic header program, it's only for documentation and not
 119 ; actually used here:
 120
 121         sei
 122         lda     #$01
 123         sta     ExecReg
 124
 125 ; This is the actual starting point of our code after switching banks for
 126 ; startup. Beware: The following code will get overwritten as soon as we
 127 ; use the stack (since it's in page 1)!
 128
 129         tsx
 130         stx     spsave          ; Save the system stackpointer
 131         ldx     #$FF
 132         txs                     ; Set up our own stack
 133
 134 ; Set the interrupt, NMI and other vectors
 135
 136         ldy     #vectable_size
 137 L0:     lda     vectable-1,y
 138         sta     $FF80,y
 139         dey
 140         bne     L0
 141
 142 ; Switch the indirect segment to the system bank
 143
 144         lda     #$0F
 145         sta     IndReg
 146
 147 ; Copy the kernal zero page ($90-$F2) from the system bank
 148
 149         lda     #$90
 150         sta     ptr1
 151         lda     #$00
 152         sta     ptr1+1
 153         ldy     #$62-1
 154 L1:     lda     (ptr1),y
 155         sta     $90,y
 156         dey
 157         bpl     L1
 158
 159 ; Copy the page 3 vectors in place
 160
 161         ldy     #$00
 162 L2:     lda     p3vectable,y
 163         sta     $300,y
 164         iny
 165         cpy     #p3vectable_size
 166         bne     L2
 167
 168 ; Copy the rest of page 3 from the system bank
 169
 170         lda     #$00
 171         sta     ptr1
 172         lda     #$03
 173         sta     ptr1+1
 174 L3:     lda     (ptr1),y
 175         sta     $300,y
 176         iny
 177         bne     L3
 178
 179 ; Set the indirect segment to bank we're executing in
 180
 181         lda     ExecReg
 182         sta     IndReg
 183
 184 ; Zero the BSS segment. We will do that here instead calling the routine
 185 ; in the common library, since we have the memory anyway, and this way,
 186 ; it's reused later.
 187
 188         lda     #<__BSS_RUN__
 189         sta     ptr1
 190         lda     #>__BSS_RUN__
 191         sta     ptr1+1
 192         lda     #0
 193         tay
 194
 195 ; Clear full pages
 196
 197         ldx     #>__BSS_SIZE__
 198         beq     Z2
 199 Z1:     sta     (ptr1),y
 200         iny
 201         bne     Z1
 202         inc     ptr1+1                  ; Next page
 203         dex
 204         bne     Z1
 205
 206 ; Clear the remaining page
 207
 208 Z2:     ldx     #<__BSS_SIZE__
 209         beq     Z4
 210 Z3:     sta     (ptr1),y
 211         iny
 212         dex
 213         bne     Z3
 214 Z4:
 215
 216 ; Setup the C stack
 217
 218         lda     #<$FF81
 219         sta     sp
 220         lda     #>$FF81
 221         sta     sp+1
 222
 223 ; We expect to be in page 2 now
 224
 225 .if     (* < $1FD)
 226         jmp     $200
 227         .res    $200-*
 228 .endif
 229 .if     (* < $200)
 230         .res    $200-*,$EA
 231 .endif
 232 .if     (* >= $2F0)
 233 .error  "Code range invalid"
 234 .endif
 235
 236 ; This code is in page 2, so we may now start calling subroutines safely,
 237 ; since the code we execute is no longer in the stack page.
 238 ; Call module constructors
 239
 240         jsr     initlib
 241
 242 ; Create the (empty) command line for the program
 243
 244         jsr     push0           ; argc
 245         jsr     push0           ; argv
 246
 247 ; Execute the program code
 248
 249         jmp     Start
 250
 251 ; ------------------------------------------------------------------------
 252 ; Additional data that we need for initialization and that's overwritten
 253 ; later
 254
 255 vectable:
 256         jmp     $0000           ; CINT
 257         jmp     $0000           ; IOINIT
 258         jmp     $0000           ; RAMTAS
 259         jmp     $0000           ; RESTOR
 260         jmp     $0000           ; VECTOR
 261         jmp     $0000           ; SETMSG
 262         jmp     $0000           ; SECOND
 263         jmp     $0000           ; TKSA
 264         jmp     $0000           ; MEMTOP
 265         jmp     $0000           ; MEMBOT
 266         jmp     k_scnkey        ; SCNKEY
 267         jmp     $0000           ; SETTMO
 268         jmp     $0000           ; ACPTR
 269         jmp     $0000           ; CIOUT
 270         jmp     $0000           ; UNTLK
 271         jmp     $0000           ; UNLSN
 272         jmp     $0000           ; LISTEN
 273         jmp     $0000           ; TALK
 274         jmp     $0000           ; READST
 275         jmp     k_setlfs        ; SETLFS
 276         jmp     k_setnam        ; SETNAM
 277         jmp     $0000           ; OPEN
 278         jmp     $0000           ; CLOSE
 279         jmp     $0000           ; CHKIN
 280         jmp     $0000           ; CKOUT
 281         jmp     $0000           ; CLRCH
 282         jmp     $0000           ; BASIN
 283         jmp     $0000           ; BSOUT
 284         jmp     $0000           ; LOAD
 285         jmp     $0000           ; SAVE
 286         jmp     k_settim        ; SETTIM
 287         jmp     k_rdtim         ; RDTIM
 288         jmp     $0000           ; STOP
 289         jmp     $0000           ; GETIN
 290         jmp     $0000           ; CLALL
 291         jmp     k_udtim         ; UDTIM
 292         jmp     k_screen        ; SCREEN
 293         jmp     k_plot          ; PLOT
 294         jmp     k_iobase        ; IOBASE
 295         sta     ExecReg
 296         rts
 297         .byte   $01             ; Filler
 298         .word   nmi
 299         .word   0               ; Reset - not used
 300         .word   irq
 301 vectable_size   = * - vectable
 302
 303 p3vectable:
 304         .word   k_irq           ; IRQ user vector
 305         .word   k_brk           ; BRK user vector
 306         .word   k_nmi           ; NMI user vector
 307 p3vectable_size = * - p3vectable
 308
 309
 310 ; ------------------------------------------------------------------------
 311 ; This is the program code after setup. It starts at $400
 312
 313         .res    $400-*
 314
 315 Start:
 316
 317 ; Enable interrupts
 318
 319         cli
 320
 321 ; Call the user code
 322
 323         ldy     #4              ; Argument size
 324         jsr     _main           ; call the users code
 325
 326 ; Call module destructors. This is also the _exit entry.
 327
 328 _exit:  jsr     donelib         ; Run module destructors
 329
 330 ; Clear the start of the zero page, since it will be interpreted as a
 331 ; (garbage) BASIC program otherwise. This is also the default entry for
 332 ; the break vector.
 333
 334 k_brk:  sei
 335         lda     #$00
 336         ldx     #$3E
 337 Clear:  sta     $02,x
 338         dex
 339         bne     Clear
 340
 341 ; Setup the welcome code at the stack bottom in the system bank. Use
 342 ; the F4/F5 vector to access the system bank
 343
 344         lda     #$0F
 345         sta     IndReg
 346         ldy     #$00
 347         sty     $F4
 348         iny
 349         sty     $F5
 350         ldy     #reset_size-1
 351 @L1:    lda     reset,y
 352         sta     ($F4),y
 353         dey
 354         bne     @L1
 355         jmp     Back
 356
 357 ; ------------------------------------------------------------------------
 358 ; Code that is copied into the system bank at $100 when switching back
 359
 360 reset:  cli
 361         jmp     $8000                   ; BASIC cold start
 362 reset_size = * - reset
 363
 364 ; ------------------------------------------------------------------------
 365 ; Code for a few simpler kernal calls goes here
 366
 367 k_iobase:
 368         ldx     cia
 369         ldy     cia+1
 370         rts
 371
 372 k_screen:
 373         ldx     #40             ; Columns
 374         ldy     #25             ; Lines
 375         rts
 376
 377 k_setlfs:
 378         sta     LogicalAdr
 379         stx     FirstAdr
 380         sty     SecondAdr
 381         rts
 382
 383 k_setnam:
 384         sta     FileNameLen
 385         lda     $00,x
 386         sta     FileNameAdrLo
 387         lda     $01,x
 388         sta     FileNameAdrHi
 389         lda     $02,x
 390         sta     FileNameAdrSeg
 391         rts
 392
 393 k_rdtim:
 394         sei
 395         lda     time+0
 396         ldx     time+1
 397         ldy     time+2
 398         cli
 399         rts
 400
 401 k_settim:
 402         sei
 403         sta     time+0
 404         stx     time+1
 405         sty     time+2
 406         cli
 407         rts
 408
 409 ; -------------------------------------------------------------------------
 410 ; Data area - switch back to relocatable mode
 411
 412         .reloc
 413
 414 .data
 415 spsave: .res    1
 416
 417
 418