git.sur5r.net Git - cc65/blob - libsrc/cbm510/joy/cbm510-std.s

   1 ;
   2 ; Standard joystick driver for the Commodore 510 (aka P500). May be used
   3 ; multiple times when linked to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2003-02-16
   6 ;
   7
   8         .include        "zeropage.inc"
   9         .include        "../extzp.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "cbm510.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "HEADER"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Library reference
  29
  30         .addr   $0000
  31
  32 ; Button state masks (8 values)
  33
  34         .byte   $01                     ; JOY_UP
  35         .byte   $02                     ; JOY_DOWN
  36         .byte   $04                     ; JOY_LEFT
  37         .byte   $08                     ; JOY_RIGHT
  38         .byte   $10                     ; JOY_FIRE
  39         .byte   $00                     ; JOY_FIRE2 unavailable
  40         .byte   $00                     ; Future expansion
  41         .byte   $00                     ; Future expansion
  42
  43 ; Jump table.
  44
  45         .addr   INSTALL
  46         .addr   UNINSTALL
  47         .addr   COUNT
  48         .addr   READ
  49         .addr   0                       ; IRQ entry unused
  50
  51 ; ------------------------------------------------------------------------
  52 ; Constants
  53
  54 JOY_COUNT       = 2             ; Number of joysticks we support
  55
  56
  57 ; ------------------------------------------------------------------------
  58 ; Data.
  59
  60
  61 .code
  62
  63 ; ------------------------------------------------------------------------
  64 ; INSTALL routine. Is called after the driver is loaded into memory. If
  65 ; possible, check if the hardware is present and determine the amount of
  66 ; memory available.
  67 ; Must return an JOY_ERR_xx code in a/x.
  68 ;
  69
  70 INSTALL:
  71         lda     #<JOY_ERR_OK
  72         ldx     #>JOY_ERR_OK
  73 ;       rts                     ; Run into UNINSTALL instead
  74
  75 ; ------------------------------------------------------------------------
  76 ; UNINSTALL routine. Is called before the driver is removed from memory.
  77 ; Can do cleanup or whatever. Must not return anything.
  78 ;
  79
  80 UNINSTALL:
  81         rts
  82
  83
  84 ; ------------------------------------------------------------------------
  85 ; COUNT: Return the total number of available joysticks in a/x.
  86 ;
  87
  88 COUNT:
  89         lda     #<JOY_COUNT
  90         ldx     #>JOY_COUNT
  91         rts
  92
  93 ; ------------------------------------------------------------------------
  94 ; READ: Read a particular joystick passed in A.
  95 ;
  96
  97 READ:   ldx     #$0F            ; Switch to the system bank
  98         stx     IndReg
  99         tax                     ; Save joystick number
 100
 101 ; Get the direction bits
 102
 103         ldy     #CIA::PRB
 104         lda     (cia2),y        ; Read joystick inputs
 105         sta     tmp1
 106
 107 ; Get the fire bits
 108
 109         ldy     #CIA::PRA
 110         lda     (cia2),y
 111
 112 ; Make the result value
 113
 114         cpx     #$00            ; Joystick 0?
 115         bne     @L1             ; Jump if no
 116
 117 ; Joystick 1, fire is in bit 6, direction in bit 0-3
 118
 119         asl     a
 120         jmp     @L2
 121
 122 ; Joystick 2, fire is in bit 7, direction in bit 5-7
 123
 124 @L1:    ldx     #$00            ; High byte of return value
 125         lsr     tmp1
 126         lsr     tmp1
 127         lsr     tmp1
 128         lsr     tmp1
 129
 130 ; Mask the relavant bits, get the fire bit
 131
 132 @L2:    asl     a               ; Fire bit into carry
 133         lda     tmp1
 134         and     #$0F
 135         bcc     @L3
 136         ora     #$10
 137 @L3:    eor     #$1F            ; All bits are inverted
 138
 139 ; Switch back to the execution bank and return the joystick mask in a/x
 140
 141         ldy     ExecReg
 142         sty     IndReg
 143         rts
 144