git.sur5r.net Git - cc65/blob - libsrc/joystick/joy-kernel.s

   1 ;
   2 ; Ullrich von Bassewitz, 2002-12-20
   3 ;
   4 ; Common functions of the joystick API.
   5 ;
   6
   7         .export         _joy_install, _joy_uninstall, _joy_masks
   8         .export         joy_clear_ptr
   9
  10         .importzp       ptr1
  11
  12         .include        "joy-kernel.inc"
  13         .include        "joy-error.inc"
  14
  15
  16 ;----------------------------------------------------------------------------
  17 ; Variables
  18
  19
  20 .bss
  21 _joy_drv:       .res    2               ; Pointer to driver
  22
  23 _joy_masks:     .res    .sizeof(JOY_HDR::MASKS)
  24
  25 ; Jump table for the driver functions.
  26 .data
  27 joy_vectors:
  28 joy_install:    jmp     $0000
  29 joy_uninstall:  jmp     $0000
  30 joy_count:      jmp     $0000
  31 joy_read:       jmp     $0000
  32
  33 ; Driver header signature
  34 .rodata
  35 joy_sig:        .byte   $6A, $6F, $79, JOY_API_VERSION  ; "joy", version
  36
  37
  38 ;----------------------------------------------------------------------------
  39 ; unsigned char __fastcall__ joy_install (void* driver);
  40 ; /* Install the driver once it is loaded */
  41
  42
  43 _joy_install:
  44         sta     _joy_drv
  45         sta     ptr1
  46         stx     _joy_drv+1
  47         stx     ptr1+1
  48
  49 ; Check the driver signature
  50
  51         ldy     #.sizeof(joy_sig)-1
  52 @L0:    lda     (ptr1),y
  53         cmp     joy_sig,y
  54         bne     inv_drv
  55         dey
  56         bpl     @L0
  57
  58 ; Copy the mask array
  59
  60         ldy     #JOY_HDR::MASKS + .sizeof(JOY_HDR::MASKS) - 1
  61         ldx     #.sizeof(JOY_HDR::MASKS)-1
  62 @L1:    lda     (ptr1),y
  63         sta     _joy_masks,x
  64         dey
  65         dex
  66         bpl     @L1
  67
  68 ; Copy the jump vectors
  69
  70         ldy     #JOY_HDR::JUMPTAB
  71         ldx     #0
  72 @L2:    inx                             ; Skip the JMP opcode
  73         jsr     copy                    ; Copy one byte
  74         jsr     copy                    ; Copy one byte
  75         cpy     #(JOY_HDR::JUMPTAB + .sizeof(JOY_HDR::JUMPTAB))
  76         bne     @L2
  77
  78         jmp     joy_install             ; Call driver install routine
  79
  80 ; Driver signature invalid
  81
  82 inv_drv:
  83         lda     #JOY_ERR_INV_DRIVER
  84         ldx     #0
  85         rts
  86
  87 ; Copy one byte from the jump vectors
  88
  89 copy:   lda     (ptr1),y
  90         iny
  91 set:    sta     joy_vectors,x
  92         inx
  93         rts
  94
  95 ;----------------------------------------------------------------------------
  96 ; unsigned char __fastcall__ joy_uninstall (void);
  97 ; /* Uninstall the currently loaded driver. Note: This call does not free
  98 ;  * allocated memory.
  99 ;  */
 100
 101 _joy_uninstall:
 102         jsr     joy_uninstall           ; Call the driver routine
 103
 104 joy_clear_ptr:                          ; External entry point
 105         lda     #0
 106         sta     _joy_drv
 107         sta     _joy_drv+1              ; Clear the driver pointer
 108
 109         tax                             ; Return zero
 110         rts
 111