git.sur5r.net Git - cc65/blob - libsrc/plus4/plus4-stdjoy.s

   1 ;
   2 ; Standard joystick driver for the Plus/4. May be used multiple times when linked
   3 ; to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2002-12-21
   6 ;
   7
   8         .include        "zeropage.inc"
   9
  10         .include        "joy-kernel.inc"
  11         .include        "joy-error.inc"
  12         .include        "../plus4/plus4.inc"
  13
  14         .macpack        generic
  15
  16
  17 ; ------------------------------------------------------------------------
  18 ; Header. Includes jump table
  19
  20 .segment        "JUMPTABLE"
  21
  22 ; Driver signature
  23
  24         .byte   $6A, $6F, $79           ; "joy"
  25         .byte   $00                     ; Driver API version number
  26
  27 ; Button state masks (8 values)
  28
  29         .byte   $01                     ; JOY_UP
  30         .byte   $02                     ; JOY_DOWN
  31         .byte   $04                     ; JOY_LEFT
  32         .byte   $08                     ; JOY_RIGHT
  33         .byte   $10                     ; JOY_FIRE
  34         .byte   $00                     ; Future expansion
  35         .byte   $00                     ; Future expansion
  36         .byte   $00                     ; Future expansion
  37
  38 ; Jump table.
  39
  40         .word   INSTALL
  41         .word   UNINSTALL
  42         .word   COUNT
  43         .word   READ
  44
  45 ; ------------------------------------------------------------------------
  46 ; Constants
  47
  48 JOY_COUNT       = 2             ; Number of joysticks we support
  49
  50
  51 ; ------------------------------------------------------------------------
  52 ; Data.
  53
  54
  55 .code
  56
  57 ; ------------------------------------------------------------------------
  58 ; INSTALL routine. Is called after the driver is loaded into memory. If
  59 ; possible, check if the hardware is present and determine the amount of
  60 ; memory available.
  61 ; Must return an JOY_ERR_xx code in a/x.
  62 ;
  63
  64 INSTALL:
  65         lda     #<JOY_ERR_OK
  66         ldx     #>JOY_ERR_OK
  67
  68 ;       rts                     ; Run into DEINSTALL instead
  69
  70 ; ------------------------------------------------------------------------
  71 ; UNINSTALL routine. Is called before the driver is removed from memory.
  72 ; Can do cleanup or whatever. Must not return anything.
  73 ;
  74
  75 UNINSTALL:
  76         rts
  77
  78
  79 ; ------------------------------------------------------------------------
  80 ; COUNT: Return the total number of available joysticks in a/x.
  81 ;
  82
  83 COUNT:
  84         lda     #<JOY_COUNT
  85         ldx     #>JOY_COUNT
  86         rts
  87
  88 ; ------------------------------------------------------------------------
  89 ; READ: Read a particular joystick passed in A.
  90 ;
  91
  92 READ:   ldy     #$FA            ; Load index for joystick #1
  93         tax                     ; Test joystick number
  94         beq     @L1
  95         ldy     #$FB            ; Load index for joystick #2
  96 @L1:    sei
  97         sty     TED_KBD
  98         lda     TED_KBD
  99         cli
 100         ldx     #$00            ; Clear high byte
 101         and     #$1F
 102         eor     #$1F
 103         rts
 104