git.sur5r.net Git - cc65/blob - libsrc/tgi/tgi-kernel.s

   1 ;
   2 ; Ullrich von Bassewitz, 21.06.2002
   3 ;
   4 ; Common functions of the tgi graphics kernel.
   5 ;
   6
   7         .include        "tgi-kernel.inc"
   8         .include        "tgi-error.inc"
   9
  10         .export         _tgi_setup
  11         .importzp       ptr1
  12
  13
  14 ;----------------------------------------------------------------------------
  15 ; Variables
  16
  17 .bss
  18
  19 _tgi_drv:           .res    2           ; Pointer to driver
  20 _tgi_error:         .res    1           ; Last error code
  21 _tgi_mode:          .res    1           ; Graphics mode or zero
  22 _tgi_curx:          .res    2           ; Current drawing cursor X
  23 _tgi_cury:          .res    2           ; Current drawing cursor Y
  24 _tgi_color:         .res    1           ; Current drawing color
  25 _tgi_textdir:       .res    1           ; Current text direction
  26 _tgi_textmagx:      .res    1           ; Text magnification in X dir
  27 _tgi_textmagy:      .res    1           ; Text magnification in Y dir
  28
  29 ; The following variables are copied from the driver header for faster access
  30 tgi_driver_vars:
  31 _tgi_xres:          .res    2           ; X resolution of the current mode
  32 _tgi_yres:          .res    2           ; Y resolution of the current mode
  33 _tgi_colorcount:    .res    1           ; Number of available colors
  34 _tgi_pagecount:     .res    1           ; Number of available screen pages
  35 _tgi_fontsizex:     .res    1           ; System font X size
  36 _tgi_fontsizey:     .res    1           ; System font Y size
  37 tgi_driver_var_size     = * - tgi_driver_vars
  38
  39
  40 .data
  41
  42 ; Jump table for the driver functions.
  43
  44 tgi_install:        jmp     $0000
  45 tgi_deinstall:      jmp     $0000
  46 tgi_init:           jmp     $0000
  47 tgi_done:           jmp     $0000
  48 tgi_geterror:       jmp     $0000
  49 tgi_control:        jmp     $0000
  50 tgi_clear:          jmp     $0000
  51 tgi_setviewpage:    jmp     $0000
  52 tgi_setdrawpage:    jmp     $0000
  53 tgi_setcolor:       jmp     $0000
  54 tgi_setpalette:     jmp     $0000
  55 tgi_getpalette:     jmp     $0000
  56 tgi_getdefpalette:  jmp     $0000
  57 tgi_setpixel:       jmp     $0000
  58 tgi_getpixel:       jmp     $0000
  59 tgi_horline:        jmp     $0000
  60 tgi_line:           jmp     $0000
  61 tgi_bar:            jmp     $0000
  62 tgi_circle:         jmp     $0000
  63 tgi_textstyle:      jmp     $0000
  64 tgi_outtext:        jmp     $0000
  65
  66
  67 ;----------------------------------------------------------------------------
  68 ; void __fastcall__ tgi_setup (void);
  69 ; /* Setup the driver and graphics kernel once the driver is loaded */
  70
  71
  72 copy:   lda     (ptr1),y
  73         sta     tgi_install,x
  74         iny
  75         inx
  76         rts
  77
  78
  79 _tgi_setup:
  80         jsr     tgi_set_ptr             ; load _tgi_drv into ptr1
  81
  82 ; Copy the jump vectors
  83
  84         ldy     #TGI_HDR_JUMPTAB
  85         ldx     #0
  86 @L1:    inx                             ; Skip JMP opcode
  87         jsr     copy                    ; Copy one byte
  88         jsr     copy                    ; Copy one byte
  89         cpx     #(TGI_HDR_JUMPCOUNT*3)
  90         bne     @L1
  91
  92 ; Check for emulation vectors needed
  93
  94         lda     tgi_bar+1
  95         ora     tgi_bar+2               ; Do we have a BAR vector?
  96         bne     @L2                     ; Jump if yes
  97         lda     #<tgi_emu_bar           ; Use emulation if no
  98         sta     tgi_bar+1
  99         lda     #>tgi_emu_bar
 100         sta     tgi_bar+2
 101
 102 @L2:    lda     ptr1
 103         pha
 104         lda     ptr1+1
 105         pha
 106         jsr     tgi_install             ; Call driver install routine
 107         pla                             ; (may update variables)
 108         sta     ptr1+1                  ; (may modify ptr1 so it is preserved)
 109         pla
 110         sta     ptr1
 111
 112 ; Copy variables. Beware: We are using internal knowledge about variable
 113 ; layout here!
 114
 115         ldy     #TGI_HDR_XRES
 116         ldx     #0
 117 @L3:    lda     (ptr1),y
 118         sta     tgi_driver_vars,x
 119         iny
 120         inx
 121         cpx     #tgi_driver_var_size
 122         bne     @L3
 123
 124 ; Initialize variables
 125
 126         lda     #$00
 127         ldx     #7-1
 128 @L4:    sta     _tgi_error,x            ; Clear error/mode/curx/cury/textdir
 129         dex
 130         bpl     @L4
 131
 132         rts
 133
 134 ;----------------------------------------------------------------------------
 135 ; Load the pointer to the tgi driver into ptr1.
 136
 137 tgi_set_ptr:
 138         lda     _tgi_drv
 139         sta     ptr1
 140         lda     _tgi_drv+1
 141         sta     ptr1+1
 142         rts
 143
 144 ;----------------------------------------------------------------------------
 145 ; Set an invalid argument error
 146
 147 tgi_inv_arg:
 148         lda     #TGI_ERR_INV_ARG
 149         sta     _tgi_error
 150         rts
 151