git.sur5r.net Git - cc65/blob - libsrc/tgi/tgi-kernel.s

   1 ;
   2 ; Ullrich von Bassewitz, 21.06.2002
   3 ;
   4 ; Common functions of the tgi graphics kernel.
   5 ;
   6
   7         .include        "tgi-kernel.inc"
   8         .include        "tgi-error.inc"
   9
  10         .export         tgi_clear_ptr
  11         .importzp       ptr1
  12
  13
  14 ;----------------------------------------------------------------------------
  15 ; Variables
  16
  17 .bss
  18
  19 _tgi_drv:           .res    2           ; Pointer to driver
  20 _tgi_error:         .res    1           ; Last error code
  21 _tgi_gmode:         .res    1           ; Flag: Graphics mode active
  22 _tgi_curx:          .res    2           ; Current drawing cursor X
  23 _tgi_cury:          .res    2           ; Current drawing cursor Y
  24 _tgi_color:         .res    1           ; Current drawing color
  25 _tgi_textdir:       .res    1           ; Current text direction
  26 _tgi_textmagx:      .res    1           ; Text magnification in X dir
  27 _tgi_textmagy:      .res    1           ; Text magnification in Y dir
  28
  29 ; The following variables are copied from the driver header for faster access
  30 tgi_driver_vars:
  31 _tgi_xres:          .res    2           ; X resolution of the current mode
  32 _tgi_yres:          .res    2           ; Y resolution of the current mode
  33 _tgi_colorcount:    .res    1           ; Number of available colors
  34 _tgi_pagecount:     .res    1           ; Number of available screen pages
  35 _tgi_fontsizex:     .res    1           ; System font X size
  36 _tgi_fontsizey:     .res    1           ; System font Y size
  37 tgi_driver_var_size     = * - tgi_driver_vars
  38
  39
  40 .data
  41
  42 ; Jump table for the driver functions.
  43
  44 tgi_install:        jmp     $0000
  45 tgi_uninstall:      jmp     $0000
  46 tgi_init:           jmp     $0000
  47 tgi_done:           jmp     $0000
  48 tgi_geterror:       jmp     $0000
  49 tgi_control:        jmp     $0000
  50 tgi_clear:          jmp     $0000
  51 tgi_setviewpage:    jmp     $0000
  52 tgi_setdrawpage:    jmp     $0000
  53 tgi_setcolor:       jmp     $0000
  54 tgi_setpalette:     jmp     $0000
  55 tgi_getpalette:     jmp     $0000
  56 tgi_getdefpalette:  jmp     $0000
  57 tgi_setpixel:       jmp     $0000
  58 tgi_getpixel:       jmp     $0000
  59 tgi_line:           jmp     $0000
  60 tgi_bar:            jmp     $0000
  61 tgi_circle:         jmp     $0000
  62 tgi_textstyle:      jmp     $0000
  63 tgi_outtext:        jmp     $0000
  64
  65 ; Driver header signature
  66 .rodata
  67 tgi_sig:        .byte   $74, $67, $69, TGI_API_VERSION  ; "tgi", version
  68 tgi_sig_len     = * - tgi_sig
  69
  70
  71 ;----------------------------------------------------------------------------
  72 ; void __fastcall__ tgi_install (void* driver);
  73 ; /* Install an already loaded driver. */
  74
  75
  76 _tgi_install:
  77         sta     _tgi_drv
  78         sta     ptr1
  79         stx     _tgi_drv+1
  80         stx     ptr1+1
  81
  82 ; Check the driver signature
  83
  84         ldy     #tgi_sig_len-1
  85 @L0:    lda     (ptr1),y
  86         cmp     tgi_sig,y
  87         bne     tgi_inv_drv
  88         dey
  89         bpl     @L0
  90
  91 ; Copy the jump vectors
  92
  93         ldy     #TGI_HDR_JUMPTAB
  94         ldx     #0
  95 @L1:    inx                             ; Skip JMP opcode
  96         jsr     copy                    ; Copy one byte
  97         jsr     copy                    ; Copy one byte
  98         cpx     #(TGI_HDR_JUMPCOUNT*3)
  99         bne     @L1
 100
 101 ; Call the driver install routine
 102
 103         jsr     tgi_install             ; Call driver install routine, may...
 104                                         ; ...update variables
 105         jsr     tgi_set_ptr             ; Set ptr1 to tgi_drv
 106
 107 ; Copy variables. Beware: We are using internal knowledge about variable
 108 ; layout here!
 109
 110         ldy     #TGI_HDR_XRES
 111         ldx     #0
 112 @L3:    lda     (ptr1),y
 113         sta     tgi_driver_vars,x
 114         iny
 115         inx
 116         cpx     #tgi_driver_var_size
 117         bne     @L3
 118
 119 ; Initialize variables
 120
 121         lda     #$00
 122         ldx     #7-1
 123 @L4:    sta     _tgi_error,x            ; Clear error/mode/curx/cury/textdir
 124         dex
 125         bpl     @L4
 126
 127         rts
 128
 129 ; Copy one byte from the jump vectors
 130
 131 copy:   lda     (ptr1),y
 132         sta     tgi_install,x
 133         iny
 134         inx
 135         rts
 136
 137 ;----------------------------------------------------------------------------
 138 ; Set an invalid argument error
 139
 140 tgi_inv_arg:
 141         lda     #TGI_ERR_INV_ARG
 142         sta     _tgi_error
 143         rts
 144
 145 ;----------------------------------------------------------------------------
 146 ; Set an invalid driver error
 147
 148 tgi_inv_drv:
 149         lda     #TGI_ERR_INV_DRIVER
 150         sta     _tgi_error
 151         rts
 152
 153 ;----------------------------------------------------------------------------
 154 ; Load the pointer to the tgi driver into ptr1.
 155
 156 tgi_set_ptr:
 157         lda     _tgi_drv
 158         sta     ptr1
 159         lda     _tgi_drv+1
 160         sta     ptr1+1
 161         rts
 162
 163 ;----------------------------------------------------------------------------
 164 ; void __fastcall__ tgi_uninstall (void);
 165 ; /* Uninstall the currently loaded driver but do not unload it. Will call
 166 ;  * tgi_done if necessary.
 167 ;  */
 168
 169 _tgi_uninstall:
 170         jsr     _tgi_done               ; Switch off graphics
 171         jsr     tgi_uninstall           ; Allow the driver to clean up
 172
 173 ; Clear driver pointer and error code
 174
 175 tgi_clear_ptr:                          ; External entry point
 176         lda     #$00
 177         sta     _tgi_drv
 178         sta     _tgi_drv+1
 179         sta     _tgi_error
 180
 181         rts
 182
 183