git.sur5r.net Git - minitube/blob - locale/locale.pri

   1 # This voodoo comes from the Arora project
   2
   3 INCLUDEPATH += $$PWD
   4 DEPENDPATH += $$PWD
   5
   6 TRANSLATIONS += \
   7     it_IT.ts \
   8     pt_BR.ts \
   9     ru_RU.ts \
  10     es_AR.ts \
  11     es_ES.ts \
  12     pl_PL.ts \
  13     de_DE.ts \
  14     ja_JP.ts \
  15     cs_CZ.ts \
  16     uk.ts \
  17     he_IL.ts \
  18     lat.ts \
  19     hr_HR.ts \
  20     es.ts \
  21     gl.ts \
  22     fr_FR.ts \
  23     hu_HU.ts \
  24     tr_TR.ts \
  25     nb_NO.ts
  26
  27 isEmpty(QMAKE_LRELEASE) {
  28     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
  29     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
  30 }
  31
  32 updateqm.input = TRANSLATIONS
  33 updateqm.output = build/target/locale/${QMAKE_FILE_BASE}.qm
  34 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm build/target/locale/${QMAKE_FILE_BASE}.qm
  35 updateqm.CONFIG += no_link target_predeps
  36 QMAKE_EXTRA_COMPILERS += updateqm
  37
  38 #qmfiles.files = TRANSLATIONS
  39 #qmfiles.path = Content/Resources
  40 #QMAKE_BUNDLE_DATA += qmfiles