git.sur5r.net Git - minitube/blob - minitube.pro

   1 # On some distro, Phonon headers cannot be found
   2 INCLUDEPATH += /usr/include/phonon
   3 CONFIG += release
   4 TEMPLATE = app
   5
   6 # Saner string behaviour
   7 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   8 TARGET = minitube
   9 mac {
  10     TARGET = Minitube
  11     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  12 }
  13 QT += network \
  14     xml \
  15     phonon
  16 include(src/qtsingleapplication/qtsingleapplication.pri)
  17 include(src/thlibrary/thlibrary.pri)
  18 HEADERS += src/MainWindow.h \
  19     src/SearchView.h \
  20     src/MediaView.h \
  21     src/SettingsView.h \
  22     src/AboutView.h \
  23     src/youtubesearch.h \
  24     src/video.h \
  25     src/youtubestreamreader.h \
  26     src/View.h \
  27     src/searchlineedit.h \
  28     src/urllineedit.h \
  29     src/spacer.h \
  30     src/Constants.h \
  31     src/iconloader/qticonloader.h \
  32     src/faderwidget/FaderWidget.h \
  33     src/ListModel.h \
  34     src/playlist/PrettyItemDelegate.h \
  35     src/networkaccess.h \
  36     src/videomimedata.h \
  37     src/global.h \
  38     src/updatechecker.h \
  39     src/playlistwidget.h \
  40     src/searchparams.h \
  41     src/minisplitter.h \
  42     src/loadingwidget.h \
  43     src/videoareawidget.h \
  44     src/googlesuggest.h
  45 SOURCES += src/main.cpp \
  46     src/MainWindow.cpp \
  47     src/SearchView.cpp \
  48     src/MediaView.cpp \
  49     src/SettingsView.cpp \
  50     src/AboutView.cpp \
  51     src/youtubesearch.cpp \
  52     src/youtubestreamreader.cpp \
  53     src/searchlineedit.cpp \
  54     src/urllineedit.cpp \
  55     src/spacer.cpp \
  56     src/video.cpp \
  57     src/iconloader/qticonloader.cpp \
  58     src/faderwidget/FaderWidget.cpp \
  59     src/ListModel.cpp \
  60     src/playlist/PrettyItemDelegate.cpp \
  61     src/videomimedata.cpp \
  62     src/updatechecker.cpp \
  63     src/networkaccess.cpp \
  64     src/playlistwidget.cpp \
  65     src/searchparams.cpp \
  66     src/minisplitter.cpp \
  67     src/loadingwidget.cpp \
  68     src/videoareawidget.cpp \
  69     src/googlesuggest.cpp
  70 RESOURCES += resources.qrc
  71 DESTDIR = build/target/
  72 OBJECTS_DIR = build/obj/
  73 MOC_DIR = build/moc/
  74 RCC_DIR = build/rcc/
  75
  76 # Tell Qt Linguist that we use UTF-8 strings in our sources
  77 CODECFORTR = UTF-8
  78 CODECFORSRC = UTF-8
  79 include(locale/locale.pri)
  80
  81 # deploy
  82 DISTFILES += CHANGES \
  83     LICENSE
  84 mac {
  85     CONFIG += x86 \
  86         ppc
  87     QMAKE_INFO_PLIST = Info.plist
  88     ICON = minitube.icns
  89 }
  90 unix {
  91     isEmpty(PREFIX):PREFIX = /usr/local
  92     BINDIR = $$PREFIX/bin
  93     INSTALLS += target
  94     target.path = $$BINDIR
  95     DATADIR = $$PREFIX/share
  96     PKGDATADIR = $$DATADIR/minitube
  97     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  98         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  99     INSTALLS += translations \
 100         desktop \
 101         iconsvg \
 102         icon16 \
 103         icon32 \
 104         icon128
 105     translations.path = $$PKGDATADIR
 106     translations.files += $$DESTDIR/locale
 107     desktop.path = $$DATADIR/applications
 108     desktop.files += minitube.desktop
 109
 110     # iconxpm.path = $$DATADIR/pixmaps
 111     # iconxpm.files += data/minitube.xpm
 112     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 113     iconsvg.files += data/minitube.svg
 114     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 115     icon16.files += data/16x16/minitube.png
 116     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 117     icon32.files += data/32x32/minitube.png
 118     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 119     icon128.files += data/128x128/minitube.png
 120 }