git.sur5r.net Git - minitube/blob - minitube.pro

   1 INCLUDEPATH += /usr/include/phonon
   2 CONFIG += release
   3 TEMPLATE = app
   4
   5 # TODO Saner string behaviour
   6 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   7 TARGET = minitube
   8 mac {
   9     TARGET = Minitube
  10     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  11 }
  12 QT += network \
  13     xml \
  14     phonon
  15 include(src/qtsingleapplication/qtsingleapplication.pri)
  16 include(src/thlibrary/thlibrary.pri)
  17 HEADERS += src/MainWindow.h \
  18     src/SearchView.h \
  19     src/MediaView.h \
  20     src/AboutView.h \
  21     src/youtubesearch.h \
  22     src/video.h \
  23     src/youtubestreamreader.h \
  24     src/View.h \
  25     src/searchlineedit.h \
  26     src/urllineedit.h \
  27     src/spacer.h \
  28     src/Constants.h \
  29     src/iconloader/qticonloader.h \
  30     src/faderwidget/FaderWidget.h \
  31     src/ListModel.h \
  32     src/playlist/PrettyItemDelegate.h \
  33     src/networkaccess.h \
  34     src/videomimedata.h \
  35     src/global.h \
  36     src/updatechecker.h \
  37     src/playlistwidget.h \
  38     src/searchparams.h \
  39     src/minisplitter.h \
  40     src/loadingwidget.h \
  41     src/videoareawidget.h \
  42     src/googlesuggest.h \
  43     src/videowidget.h \
  44     src/flickcharm.h
  45 SOURCES += src/main.cpp \
  46     src/MainWindow.cpp \
  47     src/SearchView.cpp \
  48     src/MediaView.cpp \
  49     src/AboutView.cpp \
  50     src/youtubesearch.cpp \
  51     src/youtubestreamreader.cpp \
  52     src/searchlineedit.cpp \
  53     src/urllineedit.cpp \
  54     src/spacer.cpp \
  55     src/video.cpp \
  56     src/iconloader/qticonloader.cpp \
  57     src/faderwidget/FaderWidget.cpp \
  58     src/ListModel.cpp \
  59     src/playlist/PrettyItemDelegate.cpp \
  60     src/videomimedata.cpp \
  61     src/updatechecker.cpp \
  62     src/networkaccess.cpp \
  63     src/playlistwidget.cpp \
  64     src/searchparams.cpp \
  65     src/minisplitter.cpp \
  66     src/loadingwidget.cpp \
  67     src/videoareawidget.cpp \
  68     src/googlesuggest.cpp \
  69     src/videowidget.cpp \
  70     src/flickcharm.cpp
  71 RESOURCES += resources.qrc
  72 DESTDIR = build/target/
  73 OBJECTS_DIR = build/obj/
  74 MOC_DIR = build/moc/
  75 RCC_DIR = build/rcc/
  76
  77 # Tell Qt Linguist that we use UTF-8 strings in our sources
  78 CODECFORTR = UTF-8
  79 CODECFORSRC = UTF-8
  80 include(locale/locale.pri)
  81
  82 # deploy
  83 DISTFILES += CHANGES \
  84     COPYING
  85 mac {
  86     CONFIG += x86 \
  87         ppc
  88     QMAKE_INFO_PLIST = Info.plist
  89     ICON = minitube.icns
  90 }
  91 unix {
  92     isEmpty(PREFIX):PREFIX = /usr
  93     BINDIR = $$PREFIX/bin
  94     INSTALLS += target
  95     target.path = $$BINDIR
  96     DATADIR = $$PREFIX/share
  97     PKGDATADIR = $$DATADIR/minitube
  98     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  99         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 100     INSTALLS += translations \
 101         desktop \
 102         iconsvg \
 103         icon16 \
 104         icon32 \
 105         icon48 \
 106         icon64 \
 107         icon128 \
 108         icon256
 109     translations.path = $$PKGDATADIR
 110     translations.files += $$DESTDIR/locale
 111     desktop.path = $$DATADIR/applications
 112     desktop.files += minitube.desktop
 113     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 114     iconsvg.files += data/minitube.svg
 115     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 116     icon16.files += data/16x16/minitube.png
 117     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 118     icon32.files += data/32x32/minitube.png
 119     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 120     icon48.files += data/48x48/minitube.png
 121     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 122     icon64.files += data/64x64/minitube.png
 123     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 124     icon128.files += data/128x128/minitube.png
 125     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 126     icon256.files += data/256x256/minitube.png
 127 }
 128 win32:RC_FILE = minitube.rc