git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 1.9
   4 DEFINES += APP_VERSION="$$VERSION"
   5
   6 APP_NAME = Minitube
   7 DEFINES += APP_NAME="$$APP_NAME"
   8
   9 APP_UNIX_NAME = minitube
  10 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  11
  12 DEFINES += QT_USE_FAST_CONCATENATION
  13 DEFINES += QT_USE_FAST_OPERATOR_PLUS
  14
  15 # TODO Saner string behaviour
  16 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
  17 TARGET = minitube
  18 QT += network \
  19     xml \
  20     phonon
  21 include(src/qtsingleapplication/qtsingleapplication.pri)
  22 HEADERS += src/MainWindow.h \
  23     src/SearchView.h \
  24     src/MediaView.h \
  25     src/AboutView.h \
  26     src/youtubesearch.h \
  27     src/video.h \
  28     src/youtubestreamreader.h \
  29     src/View.h \
  30     src/searchlineedit.h \
  31     src/urllineedit.h \
  32     src/spacer.h \
  33     src/constants.h \
  34     src/iconloader/qticonloader.h \
  35     src/ListModel.h \
  36     src/playlist/PrettyItemDelegate.h \
  37     src/networkaccess.h \
  38     src/videomimedata.h \
  39     src/global.h \
  40     src/updatechecker.h \
  41     src/playlistwidget.h \
  42     src/searchparams.h \
  43     src/minisplitter.h \
  44     src/loadingwidget.h \
  45     src/videoareawidget.h \
  46     src/autocomplete.h \
  47     src/videowidget.h \
  48     src/videodefinition.h \
  49     src/fontutils.h \
  50     src/globalshortcuts.h \
  51     src/globalshortcutbackend.h \
  52     src/downloadmanager.h \
  53     src/downloaditem.h \
  54     src/downloadview.h \
  55     src/downloadmodel.h \
  56     src/downloadlistview.h \
  57     src/downloadsettings.h \
  58     src/youtubesuggest.h \
  59     src/suggester.h \
  60     src/channelsuggest.h \
  61     src/temporary.h \
  62     src/segmentedcontrol.h \
  63     src/playlistview.h \
  64     src/refinesearchwidget.h \
  65     src/refinesearchbutton.h \
  66     src/sidebarwidget.h
  67 SOURCES += src/main.cpp \
  68     src/MainWindow.cpp \
  69     src/SearchView.cpp \
  70     src/MediaView.cpp \
  71     src/AboutView.cpp \
  72     src/youtubesearch.cpp \
  73     src/youtubestreamreader.cpp \
  74     src/searchlineedit.cpp \
  75     src/urllineedit.cpp \
  76     src/spacer.cpp \
  77     src/video.cpp \
  78     src/iconloader/qticonloader.cpp \
  79     src/ListModel.cpp \
  80     src/playlist/PrettyItemDelegate.cpp \
  81     src/videomimedata.cpp \
  82     src/updatechecker.cpp \
  83     src/networkaccess.cpp \
  84     src/playlistwidget.cpp \
  85     src/searchparams.cpp \
  86     src/minisplitter.cpp \
  87     src/loadingwidget.cpp \
  88     src/videoareawidget.cpp \
  89     src/autocomplete.cpp \
  90     src/videowidget.cpp \
  91     src/videodefinition.cpp \
  92     src/constants.cpp \
  93     src/fontutils.cpp \
  94     src/globalshortcuts.cpp \
  95     src/globalshortcutbackend.cpp \
  96     src/downloadmanager.cpp \
  97     src/downloaditem.cpp \
  98     src/downloadview.cpp \
  99     src/downloadmodel.cpp \
 100     src/downloadlistview.cpp \
 101     src/downloadsettings.cpp \
 102     src/youtubesuggest.cpp \
 103     src/channelsuggest.cpp \
 104     src/temporary.cpp \
 105     src/segmentedcontrol.cpp \
 106     src/playlistview.cpp \
 107     src/refinesearchwidget.cpp \
 108     src/refinesearchbutton.cpp \
 109     src/sidebarwidget.cpp
 110 RESOURCES += resources.qrc
 111 DESTDIR = build/target/
 112 OBJECTS_DIR = build/obj/
 113 MOC_DIR = build/moc/
 114 RCC_DIR = build/rcc/
 115
 116 # Tell Qt Linguist that we use UTF-8 strings in our sources
 117 CODECFORTR = UTF-8
 118 CODECFORSRC = UTF-8
 119 include(locale/locale.pri)
 120
 121 # deploy
 122 DISTFILES += CHANGES \
 123     COPYING
 124 unix:!mac {
 125     INCLUDEPATH += /usr/include/phonon
 126     QT += dbus
 127     HEADERS += src/gnomeglobalshortcutbackend.h
 128     SOURCES += src/gnomeglobalshortcutbackend.cpp
 129     isEmpty(PREFIX):PREFIX = /usr
 130     BINDIR = $$PREFIX/bin
 131     INSTALLS += target
 132     target.path = $$BINDIR
 133     DATADIR = $$PREFIX/share
 134     PKGDATADIR = $$DATADIR/minitube
 135     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 136         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 137     INSTALLS += translations \
 138         desktop \
 139         iconsvg \
 140         icon16 \
 141         icon22 \
 142         icon32 \
 143         icon48 \
 144         icon64 \
 145         icon128 \
 146         icon256 \
 147         icon512
 148     translations.path = $$PKGDATADIR
 149     translations.files += $$DESTDIR/locale
 150     desktop.path = $$DATADIR/applications
 151     desktop.files += minitube.desktop
 152     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 153     iconsvg.files += data/minitube.svg
 154     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 155     icon16.files += data/16x16/minitube.png
 156     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 157     icon22.files += data/22x22/minitube.png
 158     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 159     icon32.files += data/32x32/minitube.png
 160     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 161     icon48.files += data/48x48/minitube.png
 162     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 163     icon64.files += data/64x64/minitube.png
 164     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 165     icon128.files += data/128x128/minitube.png
 166     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 167     icon256.files += data/256x256/minitube.png
 168     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 169     icon512.files += data/512x512/minitube.png
 170 }
 171 mac|win32:include(local/local.pri)