git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 2.3
   4 DEFINES += APP_VERSION="$$VERSION"
   5
   6 APP_NAME = Minitube
   7 DEFINES += APP_NAME="$$APP_NAME"
   8
   9 APP_UNIX_NAME = minitube
  10 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  11
  12 DEFINES *= QT_NO_DEBUG_OUTPUT
  13 DEFINES *= QT_USE_QSTRINGBUILDER
  14 DEFINES += QT_STRICT_ITERATORS
  15
  16 TARGET = $${APP_UNIX_NAME}
  17
  18 QT += network xml sql script
  19
  20 qt:greaterThan(QT_MAJOR_VERSION, 4) {
  21     contains(QT, gui): QT *= widgets
  22 } else {
  23     QT += phonon
  24 }
  25
  26 include(src/qtsingleapplication/qtsingleapplication.pri)
  27
  28 HEADERS += \
  29     src/video.h \
  30     src/searchlineedit.h \
  31     src/urllineedit.h \
  32     src/spacer.h \
  33     src/constants.h \
  34     src/playlistitemdelegate.h \
  35     src/networkaccess.h \
  36     src/videomimedata.h \
  37     src/global.h \
  38     src/updatechecker.h \
  39     src/searchparams.h \
  40     src/minisplitter.h \
  41     src/loadingwidget.h \
  42     src/videoareawidget.h \
  43     src/autocomplete.h \
  44     src/videodefinition.h \
  45     src/fontutils.h \
  46     src/globalshortcuts.h \
  47     src/globalshortcutbackend.h \
  48     src/downloadmanager.h \
  49     src/downloaditem.h \
  50     src/downloadview.h \
  51     src/downloadmodel.h \
  52     src/downloadlistview.h \
  53     src/downloadsettings.h \
  54     src/suggester.h \
  55     src/channelsuggest.h \
  56     src/temporary.h \
  57     src/segmentedcontrol.h \
  58     src/playlistview.h \
  59     src/refinesearchwidget.h \
  60     src/refinesearchbutton.h \
  61     src/sidebarwidget.h \
  62     src/homeview.h \
  63     src/aboutview.h \
  64     src/mainwindow.h \
  65     src/mediaview.h \
  66     src/searchview.h \
  67     src/view.h \
  68     src/playlistmodel.h \
  69     src/videosource.h \
  70     src/ytsearch.h \
  71     src/ytstandardfeed.h \
  72     src/standardfeedsview.h \
  73     src/ytregions.h \
  74     src/ytcategories.h \
  75     src/ytfeedreader.h \
  76     src/ytsuggester.h \
  77     src/videosourcewidget.h \
  78     src/regionsview.h \
  79     src/ytsinglevideosource.h \
  80     src/sidebarheader.h \
  81     src/utils.h \
  82     src/diskcache.h \
  83     src/gridwidget.h \
  84     src/painterutils.h \
  85     src/database.h \
  86     src/ytuser.h \
  87     src/channelaggregator.h \
  88     src/channelmodel.h \
  89     src/aggregatevideosource.h \
  90     src/channelview.h \
  91     src/channelitemdelegate.h \
  92     src/jsfunctions.h \
  93     src/seekslider.h
  94 SOURCES += src/main.cpp \
  95     src/searchlineedit.cpp \
  96     src/urllineedit.cpp \
  97     src/spacer.cpp \
  98     src/video.cpp \
  99     src/videomimedata.cpp \
 100     src/updatechecker.cpp \
 101     src/networkaccess.cpp \
 102     src/searchparams.cpp \
 103     src/minisplitter.cpp \
 104     src/loadingwidget.cpp \
 105     src/videoareawidget.cpp \
 106     src/autocomplete.cpp \
 107     src/videodefinition.cpp \
 108     src/constants.cpp \
 109     src/fontutils.cpp \
 110     src/globalshortcuts.cpp \
 111     src/globalshortcutbackend.cpp \
 112     src/downloadmanager.cpp \
 113     src/downloaditem.cpp \
 114     src/downloadview.cpp \
 115     src/downloadmodel.cpp \
 116     src/downloadlistview.cpp \
 117     src/downloadsettings.cpp \
 118     src/channelsuggest.cpp \
 119     src/temporary.cpp \
 120     src/segmentedcontrol.cpp \
 121     src/playlistview.cpp \
 122     src/refinesearchwidget.cpp \
 123     src/refinesearchbutton.cpp \
 124     src/sidebarwidget.cpp \
 125     src/homeview.cpp \
 126     src/mainwindow.cpp \
 127     src/mediaview.cpp \
 128     src/aboutview.cpp \
 129     src/searchview.cpp \
 130     src/playlistitemdelegate.cpp \
 131     src/playlistmodel.cpp \
 132     src/videosource.cpp \
 133     src/ytsearch.cpp \
 134     src/ytstandardfeed.cpp \
 135     src/standardfeedsview.cpp \
 136     src/ytregions.cpp \
 137     src/ytcategories.cpp \
 138     src/ytfeedreader.cpp \
 139     src/ytsuggester.cpp \
 140     src/videosourcewidget.cpp \
 141     src/regionsview.cpp \
 142     src/ytsinglevideosource.cpp \
 143     src/sidebarheader.cpp \
 144     src/utils.cpp \
 145     src/diskcache.cpp \
 146     src/gridwidget.cpp \
 147     src/painterutils.cpp \
 148     src/database.cpp \
 149     src/ytuser.cpp \
 150     src/channelaggregator.cpp \
 151     src/channelmodel.cpp \
 152     src/aggregatevideosource.cpp \
 153     src/channelview.cpp \
 154     src/channelitemdelegate.cpp \
 155     src/jsfunctions.cpp \
 156     src/seekslider.cpp
 157 RESOURCES += resources.qrc
 158 DESTDIR = build/target/
 159 OBJECTS_DIR = build/obj/
 160 MOC_DIR = build/moc/
 161 RCC_DIR = build/rcc/
 162
 163 # Tell Qt Linguist that we use UTF-8 strings in our sources
 164 CODECFORTR = UTF-8
 165 CODECFORSRC = UTF-8
 166 include(locale/locale.pri)
 167
 168 # deploy
 169 DISTFILES += CHANGES COPYING
 170 unix:!mac {
 171     INCLUDEPATH += /usr/include/phonon
 172     QT += dbus
 173     HEADERS += src/gnomeglobalshortcutbackend.h
 174     SOURCES += src/gnomeglobalshortcutbackend.cpp
 175     isEmpty(PREFIX):PREFIX = /usr
 176     BINDIR = $$PREFIX/bin
 177     INSTALLS += target
 178     target.path = $$BINDIR
 179     DATADIR = $$PREFIX/share
 180     PKGDATADIR = $$DATADIR/minitube
 181     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 182         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 183     INSTALLS += translations \
 184         desktop \
 185         iconsvg \
 186         icon16 \
 187         icon22 \
 188         icon32 \
 189         icon48 \
 190         icon64 \
 191         icon128 \
 192         icon256 \
 193         icon512
 194     translations.path = $$PKGDATADIR
 195     translations.files += $$DESTDIR/locale
 196     desktop.path = $$DATADIR/applications
 197     desktop.files += minitube.desktop
 198     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 199     iconsvg.files += data/minitube.svg
 200     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 201     icon16.files += data/16x16/minitube.png
 202     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 203     icon22.files += data/22x22/minitube.png
 204     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 205     icon32.files += data/32x32/minitube.png
 206     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 207     icon48.files += data/48x48/minitube.png
 208     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 209     icon64.files += data/64x64/minitube.png
 210     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 211     icon128.files += data/128x128/minitube.png
 212     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 213     icon256.files += data/256x256/minitube.png
 214     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 215     icon512.files += data/512x512/minitube.png
 216 }
 217 mac|win32|contains(DEFINES, APP_UBUNTU):include(local/local.pri)