git.sur5r.net Git - minitube/blob - minitube.pro

   1 # On some distro, Phonon headers cannot be found
   2 INCLUDEPATH += /usr/include/phonon
   3 CONFIG += release
   4 TEMPLATE = app
   5
   6 # Saner string behaviour
   7 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   8 TARGET = minitube
   9 mac {
  10     TARGET = Minitube
  11     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  12 }
  13 QT += network \
  14     xml \
  15     phonon
  16 include(src/qtsingleapplication/qtsingleapplication.pri)
  17 include(src/thlibrary/thlibrary.pri)
  18 HEADERS += src/MainWindow.h \
  19     src/SearchView.h \
  20     src/MediaView.h \
  21     src/SettingsView.h \
  22     src/AboutView.h \
  23     src/youtubesearch.h \
  24     src/video.h \
  25     src/youtubestreamreader.h \
  26     src/View.h \
  27     src/searchlineedit.h \
  28     src/urllineedit.h \
  29     src/spacer.h \
  30     src/Constants.h \
  31     src/iconloader/qticonloader.h \
  32     src/faderwidget/FaderWidget.h \
  33     src/ListModel.h \
  34     src/playlist/PrettyItemDelegate.h \
  35     src/networkaccess.h \
  36     src/videomimedata.h \
  37     src/global.h \
  38     src/updatechecker.h \
  39     src/playlistwidget.h \
  40     src/searchparams.h \
  41     src/minisplitter.h \
  42     src/loadingwidget.h \
  43     src/videoareawidget.h \
  44     src/googlesuggest.h \
  45     src/videowidget.h
  46 SOURCES += src/main.cpp \
  47     src/MainWindow.cpp \
  48     src/SearchView.cpp \
  49     src/MediaView.cpp \
  50     src/SettingsView.cpp \
  51     src/AboutView.cpp \
  52     src/youtubesearch.cpp \
  53     src/youtubestreamreader.cpp \
  54     src/searchlineedit.cpp \
  55     src/urllineedit.cpp \
  56     src/spacer.cpp \
  57     src/video.cpp \
  58     src/iconloader/qticonloader.cpp \
  59     src/faderwidget/FaderWidget.cpp \
  60     src/ListModel.cpp \
  61     src/playlist/PrettyItemDelegate.cpp \
  62     src/videomimedata.cpp \
  63     src/updatechecker.cpp \
  64     src/networkaccess.cpp \
  65     src/playlistwidget.cpp \
  66     src/searchparams.cpp \
  67     src/minisplitter.cpp \
  68     src/loadingwidget.cpp \
  69     src/videoareawidget.cpp \
  70     src/googlesuggest.cpp \
  71     src/videowidget.cpp
  72 RESOURCES += resources.qrc
  73 DESTDIR = build/target/
  74 OBJECTS_DIR = build/obj/
  75 MOC_DIR = build/moc/
  76 RCC_DIR = build/rcc/
  77
  78 # Tell Qt Linguist that we use UTF-8 strings in our sources
  79 CODECFORTR = UTF-8
  80 CODECFORSRC = UTF-8
  81 include(locale/locale.pri)
  82
  83 # deploy
  84 DISTFILES += CHANGES \
  85     LICENSE
  86 mac {
  87     CONFIG += x86 \
  88         ppc
  89     QMAKE_INFO_PLIST = Info.plist
  90     ICON = minitube.icns
  91 }
  92 unix {
  93     isEmpty(PREFIX):PREFIX = /usr/local
  94     BINDIR = $$PREFIX/bin
  95     INSTALLS += target
  96     target.path = $$BINDIR
  97     DATADIR = $$PREFIX/share
  98     PKGDATADIR = $$DATADIR/minitube
  99     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 100         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 101     INSTALLS += translations \
 102         desktop \
 103         iconsvg \
 104         icon16 \
 105         icon32 \
 106         icon128
 107     translations.path = $$PKGDATADIR
 108     translations.files += $$DESTDIR/locale
 109     desktop.path = $$DATADIR/applications
 110     desktop.files += minitube.desktop
 111
 112     # iconxpm.path = $$DATADIR/pixmaps
 113     # iconxpm.files += data/minitube.xpm
 114     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 115     iconsvg.files += data/minitube.svg
 116     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 117     icon16.files += data/16x16/minitube.png
 118     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 119     icon32.files += data/32x32/minitube.png
 120     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 121     icon128.files += data/128x128/minitube.png
 122 }