git.sur5r.net Git - minitube/blob - minitube.pro

   1 # On some distro, Phonon headers cannot be found
   2 INCLUDEPATH += /usr/include/phonon
   3
   4 CONFIG += release
   5 TEMPLATE = app
   6
   7 # Saner string behaviour
   8 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   9 TARGET = minitube
  10 mac {
  11     TARGET = Minitube
  12     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  13 }
  14 QT += network \
  15     xml \
  16     phonon
  17 include(src/qtsingleapplication/qtsingleapplication.pri)
  18 include(src/thlibrary/thlibrary.pri)
  19 HEADERS += src/MainWindow.h \
  20     src/SearchView.h \
  21     src/MediaView.h \
  22     src/SettingsView.h \
  23     src/AboutView.h \
  24     src/youtubesearch.h \
  25     src/video.h \
  26     src/youtubestreamreader.h \
  27     src/View.h \
  28     src/searchlineedit.h \
  29     src/urllineedit.h \
  30     src/spacer.h \
  31     src/Constants.h \
  32     src/iconloader/qticonloader.h \
  33     src/faderwidget/FaderWidget.h \
  34     src/ListModel.h \
  35     src/playlist/PrettyItemDelegate.h \
  36     src/networkaccess.h \
  37     src/videomimedata.h \
  38     src/global.h \
  39     src/updatechecker.h \
  40     src/playlistwidget.h \
  41     src/searchparams.h \
  42     src/minisplitter.h \
  43     src/loadingwidget.h \
  44     src/videoareawidget.h
  45 SOURCES += src/main.cpp \
  46     src/MainWindow.cpp \
  47     src/SearchView.cpp \
  48     src/MediaView.cpp \
  49     src/SettingsView.cpp \
  50     src/AboutView.cpp \
  51     src/youtubesearch.cpp \
  52     src/youtubestreamreader.cpp \
  53     src/searchlineedit.cpp \
  54     src/urllineedit.cpp \
  55     src/spacer.cpp \
  56     src/video.cpp \
  57     src/iconloader/qticonloader.cpp \
  58     src/faderwidget/FaderWidget.cpp \
  59     src/ListModel.cpp \
  60     src/playlist/PrettyItemDelegate.cpp \
  61     src/videomimedata.cpp \
  62     src/updatechecker.cpp \
  63     src/networkaccess.cpp \
  64     src/playlistwidget.cpp \
  65     src/searchparams.cpp \
  66     src/minisplitter.cpp \
  67     src/loadingwidget.cpp \
  68     src/videoareawidget.cpp
  69 RESOURCES += resources.qrc
  70 DESTDIR = build/target/
  71 OBJECTS_DIR = build/obj/
  72 MOC_DIR = build/moc/
  73 RCC_DIR = build/rcc/
  74
  75 # Tell Qt Linguist that we use UTF-8 strings in our sources
  76 CODECFORTR = UTF-8
  77 CODECFORSRC = UTF-8
  78 include(locale/locale.pri)
  79
  80 # deploy
  81 DISTFILES += CHANGES \
  82     LICENSE
  83 mac {
  84     CONFIG += x86 \
  85         ppc
  86     QMAKE_INFO_PLIST = Info.plist
  87     ICON = minitube.icns
  88 }
  89 unix {
  90     isEmpty(PREFIX):PREFIX = /usr/local
  91     BINDIR = $$PREFIX/bin
  92     INSTALLS += target
  93     target.path = $$BINDIR
  94     DATADIR = $$PREFIX/share
  95     PKGDATADIR = $$DATADIR/minitube
  96     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  97         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  98     INSTALLS += translations \
  99         desktop \
 100         iconsvg \
 101         icon16 \
 102         icon32 \
 103         icon128
 104     translations.path = $$PKGDATADIR
 105     translations.files += $$DESTDIR/locale
 106     desktop.path = $$DATADIR/applications
 107     desktop.files += minitube.desktop
 108     # iconxpm.path = $$DATADIR/pixmaps
 109     # iconxpm.files += data/minitube.xpm
 110     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 111     iconsvg.files += data/minitube.svg
 112     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 113     icon16.files += data/16x16/minitube.png
 114     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 115     icon32.files += data/32x32/minitube.png
 116     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 117     icon128.files += data/128x128/minitube.png
 118 }