git.sur5r.net Git - minitube/blob - minitube.pro

   1 # If Phonon cannot be found, uncomment the following (and set the correct path)
   2 # INCLUDEPATH += /usr/include/phonon
   3 CONFIG += release
   4 TEMPLATE = app
   5
   6 # Saner string behaviour
   7 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   8 TARGET = minitube
   9 mac {
  10     TARGET = Minitube
  11     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  12 }
  13 QT += network \
  14     xml \
  15     phonon
  16 include(src/qtsingleapplication/qtsingleapplication.pri)
  17 include(src/thlibrary/thlibrary.pri)
  18 HEADERS += src/MainWindow.h \
  19     src/SearchView.h \
  20     src/MediaView.h \
  21     src/SettingsView.h \
  22     src/AboutView.h \
  23     src/youtubesearch.h \
  24     src/video.h \
  25     src/youtubestreamreader.h \
  26     src/View.h \
  27     src/searchlineedit.h \
  28     src/urllineedit.h \
  29     src/spacer.h \
  30     src/Constants.h \
  31     src/iconloader/qticonloader.h \
  32     src/faderwidget/FaderWidget.h \
  33     src/ListModel.h \
  34     src/playlist/PrettyItemDelegate.h \
  35     src/networkaccess.h \
  36     src/videomimedata.h \
  37     src/global.h \
  38     src/updatechecker.h \
  39     src/playlistwidget.h \
  40     src/searchparams.h \
  41     src/minisplitter.h \
  42     src/loadingwidget.h \
  43     src/videoareawidget.h
  44 SOURCES += src/main.cpp \
  45     src/MainWindow.cpp \
  46     src/SearchView.cpp \
  47     src/MediaView.cpp \
  48     src/SettingsView.cpp \
  49     src/AboutView.cpp \
  50     src/youtubesearch.cpp \
  51     src/youtubestreamreader.cpp \
  52     src/searchlineedit.cpp \
  53     src/urllineedit.cpp \
  54     src/spacer.cpp \
  55     src/video.cpp \
  56     src/iconloader/qticonloader.cpp \
  57     src/faderwidget/FaderWidget.cpp \
  58     src/ListModel.cpp \
  59     src/playlist/PrettyItemDelegate.cpp \
  60     src/videomimedata.cpp \
  61     src/updatechecker.cpp \
  62     src/networkaccess.cpp \
  63     src/playlistwidget.cpp \
  64     src/searchparams.cpp \
  65     src/minisplitter.cpp \
  66     src/loadingwidget.cpp \
  67     src/videoareawidget.cpp
  68 RESOURCES += resources.qrc
  69 DESTDIR = build/target/
  70 OBJECTS_DIR = build/obj/
  71 MOC_DIR = build/moc/
  72 RCC_DIR = build/rcc/
  73
  74 # Tell Qt Linguist that we use UTF-8 strings in our sources
  75 CODECFORTR = UTF-8
  76 CODECFORSRC = UTF-8
  77 include(locale/locale.pri)
  78
  79 # deploy
  80 DISTFILES += CHANGES \
  81     LICENSE
  82 mac {
  83     CONFIG += x86 \
  84         ppc
  85     QMAKE_INFO_PLIST = Info.plist
  86     ICON = minitube.icns
  87 }
  88 unix {
  89     isEmpty(PREFIX):PREFIX = /usr/local
  90     BINDIR = $$PREFIX/bin
  91     INSTALLS += target
  92     target.path = $$BINDIR
  93     DATADIR = $$PREFIX/share
  94     PKGDATADIR = $$DATADIR/minitube
  95     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  96         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  97     INSTALLS += translations \
  98         desktop \
  99         iconsvg \
 100         icon16 \
 101         icon32 \
 102         icon128
 103     translations.path = $$PKGDATADIR
 104     translations.files += .qm/locale
 105     desktop.path = $$DATADIR/applications
 106     desktop.files += minitube.desktop
 107
 108     # iconxpm.path = $$DATADIR/pixmaps
 109     # iconxpm.files += data/minitube.xpm
 110     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 111     iconsvg.files += data/minitube.svg
 112     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 113     icon16.files += data/16x16/minitube.png
 114     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 115     icon32.files += data/32x32/minitube.png
 116     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 117     icon128.files += data/128x128/minitube.png
 118 }