git.sur5r.net Git - u-boot/blob - scripts/checkstack.pl

   1 #!/usr/bin/perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@lazybastard.org>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AVR32 port by Haavard Skinnemoen (Atmel)
  16 #       AArch64, PARISC ports by Kyle McMartin
  17 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  18 #
  19 #       Usage:
  20 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  21 #
  22 #       TODO :  Port to all architectures (one regex per arch)
  23
  24 use strict;
  25
  26 # check for arch
  27 #
  28 # $re is used for two matches:
  29 # $& (whole re) matches the complete objdump line with the stack growth
  30 # $1 (first bracket) matches the size of the stack growth
  31 #
  32 # $dre is similar, but for dynamic stack redutions:
  33 # $& (whole re) matches the complete objdump line with the stack growth
  34 # $1 (first bracket) matches the dynamic amount of the stack growth
  35 #
  36 # use anything else and feel the pain ;)
  37 my (@stack, $re, $dre, $x, $xs, $funcre);
  38 {
  39         my $arch = shift;
  40         if ($arch eq "") {
  41                 $arch = `uname -m`;
  42                 chomp($arch);
  43         }
  44
  45         $x      = "[0-9a-f]";   # hex character
  46         $xs     = "[0-9a-f ]";  # hex character or space
  47         $funcre = qr/^$x* <(.*)>:$/;
  48         if ($arch eq 'aarch64') {
  49                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
  50                 $re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
  51         } elsif ($arch eq 'arm') {
  52                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  53                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  54         } elsif ($arch eq 'avr32') {
  55                 #8000008a:       20 1d           sub sp,4
  56                 #80000ca8:       fa cd 05 b0     sub sp,sp,1456
  57                 $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o;
  58         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  59                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  60                 # or
  61                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  62                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  63                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  64         } elsif ($arch eq 'ia64') {
  65                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  66                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  67         } elsif ($arch eq 'm68k') {
  68                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  69                 #  1df770:       defc ffe4       addaw #-28,%sp
  70                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  71         } elsif ($arch eq 'metag') {
  72                 #400026fc:       40 00 00 82     ADD       A0StP,A0StP,#0x8
  73                 $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o;
  74                 $funcre = qr/^$x* <[^\$](.*)>:$/;
  75         } elsif ($arch eq 'mips64') {
  76                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  77                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  78         } elsif ($arch eq 'mips') {
  79                 #88003254:       27bdffe0        addiu   sp,sp,-32
  80                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  81         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  82                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  83         } elsif ($arch eq 'ppc') {
  84                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  85                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  86         } elsif ($arch eq 'ppc64') {
  87                 #XXX
  88                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  89         } elsif ($arch eq 'powerpc') {
  90                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  91         } elsif ($arch =~ /^s390x?$/) {
  92                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  93                 # or
  94                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
  95                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
  96                       (?:\(\%r15\))?$/ox;
  97         } elsif ($arch =~ /^sh64$/) {
  98                 #XXX: we only check for the immediate case presently,
  99                 #     though we will want to check for the movi/sub
 100                 #     pair for larger users. -- PFM.
 101                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
 102                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
 103         } elsif ($arch =~ /^blackfin$/) {
 104                 #   0:   00 e8 38 01     LINK 0x4e0;
 105                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
 106         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
 107                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 108                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 109         } else {
 110                 print("wrong or unknown architecture \"$arch\"\n");
 111                 exit
 112         }
 113 }
 114
 115 #
 116 # main()
 117 #
 118 my ($func, $file, $lastslash);
 119
 120 while (my $line = <STDIN>) {
 121         if ($line =~ m/$funcre/) {
 122                 $func = $1;
 123         }
 124         elsif ($line =~ m/(.*):\s*file format/) {
 125                 $file = $1;
 126                 $file =~ s/\.ko//;
 127                 $lastslash = rindex($file, "/");
 128                 if ($lastslash != -1) {
 129                         $file = substr($file, $lastslash + 1);
 130                 }
 131         }
 132         elsif ($line =~ m/$re/) {
 133                 my $size = $1;
 134                 $size = hex($size) if ($size =~ /^0x/);
 135
 136                 if ($size > 0xf0000000) {
 137                         $size = - $size;
 138                         $size += 0x80000000;
 139                         $size += 0x80000000;
 140                 }
 141                 next if ($size > 0x10000000);
 142
 143                 next if $line !~ m/^($xs*)/;
 144                 my $addr = $1;
 145                 $addr =~ s/ /0/g;
 146                 $addr = "0x$addr";
 147
 148                 my $intro = "$addr $func [$file]:";
 149                 my $padlen = 56 - length($intro);
 150                 while ($padlen > 0) {
 151                         $intro .= '     ';
 152                         $padlen -= 8;
 153                 }
 154                 next if ($size < 100);
 155                 push @stack, "$intro$size\n";
 156         }
 157         elsif (defined $dre && $line =~ m/$dre/) {
 158                 my $size = "Dynamic ($1)";
 159
 160                 next if $line !~ m/^($xs*)/;
 161                 my $addr = $1;
 162                 $addr =~ s/ /0/g;
 163                 $addr = "0x$addr";
 164
 165                 my $intro = "$addr $func [$file]:";
 166                 my $padlen = 56 - length($intro);
 167                 while ($padlen > 0) {
 168                         $intro .= '     ';
 169                         $padlen -= 8;
 170                 }
 171                 push @stack, "$intro$size\n";
 172         }
 173 }
 174
 175 # Sort output by size (last field)
 176 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;