git.sur5r.net Git - openocd/blob - testing/examples/STR710Test/prj/hitex_str7_ram.ld

   1 /***********************************************************************************
   2 *       Copyright 2005 Anglia Design
   3 *       This demo code and associated components are provided as is and has no warranty,
   4 *       implied or otherwise.  You are free to use/modify any of the provided
   5 *       code at your own risk in your applications with the expressed limitation
   6 *       of liability (see below)
   7 *
   8 *       LIMITATION OF LIABILITY:   ANGLIA OR ANGLIA DESIGNS SHALL NOT BE LIABLE FOR ANY
   9 *       LOSS OF PROFITS, LOSS OF USE, LOSS OF DATA, INTERRUPTION OF BUSINESS, NOR FOR
  10 *       INDIRECT, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES OF ANY KIND WHETHER UNDER
  11 *       THIS AGREEMENT OR OTHERWISE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.
  12 *
  13 *       Author                  : Spencer Oliver
  14 *       Web                     : www.anglia-designs.com
  15 *
  16 ***********************************************************************************/
  17
  18 /* Stack Sizes */
  19
  20         _STACKSIZE     = 1024;
  21         _STACKSIZE_IRQ = 256;
  22         _STACKSIZE_FIQ = 0;
  23         _STACKSIZE_SVC = 1024;
  24         _STACKSIZE_ABT = 0;
  25         _STACKSIZE_UND = 0;
  26         _HEAPSIZE      = 1024;
  27
  28 /* Memory Definitions */
  29
  30 MEMORY
  31 {
  32         DATA (rw) : ORIGIN = 0x20000000, LENGTH = 0x00010000
  33 }
  34
  35 /* Section Definitions */
  36
  37 SECTIONS
  38 {
  39         /* first section is .text which is used for code */
  40
  41         .text :
  42         {
  43                 CREATE_OBJECT_SYMBOLS
  44                 KEEP(*(.vectrom))
  45                 KEEP(*(.init))
  46                 *(.text .text.*)
  47                 *(.gnu.linkonce.t.*)
  48                 *(.glue_7t) *(.glue_7) *(.vfp11_veneer)
  49                 KEEP(*(.fini))
  50                 *(.gcc_except_table)
  51         } >DATA =0
  52         . = ALIGN(4);
  53
  54         /* .ctors .dtors are used for c++ constructors/destructors */
  55
  56         .ctors :
  57         {
  58                 PROVIDE(__ctors_start__ = .);
  59                 KEEP(*(SORT(.ctors.*)))
  60                 KEEP(*(.ctors))
  61                 PROVIDE(__ctors_end__ = .);
  62         } >DATA
  63
  64         .dtors :
  65         {
  66                 PROVIDE(__dtors_start__ = .);
  67                 KEEP(*(SORT(.dtors.*)))
  68                 KEEP(*(.dtors))
  69                 PROVIDE(__dtors_end__ = .);
  70         } >DATA
  71
  72         /* .rodata section which is used for read-only data (constants) */
  73
  74         .rodata :
  75         {
  76                 *(.rodata .rodata.*)
  77                 *(.gnu.linkonce.r.*)
  78         } >DATA
  79         . = ALIGN(4);
  80
  81         .init_array :
  82         {
  83                 *(.init)
  84         *(.fini)
  85                 PROVIDE (__preinit_array_start = .);
  86                 KEEP (*(.preinit_array))
  87                 PROVIDE (__preinit_array_end = .);
  88                 PROVIDE (__init_array_start = .);
  89                 KEEP (*(SORT(.init_array.*)))
  90                 KEEP (*(.init_array))
  91                 PROVIDE (__init_array_end = .);
  92                 PROVIDE (__fini_array_start = .);
  93                 KEEP (*(.fini_array))
  94                 KEEP (*(SORT(.fini_array.*)))
  95                 PROVIDE (__fini_array_end = .);
  96         } >DATA
  97
  98         . = ALIGN(4);
  99
 100         /* .ARM.exidx is sorted, so has to go in its own output section.  */
 101         __exidx_start = .;
 102         .ARM.exidx :
 103         {
 104                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
 105         } >DATA
 106         __exidx_end = .;
 107
 108         _vectext = .;
 109         PROVIDE (vectext = .);
 110
 111         .vect : AT (_vectext)
 112         {
 113                 _vecstart = .;
 114                 KEEP(*(.vectram))
 115                 _vecend = .;
 116         } >DATA
 117
 118         _etext = _vectext + SIZEOF(.vect);
 119         PROVIDE (etext = .);
 120
 121         /* .data section which is used for initialized data */
 122
 123         .data : AT (_etext)
 124         {
 125                 *(.data .data.*)
 126                 *(.gnu.linkonce.d.*)
 127                 SORT(CONSTRUCTORS)
 128         } >DATA
 129         . = ALIGN(4);
 130
 131         __data_start = .;
 132         _edata = .;
 133         PROVIDE (edata = .);
 134
 135         /* .bss section which is used for uninitialized data */
 136
 137         .bss :
 138         {
 139                 __bss_start = .;
 140                 __bss_start__ = .;
 141                 *(.bss .bss.*)
 142                 *(.gnu.linkonce.b.*)
 143                 *(COMMON)
 144                 . = ALIGN(4);
 145         } >DATA
 146         . = ALIGN(4);
 147         __bss_end__ = .;
 148
 149         _end = .;
 150         PROVIDE(end = .);
 151
 152         /* .heap section which is used for memory allocation */
 153
 154         .heap (NOLOAD) :
 155         {
 156                 __heap_start__ = .;
 157                 *(.heap)
 158                 . = MAX(__heap_start__ + _HEAPSIZE , .);
 159         } >DATA
 160         __heap_end__ = __heap_start__ + SIZEOF(.heap);
 161
 162         /* .stack section - user mode stack */
 163
 164         .stack (__heap_end__ + 3) / 4 * 4 (NOLOAD) :
 165         {
 166                 __stack_start__ = .;
 167                 *(.stack)
 168                 . = MAX(__stack_start__ + _STACKSIZE , .);
 169         } >DATA
 170         __stack_end__ = __stack_start__ + SIZEOF(.stack);
 171
 172         /* .stack_irq section */
 173
 174         .stack_irq (__stack_end__ + 3) / 4 * 4 (NOLOAD) :
 175         {
 176                 __stack_irq_start__ = .;
 177                 *(.stack_irq)
 178                 . = MAX(__stack_irq_start__ + _STACKSIZE_IRQ , .);
 179         } >DATA
 180         __stack_irq_end__ = __stack_irq_start__ + SIZEOF(.stack_irq);
 181
 182         /* .stack_fiq section */
 183
 184         .stack_fiq (__stack_irq_end__ + 3) / 4 * 4 (NOLOAD) :
 185         {
 186                 __stack_fiq_start__ = .;
 187                 *(.stack_fiq)
 188             . = MAX(__stack_fiq_start__ + _STACKSIZE_FIQ , .);
 189         } >DATA
 190         __stack_fiq_end__ = __stack_fiq_start__ + SIZEOF(.stack_fiq);
 191
 192         /* .stack_svc section */
 193
 194         .stack_svc (__stack_fiq_end__ + 3) / 4 * 4 (NOLOAD) :
 195         {
 196                 __stack_svc_start__ = .;
 197                 *(.stack_svc)
 198                 . = MAX(__stack_svc_start__ + _STACKSIZE_SVC , .);
 199         } >DATA
 200         __stack_svc_end__ = __stack_svc_start__ + SIZEOF(.stack_svc);
 201
 202         /* .stack_abt section */
 203
 204         .stack_abt (__stack_svc_end__ + 3) / 4 * 4 (NOLOAD) :
 205         {
 206                 __stack_abt_start__ = .;
 207                 *(.stack_abt)
 208                 . = MAX(__stack_abt_start__ + _STACKSIZE_ABT , .);
 209         } >DATA
 210         __stack_abt_end__ = __stack_abt_start__ + SIZEOF(.stack_abt);
 211
 212         /* .stack_und section */
 213
 214         .stack_und (__stack_abt_end__ + 3) / 4 * 4 (NOLOAD) :
 215         {
 216                 __stack_und_start__ = .;
 217                 *(.stack_und)
 218         . = MAX(__stack_und_start__ + _STACKSIZE_UND , .);
 219         } >DATA
 220         __stack_und_end__ = __stack_und_start__ + SIZEOF(.stack_und);
 221
 222         /* Stabs debugging sections.  */
 223         .stab          0 : { *(.stab) }
 224         .stabstr       0 : { *(.stabstr) }
 225         .stab.excl     0 : { *(.stab.excl) }
 226         .stab.exclstr  0 : { *(.stab.exclstr) }
 227         .stab.index    0 : { *(.stab.index) }
 228         .stab.indexstr 0 : { *(.stab.indexstr) }
 229         .comment       0 : { *(.comment) }
 230         /* DWARF debug sections.
 231                 Symbols in the DWARF debugging sections are relative to the beginning
 232                 of the section so we begin them at 0.  */
 233         /* DWARF 1 */
 234         .debug          0 : { *(.debug) }
 235         .line           0 : { *(.line) }
 236         /* GNU DWARF 1 extensions */
 237         .debug_srcinfo  0 : { *(.debug_srcinfo) }
 238         .debug_sfnames  0 : { *(.debug_sfnames) }
 239         /* DWARF 1.1 and DWARF 2 */
 240         .debug_aranges  0 : { *(.debug_aranges) }
 241         .debug_pubnames 0 : { *(.debug_pubnames) }
 242         /* DWARF 2 */
 243         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 244         .debug_abbrev   0 : { *(.debug_abbrev) }
 245         .debug_line     0 : { *(.debug_line) }
 246         .debug_frame    0 : { *(.debug_frame) }
 247         .debug_str      0 : { *(.debug_str) }
 248         .debug_loc      0 : { *(.debug_loc) }
 249         .debug_macinfo  0 : { *(.debug_macinfo) }
 250         /* SGI/MIPS DWARF 2 extensions */
 251         .debug_weaknames 0 : { *(.debug_weaknames) }
 252         .debug_funcnames 0 : { *(.debug_funcnames) }
 253         .debug_typenames 0 : { *(.debug_typenames) }
 254         .debug_varnames  0 : { *(.debug_varnames) }
 255 }