git.sur5r.net Git - openocd/blob - testing/examples/STR912Test/prj/str912_ram.ld

   1 /***********************************************************************************\r
   2 *       Copyright 2005 Anglia Design\r
   3 *       This demo code and associated components are provided as is and has no warranty,\r
   4 *       implied or otherwise.  You are free to use/modify any of the provided\r
   5 *       code at your own risk in your applications with the expressed limitation\r
   6 *       of liability (see below)\r
   7 * \r
   8 *       LIMITATION OF LIABILITY:   ANGLIA OR ANGLIA DESIGNS SHALL NOT BE LIABLE FOR ANY\r
   9 *       LOSS OF PROFITS, LOSS OF USE, LOSS OF DATA, INTERRUPTION OF BUSINESS, NOR FOR\r
  10 *       INDIRECT, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES OF ANY KIND WHETHER UNDER\r
  11 *       THIS AGREEMENT OR OTHERWISE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.\r
  12 *\r
  13 *       Author                  : Spencer Oliver\r
  14 *       Web                     : www.anglia-designs.com\r
  15 *\r
  16 ***********************************************************************************/\r
  17 \r
  18 /* Stack Sizes */\r
  19 \r
  20         _STACKSIZE     = 1024;\r
  21         _STACKSIZE_IRQ = 256;\r
  22         _STACKSIZE_FIQ = 0;\r
  23         _STACKSIZE_SVC = 1024;\r
  24         _STACKSIZE_ABT = 0;\r
  25         _STACKSIZE_UND = 0;\r
  26         _HEAPSIZE      = 1024;\r
  27 \r
  28 /* Memory Definitions */\r
  29 \r
  30 MEMORY\r
  31 {\r
  32         DATA (rw) : ORIGIN = 0x04000000, LENGTH = 0x00018000\r
  33 }\r
  34 \r
  35 /* Section Definitions */\r
  36 \r
  37 SECTIONS\r
  38 {\r
  39         /* first section is .text which is used for code */\r
  40 \r
  41         .text :\r
  42         {\r
  43                 KEEP(*(.vectors))\r
  44                 KEEP(*(.init))\r
  45                 *(.text .text.*)\r
  46                 *(.gnu.linkonce.t.*)\r
  47                 *(.glue_7t .glue_7)\r
  48                 KEEP(*(.fini))\r
  49                 *(.gcc_except_table)\r
  50         } >DATA =0\r
  51         . = ALIGN(4);\r
  52 \r
  53         /* .ctors .dtors are used for c++ constructors/destructors */\r
  54         \r
  55         .ctors :\r
  56         {\r
  57                 PROVIDE(__ctors_start__ = .);\r
  58                 KEEP(*(SORT(.ctors.*)))\r
  59                 KEEP(*(.ctors))\r
  60                 PROVIDE(__ctors_end__ = .);\r
  61         } >DATA\r
  62 \r
  63         .dtors :\r
  64         {\r
  65                 PROVIDE(__dtors_start__ = .); \r
  66                 KEEP(*(SORT(.dtors.*)))\r
  67                 KEEP(*(.dtors))\r
  68                 PROVIDE(__dtors_end__ = .);\r
  69         } >DATA\r
  70         \r
  71         /* .rodata section which is used for read-only data (constants) */\r
  72 \r
  73         .rodata :\r
  74         {\r
  75                 *(.rodata .rodata.*)\r
  76                 *(.gnu.linkonce.r.*)\r
  77         } >DATA\r
  78         . = ALIGN(4);\r
  79 \r
  80         _etext = .;\r
  81         PROVIDE (etext = .);\r
  82 \r
  83         /* .data section which is used for initialized data */\r
  84 \r
  85         .data : AT (_etext)\r
  86         {\r
  87                 *(.data .data.*)\r
  88                 *(.gnu.linkonce.d.*)\r
  89                 SORT(CONSTRUCTORS)\r
  90         } >DATA\r
  91         . = ALIGN(4);\r
  92         \r
  93         __data_start = .;\r
  94         _edata = .;\r
  95         PROVIDE (edata = .);\r
  96 \r
  97         /* .bss section which is used for uninitialized data */\r
  98 \r
  99         .bss :\r
 100         {\r
 101                 __bss_start = .;\r
 102                 __bss_start__ = .;\r
 103                 *(.bss .bss.*)\r
 104                 *(.gnu.linkonce.b.*)\r
 105                 *(COMMON)\r
 106                 . = ALIGN(4);\r
 107         } >DATA\r
 108         . = ALIGN(4);\r
 109         __bss_end__ = .;\r
 110         \r
 111         _end = .;\r
 112         PROVIDE(end = .);\r
 113 \r
 114         /* .heap section which is used for memory allocation */\r
 115         \r
 116         .heap (NOLOAD) :\r
 117         {\r
 118                 __heap_start__ = .;\r
 119                 *(.heap)\r
 120                 . = MAX(__heap_start__ + _HEAPSIZE , .);\r
 121         } >DATA\r
 122         __heap_end__ = __heap_start__ + SIZEOF(.heap);\r
 123         \r
 124         /* .stack section - user mode stack */\r
 125         \r
 126         .stack (__heap_end__ + 3) / 4 * 4 (NOLOAD) :\r
 127         {\r
 128                 __stack_start__ = .;\r
 129                 *(.stack)\r
 130                 . = MAX(__stack_start__ + _STACKSIZE , .);\r
 131         } >DATA\r
 132         __stack_end__ = __stack_start__ + SIZEOF(.stack);\r
 133 \r
 134         /* .stack_irq section */\r
 135         \r
 136         .stack_irq (__stack_end__ + 3) / 4 * 4 (NOLOAD) :\r
 137         {\r
 138                 __stack_irq_start__ = .;\r
 139                 *(.stack_irq)\r
 140                 . = MAX(__stack_irq_start__ + _STACKSIZE_IRQ , .);\r
 141         } >DATA\r
 142         __stack_irq_end__ = __stack_irq_start__ + SIZEOF(.stack_irq);\r
 143 \r
 144         /* .stack_fiq section */\r
 145         \r
 146         .stack_fiq (__stack_irq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 147         {\r
 148                 __stack_fiq_start__ = .;\r
 149                 *(.stack_fiq)\r
 150             . = MAX(__stack_fiq_start__ + _STACKSIZE_FIQ , .);\r
 151         } >DATA\r
 152         __stack_fiq_end__ = __stack_fiq_start__ + SIZEOF(.stack_fiq);\r
 153 \r
 154         /* .stack_svc section */\r
 155         \r
 156         .stack_svc (__stack_fiq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 157         {\r
 158                 __stack_svc_start__ = .;\r
 159                 *(.stack_svc)\r
 160                 . = MAX(__stack_svc_start__ + _STACKSIZE_SVC , .);\r
 161         } >DATA\r
 162         __stack_svc_end__ = __stack_svc_start__ + SIZEOF(.stack_svc);\r
 163 \r
 164         /* .stack_abt section */\r
 165         \r
 166         .stack_abt (__stack_svc_end__ + 3) / 4 * 4 (NOLOAD) :\r
 167         {\r
 168                 __stack_abt_start__ = .;\r
 169                 *(.stack_abt)\r
 170                 . = MAX(__stack_abt_start__ + _STACKSIZE_ABT , .);\r
 171         } >DATA\r
 172         __stack_abt_end__ = __stack_abt_start__ + SIZEOF(.stack_abt);\r
 173 \r
 174         /* .stack_und section */\r
 175         \r
 176         .stack_und (__stack_abt_end__ + 3) / 4 * 4 (NOLOAD) :\r
 177         {\r
 178                 __stack_und_start__ = .;\r
 179                 *(.stack_und)\r
 180         . = MAX(__stack_und_start__ + _STACKSIZE_UND , .);\r
 181         } >DATA\r
 182         __stack_und_end__ = __stack_und_start__ + SIZEOF(.stack_und);\r
 183         \r
 184         /* Stabs debugging sections.  */\r
 185         .stab          0 : { *(.stab) }\r
 186         .stabstr       0 : { *(.stabstr) }\r
 187         .stab.excl     0 : { *(.stab.excl) }\r
 188         .stab.exclstr  0 : { *(.stab.exclstr) }\r
 189         .stab.index    0 : { *(.stab.index) }\r
 190         .stab.indexstr 0 : { *(.stab.indexstr) }\r
 191         .comment       0 : { *(.comment) }\r
 192         /* DWARF debug sections.\r
 193                 Symbols in the DWARF debugging sections are relative to the beginning\r
 194                 of the section so we begin them at 0.  */\r
 195         /* DWARF 1 */\r
 196         .debug          0 : { *(.debug) }\r
 197         .line           0 : { *(.line) }\r
 198         /* GNU DWARF 1 extensions */\r
 199         .debug_srcinfo  0 : { *(.debug_srcinfo) }\r
 200         .debug_sfnames  0 : { *(.debug_sfnames) }\r
 201         /* DWARF 1.1 and DWARF 2 */\r
 202         .debug_aranges  0 : { *(.debug_aranges) }\r
 203         .debug_pubnames 0 : { *(.debug_pubnames) }\r
 204         /* DWARF 2 */\r
 205         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }\r
 206         .debug_abbrev   0 : { *(.debug_abbrev) }\r
 207         .debug_line     0 : { *(.debug_line) }\r
 208         .debug_frame    0 : { *(.debug_frame) }\r
 209         .debug_str      0 : { *(.debug_str) }\r
 210         .debug_loc      0 : { *(.debug_loc) }\r
 211         .debug_macinfo  0 : { *(.debug_macinfo) }\r
 212         /* SGI/MIPS DWARF 2 extensions */\r
 213         .debug_weaknames 0 : { *(.debug_weaknames) }\r
 214         .debug_funcnames 0 : { *(.debug_funcnames) }\r
 215         .debug_typenames 0 : { *(.debug_typenames) }\r
 216         .debug_varnames  0 : { *(.debug_varnames) }     \r
 217 }\r
 218 \r