MIPS: u-boot.lds: add relocation specific sections

This section contain the table needed for dynamic
relocation. Also provide symbols for the relocation
code to access the table.

Discard all sections which are not needed in the final
ELF binary and U-Boot image. Section .dynsym cannot be
discarded or GNU ld crashes otherwise. This section
will be stripped by GNU objcpy in a later patch.

Signed-off-by: Gabor Juhos <juhosg@openwrt.org>
Signed-off-by: Daniel Schwierzeck <daniel.schwierzeck@gmail.com>

diff --git a/arch/mips/cpu/u-boot.lds b/arch/mips/cpu/u-boot.lds
index 4cd983ae4f20865bb4f473eadcc40dace9190e1a..10513abd2c5c46e35d0f4d32438f0c57f3d8bb86 100644 (file)
--- a/arch/mips/cpu/u-boot.lds
+++ b/arch/mips/cpu/u-boot.lds
@@ -70,7 +70,35 @@ SECTIONS
        . = ALIGN(4);
        __image_copy_end = .;
 
-       .bss : {
+       .rel.dyn : {
+               __rel_dyn_start = .;
+               *(.rel.dyn)
+               __rel_dyn_end = .;
+       }
+
+       .deadcode : {
+               /*
+                * Workaround for a binutils feature (or bug?).
+                *
+                * The GNU ld from binutils puts the dynamic relocation
+                * entries into the .rel.dyn section. Sometimes it
+                * allocates more dynamic relocation entries than it needs
+                * and the unused slots are set to R_MIPS_NONE entries.
+                *
+                * However the size of the .rel.dyn section in the ELF
+                * section header does not cover the unused entries, so
+                * objcopy removes those during stripping.
+                *
+                * Create a small section here to avoid that.
+                */
+               LONG(0xffffffff);
+       }
+
+       .dynsym : {
+               *(.dynsym)
+       }
+
+       .bss __rel_dyn_start (OVERLAY) : {
                __bss_start = .;
                *(.sbss.*)
                *(.bss.*)
@@ -78,4 +106,16 @@ SECTIONS
                . = ALIGN(4);
                __bss_end = .;
        }
+
+       /DISCARD/ : {
+               *(.dynbss)
+               *(.dynstr)
+               *(.dynamic)
+               *(.interp)
+               *(.hash)
+               *(.gnu.*)
+               *(.plt)
+               *(.got.plt)
+               *(.rel.plt)
+       }
 }