git.sur5r.net Git - bacula/bacula/blob - bacula/src/qt-console/tray-monitor/tray-monitor.pro.in

   1 ######################################################################
   2 #
   3 #  !!!!!!! IMPORTANT !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   4 #
   5 #  Edit only tray-monitor.pro.in  -- tray-monitor.pro is built by the ./configure program
   6 #
   7 #  !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   8 #
   9 # CONFIG options for Windows are pulled from win32/qmake.conf
  10 CONFIG += qt
  11 #CONFIG += qt debug
  12
  13 cross-win32 {
  14   LIBS       +=  -mwindows -L../../win32/release32 -lbacula
  15   INCLUDEPATH += ../../win32/compat
  16 }
  17 !cross-win32 {
  18   LIBS        += -L../../lib -lbaccfg -lbac -L../../findlib -lbacfind @OPENSSL_LIBS@
  19 }
  20
  21
  22 bins.path = /$(DESTDIR)@sbindir@
  23 bins.files = bacula-tray-monitor
  24 confs.path = /$(DESTDIR)@sysconfdir@
  25 confs.commands = ./install_conf_file
  26
  27 TEMPLATE     = app
  28 TARGET       = bacula-tray-monitor
  29 DEPENDPATH  += .
  30 INCLUDEPATH += ../.. .
  31 LIBTOOL_LINK = @QMAKE_LIBTOOL@ --silent --tag=CXX --mode=link
  32 LIBTOOL_INSTALL = @QMAKE_LIBTOOL@ --silent --mode=install
  33 QMAKE_LINK   = $${LIBTOOL_LINK} $(CXX)
  34 QMAKE_INSTALL_PROGRAM = $${LIBTOOL_INSTALL} install -m @SBINPERM@ -p
  35 QMAKE_CLEAN += obj/* .libs/* bacula-tray-monitor release/bacula-tray-monitor
  36
  37 RESOURCES    = ../main.qrc
  38 MOC_DIR      = moc
  39 OBJECTS_DIR  = obj
  40 UI_DIR       = ui
  41
  42 # Main directory
  43 HEADERS += tray_conf.h  tray-monitor.h  tray-ui.h
  44 SOURCES += authenticate.cpp  tray_conf.cpp  tray-monitor.cpp
  45
  46 FORMS += ../run/run.ui