git.sur5r.net Git - cc65/blob - libsrc/atari/joy/atrstd.s

   1 ;
   2 ; Standard joystick driver for the Atari. May be used multiple times when linked
   3 ; to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2002-12-21
   6 ; Using the readjoy code from Christian Groessler
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "atari.inc"
  14
  15         .macpack        generic
  16         .macpack        module
  17
  18
  19 ; ------------------------------------------------------------------------
  20 ; Header. Includes jump table
  21
  22 .ifdef __ATARIXL__
  23         module_header   _atrxstd_joy
  24 .else
  25         module_header   _atrstd_joy
  26 .endif
  27
  28 ; Driver signature
  29
  30         .byte   $6A, $6F, $79           ; "joy"
  31         .byte   JOY_API_VERSION         ; Driver API version number
  32
  33 ; Library reference
  34
  35         .addr   $0000
  36
  37 ; Jump table.
  38
  39         .addr   INSTALL
  40         .addr   UNINSTALL
  41         .addr   COUNT
  42         .addr   READJOY
  43         .addr   0                       ; IRQ entry not used
  44
  45 ; ------------------------------------------------------------------------
  46 ; Constants
  47
  48 JOY_COUNT       = 4             ; Number of joysticks we support
  49
  50
  51 ; ------------------------------------------------------------------------
  52 ; Data.
  53
  54
  55 .code
  56
  57 ; ------------------------------------------------------------------------
  58 ; INSTALL routine. Is called after the driver is loaded into memory. If
  59 ; possible, check if the hardware is present and determine the amount of
  60 ; memory available.
  61 ; Must return an JOY_ERR_xx code in a/x.
  62 ;
  63
  64 INSTALL:
  65         lda     #JOY_ERR_OK
  66         ldx     #0
  67 ;       rts                     ; Run into UNINSTALL instead
  68
  69 ; ------------------------------------------------------------------------
  70 ; UNINSTALL routine. Is called before the driver is removed from memory.
  71 ; Can do cleanup or whatever. Must not return anything.
  72 ;
  73
  74 UNINSTALL:
  75         rts
  76
  77
  78 ; ------------------------------------------------------------------------
  79 ; COUNT: Return the total number of available joysticks in a/x.
  80 ;
  81
  82 COUNT:
  83         lda     #JOY_COUNT
  84         ldx     $fcd8
  85         cpx     #$a2
  86         beq     _400800
  87         lsr     a               ; XL and newer machines only have 2 ports
  88 _400800:
  89         ldx     #0
  90         rts
  91
  92 ; ------------------------------------------------------------------------
  93 ; READ: Read a particular joystick passed in A.
  94 ;
  95
  96 READJOY:
  97         and     #3              ; fix joystick number
  98         tax                     ; Joystick number (0-3) into X
  99
 100 ; Read joystick
 101
 102         lda     STRIG0,x        ; get button
 103         asl     a
 104         asl     a
 105         asl     a
 106         asl     a
 107         ora     STICK0,x        ; add position information
 108         eor     #$1F
 109         ldx     #0              ; fix X
 110         rts