git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/GCC/ARM_CR5/portASM.S

   1 /*\r
   2  * FreeRTOS Kernel V10.0.0\r
   3  * Copyright (C) 2017 Amazon.com, Inc. or its affiliates.  All Rights Reserved.\r
   4  *\r
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy of\r
   6  * this software and associated documentation files (the "Software"), to deal in\r
   7  * the Software without restriction, including without limitation the rights to\r
   8  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of\r
   9  * the Software, and to permit persons to whom the Software is furnished to do so,\r
  10  * subject to the following conditions:\r
  11  *\r
  12  * The above copyright notice and this permission notice shall be included in all\r
  13  * copies or substantial portions of the Software. If you wish to use our Amazon\r
  14  * FreeRTOS name, please do so in a fair use way that does not cause confusion.\r
  15  *\r
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR\r
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS\r
  18  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR\r
  19  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER\r
  20  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN\r
  21  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.\r
  22  *\r
  23  * http://www.FreeRTOS.org\r
  24  * http://aws.amazon.com/freertos\r
  25  *\r
  26  * 1 tab == 4 spaces!\r
  27  */\r
  28 \r
  29         .text\r
  30         .arm\r
  31 \r
  32         .set SYS_MODE,  0x1f\r
  33         .set SVC_MODE,  0x13\r
  34         .set IRQ_MODE,  0x12\r
  35 \r
  36         /* Hardware registers. */\r
  37         .extern ulICCIAR\r
  38         .extern ulICCEOIR\r
  39         .extern ulICCPMR\r
  40 \r
  41         /* Variables and functions. */\r
  42         .extern ulMaxAPIPriorityMask\r
  43         .extern _freertos_vector_table\r
  44         .extern pxCurrentTCB\r
  45         .extern vTaskSwitchContext\r
  46         .extern vApplicationIRQHandler\r
  47         .extern ulPortInterruptNesting\r
  48         .extern ulPortTaskHasFPUContext\r
  49 \r
  50         .global FreeRTOS_IRQ_Handler\r
  51         .global FreeRTOS_SWI_Handler\r
  52         .global vPortRestoreTaskContext\r
  53 \r
  54 .macro portSAVE_CONTEXT\r
  55 \r
  56         /* Save the LR and SPSR onto the system mode stack before switching to\r
  57         system mode to save the remaining system mode registers. */\r
  58         SRSDB   sp!, #SYS_MODE\r
  59         CPS             #SYS_MODE\r
  60         PUSH    {R0-R12, R14}\r
  61 \r
  62         /* Push the critical nesting count. */\r
  63         LDR             R2, ulCriticalNestingConst\r
  64         LDR             R1, [R2]\r
  65         PUSH    {R1}\r
  66 \r
  67         /* Does the task have a floating point context that needs saving?  If\r
  68         ulPortTaskHasFPUContext is 0 then no. */\r
  69         LDR             R2, ulPortTaskHasFPUContextConst\r
  70         LDR             R3, [R2]\r
  71         CMP             R3, #0\r
  72 \r
  73         /* Save the floating point context, if any. */\r
  74         FMRXNE  R1,  FPSCR\r
  75         VPUSHNE {D0-D15}\r
  76         /*VPUSHNE       {D16-D31}*/\r
  77         PUSHNE  {R1}\r
  78 \r
  79         /* Save ulPortTaskHasFPUContext itself. */\r
  80         PUSH    {R3}\r
  81 \r
  82         /* Save the stack pointer in the TCB. */\r
  83         LDR             R0, pxCurrentTCBConst\r
  84         LDR             R1, [R0]\r
  85         STR             SP, [R1]\r
  86 \r
  87         .endm\r
  88 \r
  89 ; /**********************************************************************/\r
  90 \r
  91 .macro portRESTORE_CONTEXT\r
  92 \r
  93         /* Set the SP to point to the stack of the task being restored. */\r
  94         LDR             R0, pxCurrentTCBConst\r
  95         LDR             R1, [R0]\r
  96         LDR             SP, [R1]\r
  97 \r
  98         /* Is there a floating point context to restore?  If the restored\r
  99         ulPortTaskHasFPUContext is zero then no. */\r
 100         LDR             R0, ulPortTaskHasFPUContextConst\r
 101         POP             {R1}\r
 102         STR             R1, [R0]\r
 103         CMP             R1, #0\r
 104 \r
 105         /* Restore the floating point context, if any. */\r
 106         POPNE   {R0}\r
 107         /*VPOPNE        {D16-D31}*/\r
 108         VPOPNE  {D0-D15}\r
 109         VMSRNE  FPSCR, R0\r
 110 \r
 111         /* Restore the critical section nesting depth. */\r
 112         LDR             R0, ulCriticalNestingConst\r
 113         POP             {R1}\r
 114         STR             R1, [R0]\r
 115 \r
 116         /* Ensure the priority mask is correct for the critical nesting depth. */\r
 117         LDR             R2, ulICCPMRConst\r
 118         LDR             R2, [R2]\r
 119         CMP             R1, #0\r
 120         MOVEQ   R4, #255\r
 121         LDRNE   R4, ulMaxAPIPriorityMaskConst\r
 122         LDRNE   R4, [R4]\r
 123         STR             R4, [R2]\r
 124 \r
 125         /* Restore all system mode registers other than the SP (which is already\r
 126         being used). */\r
 127         POP             {R0-R12, R14}\r
 128 \r
 129         /* Return to the task code, loading CPSR on the way. */\r
 130         RFEIA   sp!\r
 131 \r
 132         .endm\r
 133 \r
 134 \r
 135 \r
 136 \r
 137 /******************************************************************************\r
 138  * SVC handler is used to start the scheduler.\r
 139  *****************************************************************************/\r
 140 .align 4\r
 141 .type FreeRTOS_SWI_Handler, %function\r
 142 FreeRTOS_SWI_Handler:\r
 143         /* Save the context of the current task and select a new task to run. */\r
 144         portSAVE_CONTEXT\r
 145         LDR R0, vTaskSwitchContextConst\r
 146         BLX     R0\r
 147         portRESTORE_CONTEXT\r
 148 \r
 149 \r
 150 /******************************************************************************\r
 151  * vPortRestoreTaskContext is used to start the scheduler.\r
 152  *****************************************************************************/\r
 153 .type vPortRestoreTaskContext, %function\r
 154 vPortRestoreTaskContext:\r
 155         /* Switch to system mode. */\r
 156         CPS             #SYS_MODE\r
 157         portRESTORE_CONTEXT\r
 158 \r
 159 .align 4\r
 160 .type FreeRTOS_IRQ_Handler, %function\r
 161 FreeRTOS_IRQ_Handler:\r
 162 \r
 163         /* Return to the interrupted instruction. */\r
 164         SUB             lr, lr, #4\r
 165 \r
 166         /* Push the return address and SPSR. */\r
 167         PUSH    {lr}\r
 168         MRS             lr, SPSR\r
 169         PUSH    {lr}\r
 170 \r
 171         /* Change to supervisor mode to allow reentry. */\r
 172         CPS             #SVC_MODE\r
 173 \r
 174         /* Push used registers. */\r
 175         PUSH    {r0-r4, r12}\r
 176 \r
 177         /* Increment nesting count.  r3 holds the address of ulPortInterruptNesting\r
 178         for future use.  r1 holds the original ulPortInterruptNesting value for\r
 179         future use. */\r
 180         LDR             r3, ulPortInterruptNestingConst\r
 181         LDR             r1, [r3]\r
 182         ADD             r4, r1, #1\r
 183         STR             r4, [r3]\r
 184 \r
 185         /* Read value from the interrupt acknowledge register, which is stored in r0\r
 186         for future parameter and interrupt clearing use. */\r
 187         LDR     r2, ulICCIARConst\r
 188         LDR             r2, [r2]\r
 189         LDR             r0, [r2]\r
 190 \r
 191         /* Ensure bit 2 of the stack pointer is clear.  r2 holds the bit 2 value for\r
 192         future use.  _RB_ Is this ever needed provided the start of the stack is\r
 193         alligned on an 8-byte boundary? */\r
 194         MOV             r2, sp\r
 195         AND             r2, r2, #4\r
 196         SUB             sp, sp, r2\r
 197 \r
 198         /* Call the interrupt handler. */\r
 199         PUSH    {r0-r4, lr}\r
 200         LDR             r1, vApplicationIRQHandlerConst\r
 201         BLX             r1\r
 202         POP             {r0-r4, lr}\r
 203         ADD             sp, sp, r2\r
 204 \r
 205         CPSID   i\r
 206         DSB\r
 207         ISB\r
 208 \r
 209         /* Write the value read from ICCIAR to ICCEOIR. */\r
 210         LDR     r4, ulICCEOIRConst\r
 211         LDR             r4, [r4]\r
 212         STR             r0, [r4]\r
 213 \r
 214         /* Restore the old nesting count. */\r
 215         STR             r1, [r3]\r
 216 \r
 217         /* A context switch is never performed if the nesting count is not 0. */\r
 218         CMP             r1, #0\r
 219         BNE             exit_without_switch\r
 220 \r
 221         /* Did the interrupt request a context switch?  r1 holds the address of\r
 222         ulPortYieldRequired and r0 the value of ulPortYieldRequired for future\r
 223         use. */\r
 224         LDR             r1, =ulPortYieldRequired\r
 225         LDR             r0, [r1]\r
 226         CMP             r0, #0\r
 227         BNE             switch_before_exit\r
 228 \r
 229 exit_without_switch:\r
 230         /* No context switch.  Restore used registers, LR_irq and SPSR before\r
 231         returning. */\r
 232         POP             {r0-r4, r12}\r
 233         CPS             #IRQ_MODE\r
 234         POP             {LR}\r
 235         MSR             SPSR_cxsf, LR\r
 236         POP             {LR}\r
 237         MOVS    PC, LR\r
 238 \r
 239 switch_before_exit:\r
 240         /* A context swtich is to be performed.  Clear the context switch pending\r
 241         flag. */\r
 242         MOV             r0, #0\r
 243         STR             r0, [r1]\r
 244 \r
 245         /* Restore used registers, LR-irq and SPSR before saving the context\r
 246         to the task stack. */\r
 247         POP             {r0-r4, r12}\r
 248         CPS             #IRQ_MODE\r
 249         POP             {LR}\r
 250         MSR             SPSR_cxsf, LR\r
 251         POP             {LR}\r
 252         portSAVE_CONTEXT\r
 253 \r
 254         /* Call the function that selects the new task to execute.\r
 255         vTaskSwitchContext() if vTaskSwitchContext() uses LDRD or STRD\r
 256         instructions, or 8 byte aligned stack allocated data.  LR does not need\r
 257         saving as a new LR will be loaded by portRESTORE_CONTEXT anyway. */\r
 258         LDR             R0, vTaskSwitchContextConst\r
 259         BLX             R0\r
 260 \r
 261         /* Restore the context of, and branch to, the task selected to execute\r
 262         next. */\r
 263         portRESTORE_CONTEXT\r
 264 \r
 265 ulICCIARConst:  .word ulICCIAR\r
 266 ulICCEOIRConst: .word ulICCEOIR\r
 267 ulICCPMRConst: .word ulICCPMR\r
 268 pxCurrentTCBConst: .word pxCurrentTCB\r
 269 ulCriticalNestingConst: .word ulCriticalNesting\r
 270 ulPortTaskHasFPUContextConst: .word ulPortTaskHasFPUContext\r
 271 ulMaxAPIPriorityMaskConst: .word ulMaxAPIPriorityMask\r
 272 vTaskSwitchContextConst: .word vTaskSwitchContext\r
 273 vApplicationIRQHandlerConst: .word vApplicationIRQHandler\r
 274 ulPortInterruptNestingConst: .word ulPortInterruptNesting\r
 275 \r
 276 .end\r
 277 \r
 278 \r
 279 \r
 280 \r
 281 \r