git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/GCC/ARM_CRx_No_GIC/portASM.S

   1 /*\r
   2     FreeRTOS V9.0.0rc2 - Copyright (C) 2016 Real Time Engineers Ltd.\r
   3     All rights reserved\r
   4 \r
   5 \r
   6     ***************************************************************************\r
   7      *                                                                       *\r
   8      *    FreeRTOS tutorial books are available in pdf and paperback.        *\r
   9      *    Complete, revised, and edited pdf reference manuals are also       *\r
  10      *    available.                                                         *\r
  11      *                                                                       *\r
  12      *    Purchasing FreeRTOS documentation will not only help you, by       *\r
  13      *    ensuring you get running as quickly as possible and with an        *\r
  14      *    in-depth knowledge of how to use FreeRTOS, it will also help       *\r
  15      *    the FreeRTOS project to continue with its mission of providing     *\r
  16      *    professional grade, cross platform, de facto standard solutions    *\r
  17      *    for microcontrollers - completely free of charge!                  *\r
  18      *                                                                       *\r
  19      *    >>> See http://www.FreeRTOS.org/Documentation for details. <<<     *\r
  20      *                                                                       *\r
  21      *    Thank you for using FreeRTOS, and thank you for your support!      *\r
  22      *                                                                       *\r
  23     ***************************************************************************\r
  24 \r
  25 \r
  26     This file is part of the FreeRTOS distribution.\r
  27 \r
  28     FreeRTOS is free software; you can redistribute it and/or modify it under\r
  29     the terms of the GNU General Public License (version 2) as published by the\r
  30     Free Software Foundation AND MODIFIED BY the FreeRTOS exception.\r
  31     >>>NOTE<<< The modification to the GPL is included to allow you to\r
  32     distribute a combined work that includes FreeRTOS without being obliged to\r
  33     provide the source code for proprietary components outside of the FreeRTOS\r
  34     kernel.  FreeRTOS is distributed in the hope that it will be useful, but\r
  35     WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY\r
  36     or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for\r
  37     more details. You should have received a copy of the GNU General Public\r
  38     License and the FreeRTOS license exception along with FreeRTOS; if not it\r
  39     can be viewed here: http://www.freertos.org/a00114.html and also obtained\r
  40     by writing to Richard Barry, contact details for whom are available on the\r
  41     FreeRTOS WEB site.\r
  42 \r
  43     1 tab == 4 spaces!\r
  44 \r
  45     http://www.FreeRTOS.org - Documentation, latest information, license and\r
  46     contact details.\r
  47 \r
  48     http://www.SafeRTOS.com - A version that is certified for use in safety\r
  49     critical systems.\r
  50 \r
  51     http://www.OpenRTOS.com - Commercial support, development, porting,\r
  52     licensing and training services.\r
  53 */\r
  54 \r
  55         .text\r
  56         .arm\r
  57 \r
  58         .set SYS_MODE,  0x1f\r
  59         .set SVC_MODE,  0x13\r
  60         .set IRQ_MODE,  0x12\r
  61 \r
  62         /* Variables and functions. */\r
  63         .extern ulMaxAPIPriorityMask\r
  64         .extern _freertos_vector_table\r
  65         .extern pxCurrentTCB\r
  66         .extern vTaskSwitchContext\r
  67         .extern vApplicationIRQHandler\r
  68         .extern ulPortInterruptNesting\r
  69         .extern ulPortTaskHasFPUContext\r
  70         .extern ulICCEOIR\r
  71         .extern ulPortYieldRequired\r
  72 \r
  73         .global FreeRTOS_IRQ_Handler\r
  74         .global FreeRTOS_SVC_Handler\r
  75         .global vPortRestoreTaskContext\r
  76 \r
  77 \r
  78 .macro portSAVE_CONTEXT\r
  79 \r
  80         /* Save the LR and SPSR onto the system mode stack before switching to\r
  81         system mode to save the remaining system mode registers. */\r
  82         SRSDB   sp!, #SYS_MODE\r
  83         CPS             #SYS_MODE\r
  84         PUSH    {R0-R12, R14}\r
  85 \r
  86         /* Push the critical nesting count. */\r
  87         LDR             R2, ulCriticalNestingConst\r
  88         LDR             R1, [R2]\r
  89         PUSH    {R1}\r
  90 \r
  91         /* Does the task have a floating point context that needs saving?  If\r
  92         ulPortTaskHasFPUContext is 0 then no. */\r
  93         LDR             R2, ulPortTaskHasFPUContextConst\r
  94         LDR             R3, [R2]\r
  95         CMP             R3, #0\r
  96 \r
  97         /* Save the floating point context, if any. */\r
  98         FMRXNE  R1,  FPSCR\r
  99         VPUSHNE {D0-D15}\r
 100 #if configFPU_D32 == 1\r
 101         VPUSHNE {D16-D31}\r
 102 #endif /* configFPU_D32 */\r
 103         PUSHNE  {R1}\r
 104 \r
 105         /* Save ulPortTaskHasFPUContext itself. */\r
 106         PUSH    {R3}\r
 107 \r
 108         /* Save the stack pointer in the TCB. */\r
 109         LDR             R0, pxCurrentTCBConst\r
 110         LDR             R1, [R0]\r
 111         STR             SP, [R1]\r
 112 \r
 113         .endm\r
 114 \r
 115 ; /**********************************************************************/\r
 116 \r
 117 .macro portRESTORE_CONTEXT\r
 118 \r
 119         /* Set the SP to point to the stack of the task being restored. */\r
 120         LDR             R0, pxCurrentTCBConst\r
 121         LDR             R1, [R0]\r
 122         LDR             SP, [R1]\r
 123 \r
 124         /* Is there a floating point context to restore?  If the restored\r
 125         ulPortTaskHasFPUContext is zero then no. */\r
 126         LDR             R0, ulPortTaskHasFPUContextConst\r
 127         POP             {R1}\r
 128         STR             R1, [R0]\r
 129         CMP             R1, #0\r
 130 \r
 131         /* Restore the floating point context, if any. */\r
 132         POPNE   {R0}\r
 133 #if configFPU_D32 == 1\r
 134         VPOPNE  {D16-D31}\r
 135 #endif /* configFPU_D32 */\r
 136         VPOPNE  {D0-D15}\r
 137         VMSRNE  FPSCR, R0\r
 138 \r
 139         /* Restore the critical section nesting depth. */\r
 140         LDR             R0, ulCriticalNestingConst\r
 141         POP             {R1}\r
 142         STR             R1, [R0]\r
 143 \r
 144         /* Restore all system mode registers other than the SP (which is already\r
 145         being used). */\r
 146         POP             {R0-R12, R14}\r
 147 \r
 148         /* Return to the task code, loading CPSR on the way. */\r
 149         RFEIA   sp!\r
 150 \r
 151         .endm\r
 152 \r
 153 \r
 154 \r
 155 \r
 156 /******************************************************************************\r
 157  * SVC handler is used to yield.\r
 158  *****************************************************************************/\r
 159 .align 4\r
 160 .type FreeRTOS_SVC_Handler, %function\r
 161 FreeRTOS_SVC_Handler:\r
 162         /* Save the context of the current task and select a new task to run. */\r
 163         portSAVE_CONTEXT\r
 164         LDR R0, vTaskSwitchContextConst\r
 165         BLX     R0\r
 166         portRESTORE_CONTEXT\r
 167 \r
 168 \r
 169 /******************************************************************************\r
 170  * vPortRestoreTaskContext is used to start the scheduler.\r
 171  *****************************************************************************/\r
 172 .align 4\r
 173 .type vPortRestoreTaskContext, %function\r
 174 vPortRestoreTaskContext:\r
 175         /* Switch to system mode. */\r
 176         CPS             #SYS_MODE\r
 177         portRESTORE_CONTEXT\r
 178 \r
 179 .align 4\r
 180 .type FreeRTOS_IRQ_Handler, %function\r
 181 FreeRTOS_IRQ_Handler:\r
 182         /* Return to the interrupted instruction. */\r
 183         SUB             lr, lr, #4\r
 184 \r
 185         /* Push the return address and SPSR. */\r
 186         PUSH    {lr}\r
 187         MRS             lr, SPSR\r
 188         PUSH    {lr}\r
 189 \r
 190         /* Change to supervisor mode to allow reentry. */\r
 191         CPS             #0x13\r
 192 \r
 193         /* Push used registers. */\r
 194         PUSH    {r0-r3, r12}\r
 195 \r
 196         /* Increment nesting count.  r3 holds the address of ulPortInterruptNesting\r
 197         for future use.  r1 holds the original ulPortInterruptNesting value for\r
 198         future use. */\r
 199         LDR             r3, ulPortInterruptNestingConst\r
 200         LDR             r1, [r3]\r
 201         ADD             r0, r1, #1\r
 202         STR             r0, [r3]\r
 203 \r
 204         /* Ensure bit 2 of the stack pointer is clear.  r2 holds the bit 2 value for\r
 205         future use. */\r
 206         MOV             r0, sp\r
 207         AND             r2, r0, #4\r
 208         SUB             sp, sp, r2\r
 209 \r
 210         /* Call the interrupt handler. */\r
 211         PUSH    {r0-r3, lr}\r
 212         LDR             r1, vApplicationIRQHandlerConst\r
 213         BLX             r1\r
 214         POP             {r0-r3, lr}\r
 215         ADD             sp, sp, r2\r
 216 \r
 217         CPSID   i\r
 218         DSB\r
 219         ISB\r
 220 \r
 221         /* Write to the EOI register. */\r
 222         LDR     r0, ulICCEOIRConst\r
 223         LDR             r2, [r0]\r
 224         STR             r0, [r2]\r
 225 \r
 226         /* Restore the old nesting count. */\r
 227         STR             r1, [r3]\r
 228 \r
 229         /* A context switch is never performed if the nesting count is not 0. */\r
 230         CMP             r1, #0\r
 231         BNE             exit_without_switch\r
 232 \r
 233         /* Did the interrupt request a context switch?  r1 holds the address of\r
 234         ulPortYieldRequired and r0 the value of ulPortYieldRequired for future\r
 235         use. */\r
 236         LDR             r1, ulPortYieldRequiredConst\r
 237         LDR             r0, [r1]\r
 238         CMP             r0, #0\r
 239         BNE             switch_before_exit\r
 240 \r
 241 exit_without_switch:\r
 242         /* No context switch.  Restore used registers, LR_irq and SPSR before\r
 243         returning. */\r
 244         POP             {r0-r3, r12}\r
 245         CPS             #IRQ_MODE\r
 246         POP             {LR}\r
 247         MSR             SPSR_cxsf, LR\r
 248         POP             {LR}\r
 249         MOVS    PC, LR\r
 250 \r
 251 switch_before_exit:\r
 252         /* A context swtich is to be performed.  Clear the context switch pending\r
 253         flag. */\r
 254         MOV             r0, #0\r
 255         STR             r0, [r1]\r
 256 \r
 257         /* Restore used registers, LR-irq and SPSR before saving the context\r
 258         to the task stack. */\r
 259         POP             {r0-r3, r12}\r
 260         CPS             #IRQ_MODE\r
 261         POP             {LR}\r
 262         MSR             SPSR_cxsf, LR\r
 263         POP             {LR}\r
 264         portSAVE_CONTEXT\r
 265 \r
 266         /* Call the function that selects the new task to execute.\r
 267         vTaskSwitchContext() if vTaskSwitchContext() uses LDRD or STRD\r
 268         instructions, or 8 byte aligned stack allocated data.  LR does not need\r
 269         saving as a new LR will be loaded by portRESTORE_CONTEXT anyway. */\r
 270         LDR             R0, vTaskSwitchContextConst\r
 271         BLX             R0\r
 272 \r
 273         /* Restore the context of, and branch to, the task selected to execute\r
 274         next. */\r
 275         portRESTORE_CONTEXT\r
 276 \r
 277 ulICCEOIRConst: .word ulICCEOIR\r
 278 pxCurrentTCBConst: .word pxCurrentTCB\r
 279 ulCriticalNestingConst: .word ulCriticalNesting\r
 280 ulPortTaskHasFPUContextConst: .word ulPortTaskHasFPUContext\r
 281 vTaskSwitchContextConst: .word vTaskSwitchContext\r
 282 vApplicationIRQHandlerConst: .word vApplicationIRQHandler\r
 283 ulPortInterruptNestingConst: .word ulPortInterruptNesting\r
 284 ulPortYieldRequiredConst: .word ulPortYieldRequired\r
 285 \r
 286 .end\r
 287 \r
 288 \r
 289 \r
 290 \r
 291 \r