git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/IAR/ARM_CM23/secure/secure_context_port_asm.s

   1 /*\r
   2  * FreeRTOS Kernel V10.2.0\r
   3  * Copyright (C) 2019 Amazon.com, Inc. or its affiliates.  All Rights Reserved.\r
   4  *\r
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy of\r
   6  * this software and associated documentation files (the "Software"), to deal in\r
   7  * the Software without restriction, including without limitation the rights to\r
   8  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of\r
   9  * the Software, and to permit persons to whom the Software is furnished to do so,\r
  10  * subject to the following conditions:\r
  11  *\r
  12  * The above copyright notice and this permission notice shall be included in all\r
  13  * copies or substantial portions of the Software.\r
  14  *\r
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR\r
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS\r
  17  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR\r
  18  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER\r
  19  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN\r
  20  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.\r
  21  *\r
  22  * http://www.FreeRTOS.org\r
  23  * http://aws.amazon.com/freertos\r
  24  *\r
  25  * 1 tab == 4 spaces!\r
  26  */\r
  27 \r
  28         SECTION .text:CODE:NOROOT(2)\r
  29         THUMB\r
  30 \r
  31         PUBLIC SecureContext_LoadContextAsm\r
  32         PUBLIC SecureContext_SaveContextAsm\r
  33 \r
  34 #if ( configENABLE_FPU == 1 )\r
  35         #error Cortex-M23 does not have a Floating Point Unit (FPU) and therefore configENABLE_FPU must be set to 0.\r
  36 #endif\r
  37 /*-----------------------------------------------------------*/\r
  38 \r
  39 SecureContext_LoadContextAsm:\r
  40         /* xSecureContextHandle value is in r0. */\r
  41         mrs r1, ipsr                                                    /* r1 = IPSR. */\r
  42         cbz r1, load_ctx_therad_mode                    /* Do nothing if the processor is running in the Thread Mode. */\r
  43         ldmia r0!, {r1, r2}                                             /* r1 = xSecureContextHandle->pucCurrentStackPointer, r2 = xSecureContextHandle->pucStackLimit. */\r
  44 #if ( configENABLE_MPU == 1 )\r
  45         ldmia r1!, {r3}                                                 /* Read CONTROL register value from task's stack. r3 = CONTROL. */\r
  46         msr control, r3                                                 /* CONTROL = r3. */\r
  47 #endif /* configENABLE_MPU */\r
  48         msr psplim, r2                                                  /* PSPLIM = r2. */\r
  49         msr psp, r1                                                             /* PSP = r1. */\r
  50 \r
  51         load_ctx_therad_mode:\r
  52                 bx lr\r
  53 /*-----------------------------------------------------------*/\r
  54 \r
  55 SecureContext_SaveContextAsm:\r
  56         /* xSecureContextHandle value is in r0. */\r
  57         mrs r1, ipsr                                                    /* r1 = IPSR. */\r
  58         cbz r1, save_ctx_therad_mode                    /* Do nothing if the processor is running in the Thread Mode. */\r
  59         mrs r1, psp                                                             /* r1 = PSP. */\r
  60 #if ( configENABLE_MPU == 1 )\r
  61         mrs r2, control                                                 /* r2 = CONTROL. */\r
  62         subs r1, r1, #4                                                 /* Make space for the CONTROL value on the stack. */\r
  63         str r1, [r0]                                                    /* Save the top of stack in context. xSecureContextHandle->pucCurrentStackPointer = r1. */\r
  64         stmia r1!, {r2}                                                 /* Store CONTROL value on the stack. */\r
  65 #else /* configENABLE_MPU */\r
  66         str r1, [r0]                                                    /* Save the top of stack in context. xSecureContextHandle->pucCurrentStackPointer = r1. */\r
  67 #endif /* configENABLE_MPU */\r
  68         movs r1, #0                                                             /* r1 = securecontextNO_STACK. */\r
  69         msr psplim, r1                                                  /* PSPLIM = securecontextNO_STACK. */\r
  70         msr psp, r1                                                             /* PSP = securecontextNO_STACK i.e. No stack for thread mode until next task's context is loaded. */\r
  71 \r
  72         save_ctx_therad_mode:\r
  73                 bx lr\r
  74 /*-----------------------------------------------------------*/\r
  75 \r
  76         END\r