git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/IAR/ARM_CM33/non_secure/portasm.s

   1 /*\r
   2  * FreeRTOS Kernel V10.2.1\r
   3  * Copyright (C) 2019 Amazon.com, Inc. or its affiliates.  All Rights Reserved.\r
   4  *\r
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy of\r
   6  * this software and associated documentation files (the "Software"), to deal in\r
   7  * the Software without restriction, including without limitation the rights to\r
   8  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of\r
   9  * the Software, and to permit persons to whom the Software is furnished to do so,\r
  10  * subject to the following conditions:\r
  11  *\r
  12  * The above copyright notice and this permission notice shall be included in all\r
  13  * copies or substantial portions of the Software.\r
  14  *\r
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR\r
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS\r
  17  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR\r
  18  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER\r
  19  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN\r
  20  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.\r
  21  *\r
  22  * http://www.FreeRTOS.org\r
  23  * http://aws.amazon.com/freertos\r
  24  *\r
  25  * 1 tab == 4 spaces!\r
  26  */\r
  27 \r
  28 /* Including FreeRTOSConfig.h here will cause build errors if the header file\r
  29 contains code not understood by the assembler - for example the 'extern' keyword.\r
  30 To avoid errors place any such code inside a #ifdef __ICCARM__/#endif block so\r
  31 the code is included in C files but excluded by the preprocessor in assembly\r
  32 files (__ICCARM__ is defined by the IAR C compiler but not by the IAR assembler. */\r
  33 #include "FreeRTOSConfig.h"\r
  34 \r
  35         EXTERN pxCurrentTCB\r
  36         EXTERN xSecureContext\r
  37         EXTERN vTaskSwitchContext\r
  38         EXTERN vPortSVCHandler_C\r
  39         EXTERN SecureContext_SaveContext\r
  40         EXTERN SecureContext_LoadContext\r
  41 \r
  42         PUBLIC xIsPrivileged\r
  43         PUBLIC vResetPrivilege\r
  44         PUBLIC vPortAllocateSecureContext\r
  45         PUBLIC vRestoreContextOfFirstTask\r
  46         PUBLIC vRaisePrivilege\r
  47         PUBLIC vStartFirstTask\r
  48         PUBLIC ulSetInterruptMask\r
  49         PUBLIC vClearInterruptMask\r
  50         PUBLIC PendSV_Handler\r
  51         PUBLIC SVC_Handler\r
  52         PUBLIC vPortFreeSecureContext\r
  53 /*-----------------------------------------------------------*/\r
  54 \r
  55 /*---------------- Unprivileged Functions -------------------*/\r
  56 \r
  57 /*-----------------------------------------------------------*/\r
  58 \r
  59         SECTION .text:CODE:NOROOT(2)\r
  60         THUMB\r
  61 /*-----------------------------------------------------------*/\r
  62 \r
  63 xIsPrivileged:\r
  64         mrs r0, control                                                 /* r0 = CONTROL. */\r
  65         tst r0, #1                                                              /* Perform r0 & 1 (bitwise AND) and update the conditions flag. */\r
  66         ite ne\r
  67         movne r0, #0                                                    /* CONTROL[0]!=0. Return false to indicate that the processor is not privileged. */\r
  68         moveq r0, #1                                                    /* CONTROL[0]==0. Return true to indicate that the processor is not privileged. */\r
  69         bx lr                                                                   /* Return. */\r
  70 /*-----------------------------------------------------------*/\r
  71 \r
  72 vResetPrivilege:\r
  73         mrs r0, control                                                 /* r0 = CONTROL. */\r
  74         orr r0, r0, #1                                                  /* r0 = r0 | 1. */\r
  75         msr control, r0                                                 /* CONTROL = r0. */\r
  76         bx lr                                                                   /* Return to the caller. */\r
  77 /*-----------------------------------------------------------*/\r
  78 \r
  79 vPortAllocateSecureContext:\r
  80         svc 0                                                                   /* Secure context is allocated in the supervisor call. portSVC_ALLOCATE_SECURE_CONTEXT = 0. */\r
  81         bx lr                                                                   /* Return. */\r
  82 /*-----------------------------------------------------------*/\r
  83 \r
  84 /*----------------- Privileged Functions --------------------*/\r
  85 \r
  86 /*-----------------------------------------------------------*/\r
  87 \r
  88         SECTION privileged_functions:CODE:NOROOT(2)\r
  89         THUMB\r
  90 /*-----------------------------------------------------------*/\r
  91 \r
  92 vRestoreContextOfFirstTask:\r
  93         ldr  r2, =pxCurrentTCB                                  /* Read the location of pxCurrentTCB i.e. &( pxCurrentTCB ). */\r
  94         ldr  r3, [r2]                                                   /* Read pxCurrentTCB. */\r
  95         ldr  r0, [r3]                                                   /* Read top of stack from TCB - The first item in pxCurrentTCB is the task top of stack. */\r
  96 \r
  97 #if ( configENABLE_MPU == 1 )\r
  98         dmb                                                                             /* Complete outstanding transfers before disabling MPU. */\r
  99         ldr r2, =0xe000ed94                                             /* r2 = 0xe000ed94 [Location of MPU_CTRL]. */\r
 100         ldr r4, [r2]                                                    /* Read the value of MPU_CTRL. */\r
 101         bic r4, r4, #1                                                  /* r4 = r4 & ~1 i.e. Clear the bit 0 in r4. */\r
 102         str r4, [r2]                                                    /* Disable MPU. */\r
 103 \r
 104         adds r3, #4                                                             /* r3 = r3 + 4. r3 now points to MAIR0 in TCB. */\r
 105         ldr  r4, [r3]                                                   /* r4 = *r3 i.e. r4 = MAIR0. */\r
 106         ldr  r2, =0xe000edc0                                    /* r2 = 0xe000edc0 [Location of MAIR0]. */\r
 107         str  r4, [r2]                                                   /* Program MAIR0. */\r
 108         ldr  r2, =0xe000ed98                                    /* r2 = 0xe000ed98 [Location of RNR]. */\r
 109         movs r4, #4                                                             /* r4 = 4. */\r
 110         str  r4, [r2]                                                   /* Program RNR = 4. */\r
 111         adds r3, #4                                                             /* r3 = r3 + 4. r3 now points to first RBAR in TCB. */\r
 112         ldr  r2, =0xe000ed9c                                    /* r2 = 0xe000ed9c [Location of RBAR]. */\r
 113         ldmia r3!, {r4-r11}                                             /* Read 4 set of RBAR/RLAR registers from TCB. */\r
 114         stmia r2!, {r4-r11}                                             /* Write 4 set of RBAR/RLAR registers using alias registers. */\r
 115 \r
 116         ldr r2, =0xe000ed94                                             /* r2 = 0xe000ed94 [Location of MPU_CTRL]. */\r
 117         ldr r4, [r2]                                                    /* Read the value of MPU_CTRL. */\r
 118         orr r4, r4, #1                                                  /* r4 = r4 | 1 i.e. Set the bit 0 in r4. */\r
 119         str r4, [r2]                                                    /* Enable MPU. */\r
 120         dsb                                                                             /* Force memory writes before continuing. */\r
 121 #endif /* configENABLE_MPU */\r
 122 \r
 123 #if ( configENABLE_MPU == 1 )\r
 124         ldm  r0!, {r1-r4}                                               /* Read from stack - r1 = xSecureContext, r2 = PSPLIM, r3 = CONTROL and r4 = EXC_RETURN. */\r
 125         ldr  r5, =xSecureContext\r
 126         str  r1, [r5]                                                   /* Set xSecureContext to this task's value for the same. */\r
 127         msr  psplim, r2                                                 /* Set this task's PSPLIM value. */\r
 128         msr  control, r3                                                /* Set this task's CONTROL value. */\r
 129         adds r0, #32                                                    /* Discard everything up to r0. */\r
 130         msr  psp, r0                                                    /* This is now the new top of stack to use in the task. */\r
 131         isb\r
 132         bx   r4                                                                 /* Finally, branch to EXC_RETURN. */\r
 133 #else /* configENABLE_MPU */\r
 134         ldm  r0!, {r1-r3}                                               /* Read from stack - r1 = xSecureContext, r2 = PSPLIM and r3 = EXC_RETURN. */\r
 135         ldr  r4, =xSecureContext\r
 136         str  r1, [r4]                                                   /* Set xSecureContext to this task's value for the same. */\r
 137         msr  psplim, r2                                                 /* Set this task's PSPLIM value. */\r
 138         movs r1, #2                                                             /* r1 = 2. */\r
 139         msr  CONTROL, r1                                                /* Switch to use PSP in the thread mode. */\r
 140         adds r0, #32                                                    /* Discard everything up to r0. */\r
 141         msr  psp, r0                                                    /* This is now the new top of stack to use in the task. */\r
 142         isb\r
 143         bx   r3                                                                 /* Finally, branch to EXC_RETURN. */\r
 144 #endif /* configENABLE_MPU */\r
 145 /*-----------------------------------------------------------*/\r
 146 \r
 147 vRaisePrivilege:\r
 148         mrs  r0, control                                                /* Read the CONTROL register. */\r
 149         bic r0, r0, #1                                                  /* Clear the bit 0. */\r
 150         msr  control, r0                                                /* Write back the new CONTROL value. */\r
 151         bx lr                                                                   /* Return to the caller. */\r
 152 /*-----------------------------------------------------------*/\r
 153 \r
 154 vStartFirstTask:\r
 155         ldr r0, =0xe000ed08                                             /* Use the NVIC offset register to locate the stack. */\r
 156         ldr r0, [r0]                                                    /* Read the VTOR register which gives the address of vector table. */\r
 157         ldr r0, [r0]                                                    /* The first entry in vector table is stack pointer. */\r
 158         msr msp, r0                                                             /* Set the MSP back to the start of the stack. */\r
 159         cpsie i                                                                 /* Globally enable interrupts. */\r
 160         cpsie f\r
 161         dsb\r
 162         isb\r
 163         svc 2                                                                   /* System call to start the first task. portSVC_START_SCHEDULER = 2. */\r
 164 /*-----------------------------------------------------------*/\r
 165 \r
 166 ulSetInterruptMask:\r
 167         mrs r0, basepri                                                 /* r0 = basepri. Return original basepri value. */\r
 168         mov r1, #configMAX_SYSCALL_INTERRUPT_PRIORITY\r
 169         msr basepri, r1                                                 /* Disable interrupts upto configMAX_SYSCALL_INTERRUPT_PRIORITY. */\r
 170         dsb\r
 171         isb\r
 172         bx lr                                                                   /* Return. */\r
 173 /*-----------------------------------------------------------*/\r
 174 \r
 175 vClearInterruptMask:\r
 176         msr basepri, r0                                                 /* basepri = ulMask. */\r
 177         dsb\r
 178         isb\r
 179         bx lr                                                                   /* Return. */\r
 180 /*-----------------------------------------------------------*/\r
 181 \r
 182 PendSV_Handler:\r
 183         mrs r1, psp                                                             /* Read PSP in r1. */\r
 184         ldr r2, =xSecureContext                                 /* Read the location of xSecureContext i.e. &( xSecureContext ). */\r
 185         ldr r0, [r2]                                                    /* Read xSecureContext - Value of xSecureContext must be in r0 as it is used as a parameter later. */\r
 186 \r
 187         cbz r0, save_ns_context                                 /* No secure context to save. */\r
 188         push {r0-r2, r14}\r
 189         bl SecureContext_SaveContext\r
 190         pop {r0-r3}                                                             /* LR is now in r3. */\r
 191         mov lr, r3                                                              /* LR = r3. */\r
 192         lsls r2, r3, #25                                                /* r2 = r3 << 25. Bit[6] of EXC_RETURN is 1 if secure stack was used, 0 if non-secure stack was used to store stack frame. */\r
 193         bpl save_ns_context                                             /* bpl - branch if positive or zero. If r2 >= 0 ==> Bit[6] in EXC_RETURN is 0 i.e. non-secure stack was used. */\r
 194         ldr r3, =pxCurrentTCB                                   /* Read the location of pxCurrentTCB i.e. &( pxCurrentTCB ). */\r
 195         ldr r2, [r3]                                                    /* Read pxCurrentTCB. */\r
 196 #if ( configENABLE_MPU == 1 )\r
 197         subs r1, r1, #16                                                /* Make space for xSecureContext, PSPLIM, CONTROL and LR on the stack. */\r
 198         str r1, [r2]                                                    /* Save the new top of stack in TCB. */\r
 199         mrs r2, psplim                                                  /* r2 = PSPLIM. */\r
 200         mrs r3, control                                                 /* r3 = CONTROL. */\r
 201         mov r4, lr                                                              /* r4 = LR/EXC_RETURN. */\r
 202         stmia r1!, {r0, r2-r4}                                  /* Store xSecureContext, PSPLIM, CONTROL and LR on the stack. */\r
 203 #else /* configENABLE_MPU */\r
 204         subs r1, r1, #12                                                /* Make space for xSecureContext, PSPLIM and LR on the stack. */\r
 205         str r1, [r2]                                                    /* Save the new top of stack in TCB. */\r
 206         mrs r2, psplim                                                  /* r2 = PSPLIM. */\r
 207         mov r3, lr                                                              /* r3 = LR/EXC_RETURN. */\r
 208         stmia r1!, {r0, r2-r3}                                  /* Store xSecureContext, PSPLIM and LR on the stack. */\r
 209 #endif /* configENABLE_MPU */\r
 210         b select_next_task\r
 211 \r
 212         save_ns_context:\r
 213                 ldr r3, =pxCurrentTCB                           /* Read the location of pxCurrentTCB i.e. &( pxCurrentTCB ). */\r
 214                 ldr r2, [r3]                                            /* Read pxCurrentTCB. */\r
 215         #if ( configENABLE_FPU == 1 )\r
 216                 tst lr, #0x10                                           /* Test Bit[4] in LR. Bit[4] of EXC_RETURN is 0 if the FPU is in use. */\r
 217                 it eq\r
 218                 vstmdbeq r1!, {s16-s31}                         /* Store the FPU registers which are not saved automatically. */\r
 219         #endif /* configENABLE_FPU */\r
 220         #if ( configENABLE_MPU == 1 )\r
 221                 subs r1, r1, #48                                        /* Make space for xSecureContext, PSPLIM, CONTROL, LR and the remaining registers on the stack. */\r
 222                 str r1, [r2]                                            /* Save the new top of stack in TCB. */\r
 223                 adds r1, r1, #16                                        /* r1 = r1 + 16. */\r
 224                 stm r1, {r4-r11}                                        /* Store the registers that are not saved automatically. */\r
 225                 mrs r2, psplim                                          /* r2 = PSPLIM. */\r
 226                 mrs r3, control                                         /* r3 = CONTROL. */\r
 227                 mov r4, lr                                                      /* r4 = LR/EXC_RETURN. */\r
 228                 subs r1, r1, #16                                        /* r1 = r1 - 16. */\r
 229                 stm r1, {r0, r2-r4}                                     /* Store xSecureContext, PSPLIM, CONTROL and LR on the stack. */\r
 230         #else /* configENABLE_MPU */\r
 231                 subs r1, r1, #44                                        /* Make space for xSecureContext, PSPLIM, LR and the remaining registers on the stack. */\r
 232                 str r1, [r2]                                            /* Save the new top of stack in TCB. */\r
 233                 adds r1, r1, #12                                        /* r1 = r1 + 12. */\r
 234                 stm r1, {r4-r11}                                        /* Store the registers that are not saved automatically. */\r
 235                 mrs r2, psplim                                          /* r2 = PSPLIM. */\r
 236                 mov r3, lr                                                      /* r3 = LR/EXC_RETURN. */\r
 237                 subs r1, r1, #12                                        /* r1 = r1 - 12. */\r
 238                 stmia r1!, {r0, r2-r3}                          /* Store xSecureContext, PSPLIM and LR on the stack. */\r
 239         #endif /* configENABLE_MPU */\r
 240 \r
 241         select_next_task:\r
 242                 mov r0, #configMAX_SYSCALL_INTERRUPT_PRIORITY\r
 243                 msr basepri, r0                                         /* Disable interrupts upto configMAX_SYSCALL_INTERRUPT_PRIORITY. */\r
 244                 dsb\r
 245                 isb\r
 246                 bl vTaskSwitchContext\r
 247                 mov r0, #0                                                      /* r0 = 0. */\r
 248                 msr basepri, r0                                         /* Enable interrupts. */\r
 249 \r
 250                 ldr r2, =pxCurrentTCB                           /* Read the location of pxCurrentTCB i.e. &( pxCurrentTCB ). */\r
 251                 ldr r3, [r2]                                            /* Read pxCurrentTCB. */\r
 252                 ldr r1, [r3]                                            /* The first item in pxCurrentTCB is the task top of stack. r1 now points to the top of stack. */\r
 253 \r
 254         #if ( configENABLE_MPU == 1 )\r
 255                 dmb                                                                     /* Complete outstanding transfers before disabling MPU. */\r
 256                 ldr r2, =0xe000ed94                                     /* r2 = 0xe000ed94 [Location of MPU_CTRL]. */\r
 257                 ldr r4, [r2]                                            /* Read the value of MPU_CTRL. */\r
 258                 bic r4, r4, #1                                          /* r4 = r4 & ~1 i.e. Clear the bit 0 in r4. */\r
 259                 str r4, [r2]                                            /* Disable MPU. */\r
 260 \r
 261                 adds r3, #4                                                     /* r3 = r3 + 4. r3 now points to MAIR0 in TCB. */\r
 262                 ldr r4, [r3]                                            /* r4 = *r3 i.e. r4 = MAIR0. */\r
 263                 ldr r2, =0xe000edc0                                     /* r2 = 0xe000edc0 [Location of MAIR0]. */\r
 264                 str r4, [r2]                                            /* Program MAIR0. */\r
 265                 ldr r2, =0xe000ed98                                     /* r2 = 0xe000ed98 [Location of RNR]. */\r
 266                 movs r4, #4                                                     /* r4 = 4. */\r
 267                 str r4, [r2]                                            /* Program RNR = 4. */\r
 268                 adds r3, #4                                                     /* r3 = r3 + 4. r3 now points to first RBAR in TCB. */\r
 269                 ldr  r2, =0xe000ed9c                            /* r2 = 0xe000ed9c [Location of RBAR]. */\r
 270                 ldmia r3!, {r4-r11}                                     /* Read 4 sets of RBAR/RLAR registers from TCB. */\r
 271                 stmia r2!, {r4-r11}                                     /* Write 4 set of RBAR/RLAR registers using alias registers. */\r
 272 \r
 273                 ldr r2, =0xe000ed94                                     /* r2 = 0xe000ed94 [Location of MPU_CTRL]. */\r
 274                 ldr r4, [r2]                                            /* Read the value of MPU_CTRL. */\r
 275                 orr r4, r4, #1                                          /* r4 = r4 | 1 i.e. Set the bit 0 in r4. */\r
 276                 str r4, [r2]                                            /* Enable MPU. */\r
 277                 dsb                                                                     /* Force memory writes before continuing. */\r
 278         #endif /* configENABLE_MPU */\r
 279 \r
 280         #if ( configENABLE_MPU == 1 )\r
 281                 ldmia r1!, {r0, r2-r4}                          /* Read from stack - r0 = xSecureContext, r2 = PSPLIM, r3 = CONTROL and r4 = LR. */\r
 282                 msr psplim, r2                                          /* Restore the PSPLIM register value for the task. */\r
 283                 msr control, r3                                         /* Restore the CONTROL register value for the task. */\r
 284                 mov lr, r4                                                      /* LR = r4. */\r
 285                 ldr r2, =xSecureContext                         /* Read the location of xSecureContext i.e. &( xSecureContext ). */\r
 286                 str r0, [r2]                                            /* Restore the task's xSecureContext. */\r
 287                 cbz r0, restore_ns_context                      /* If there is no secure context for the task, restore the non-secure context. */\r
 288                 push {r1,r4}\r
 289                 bl SecureContext_LoadContext            /* Restore the secure context. */\r
 290                 pop {r1,r4}\r
 291                 mov lr, r4                                                      /* LR = r4. */\r
 292                 lsls r2, r4, #25                                        /* r2 = r4 << 25. Bit[6] of EXC_RETURN is 1 if secure stack was used, 0 if non-secure stack was used to store stack frame. */\r
 293                 bpl restore_ns_context                          /* bpl - branch if positive or zero. If r2 >= 0 ==> Bit[6] in EXC_RETURN is 0 i.e. non-secure stack was used. */\r
 294                 msr psp, r1                                                     /* Remember the new top of stack for the task. */\r
 295                 bx lr\r
 296         #else /* configENABLE_MPU */\r
 297                 ldmia r1!, {r0, r2-r3}                          /* Read from stack - r0 = xSecureContext, r2 = PSPLIM and r3 = LR. */\r
 298                 msr psplim, r2                                          /* Restore the PSPLIM register value for the task. */\r
 299                 mov lr, r3                                                      /* LR = r3. */\r
 300                 ldr r2, =xSecureContext                         /* Read the location of xSecureContext i.e. &( xSecureContext ). */\r
 301                 str r0, [r2]                                            /* Restore the task's xSecureContext. */\r
 302                 cbz r0, restore_ns_context                      /* If there is no secure context for the task, restore the non-secure context. */\r
 303                 push {r1,r3}\r
 304                 bl SecureContext_LoadContext            /* Restore the secure context. */\r
 305                 pop {r1,r3}\r
 306                 mov lr, r3                                                      /* LR = r3. */\r
 307                 lsls r2, r3, #25                                        /* r2 = r3 << 25. Bit[6] of EXC_RETURN is 1 if secure stack was used, 0 if non-secure stack was used to store stack frame. */\r
 308                 bpl restore_ns_context                          /* bpl - branch if positive or zero. If r2 >= 0 ==> Bit[6] in EXC_RETURN is 0 i.e. non-secure stack was used. */\r
 309                 msr psp, r1                                                     /* Remember the new top of stack for the task. */\r
 310                 bx lr\r
 311         #endif /* configENABLE_MPU */\r
 312 \r
 313         restore_ns_context:\r
 314                 ldmia r1!, {r4-r11}                                     /* Restore the registers that are not automatically restored. */\r
 315         #if ( configENABLE_FPU == 1 )\r
 316                 tst lr, #0x10                                           /* Test Bit[4] in LR. Bit[4] of EXC_RETURN is 0 if the FPU is in use. */\r
 317                 it eq\r
 318                 vldmiaeq r1!, {s16-s31}                         /* Restore the FPU registers which are not restored automatically. */\r
 319         #endif /* configENABLE_FPU */\r
 320                 msr psp, r1                                                     /* Remember the new top of stack for the task. */\r
 321                 bx lr\r
 322 /*-----------------------------------------------------------*/\r
 323 \r
 324 SVC_Handler:\r
 325         tst lr, #4\r
 326         ite eq\r
 327         mrseq r0, msp\r
 328         mrsne r0, psp\r
 329         b vPortSVCHandler_C\r
 330 /*-----------------------------------------------------------*/\r
 331 \r
 332 vPortFreeSecureContext:\r
 333         /* r0 = uint32_t *pulTCB. */\r
 334         ldr r1, [r0]                                                    /* The first item in the TCB is the top of the stack. */\r
 335         ldr r0, [r1]                                                    /* The first item on the stack is the task's xSecureContext. */\r
 336         cmp r0, #0                                                              /* Raise svc if task's xSecureContext is not NULL. */\r
 337         it ne\r
 338         svcne 1                                                                 /* Secure context is freed in the supervisor call. portSVC_FREE_SECURE_CONTEXT = 1. */\r
 339         bx lr                                                                   /* Return. */\r
 340 /*-----------------------------------------------------------*/\r
 341 \r
 342         END\r