git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/IAR/ARM_CM7/r0p1/portasm.s

   1 /*\r
   2  * FreeRTOS Kernel V10.3.0\r
   3  * Copyright (C) 2020 Amazon.com, Inc. or its affiliates.  All Rights Reserved.\r
   4  *\r
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy of\r
   6  * this software and associated documentation files (the "Software"), to deal in\r
   7  * the Software without restriction, including without limitation the rights to\r
   8  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of\r
   9  * the Software, and to permit persons to whom the Software is furnished to do so,\r
  10  * subject to the following conditions:\r
  11  *\r
  12  * The above copyright notice and this permission notice shall be included in all\r
  13  * copies or substantial portions of the Software.\r
  14  *\r
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR\r
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS\r
  17  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR\r
  18  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER\r
  19  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN\r
  20  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.\r
  21  *\r
  22  * http://www.FreeRTOS.org\r
  23  * http://aws.amazon.com/freertos\r
  24  *\r
  25  * 1 tab == 4 spaces!\r
  26  */\r
  27 \r
  28 #include <FreeRTOSConfig.h>\r
  29 \r
  30         RSEG    CODE:CODE(2)\r
  31         thumb\r
  32 \r
  33         EXTERN pxCurrentTCB\r
  34         EXTERN vTaskSwitchContext\r
  35 \r
  36         PUBLIC xPortPendSVHandler\r
  37         PUBLIC vPortSVCHandler\r
  38         PUBLIC vPortStartFirstTask\r
  39         PUBLIC vPortEnableVFP\r
  40 \r
  41 \r
  42 /*-----------------------------------------------------------*/\r
  43 \r
  44 xPortPendSVHandler:\r
  45         mrs r0, psp\r
  46         isb\r
  47         /* Get the location of the current TCB. */\r
  48         ldr     r3, =pxCurrentTCB\r
  49         ldr     r2, [r3]\r
  50 \r
  51         /* Is the task using the FPU context?  If so, push high vfp registers. */\r
  52         tst r14, #0x10\r
  53         it eq\r
  54         vstmdbeq r0!, {s16-s31}\r
  55 \r
  56         /* Save the core registers. */\r
  57         stmdb r0!, {r4-r11, r14}\r
  58 \r
  59         /* Save the new top of stack into the first member of the TCB. */\r
  60         str r0, [r2]\r
  61 \r
  62         stmdb sp!, {r0, r3}\r
  63         mov r0, #configMAX_SYSCALL_INTERRUPT_PRIORITY\r
  64         cpsid i\r
  65         msr basepri, r0\r
  66         dsb\r
  67         isb\r
  68         cpsie i\r
  69         bl vTaskSwitchContext\r
  70         mov r0, #0\r
  71         msr basepri, r0\r
  72         ldmia sp!, {r0, r3}\r
  73 \r
  74         /* The first item in pxCurrentTCB is the task top of stack. */\r
  75         ldr r1, [r3]\r
  76         ldr r0, [r1]\r
  77 \r
  78         /* Pop the core registers. */\r
  79         ldmia r0!, {r4-r11, r14}\r
  80 \r
  81         /* Is the task using the FPU context?  If so, pop the high vfp registers\r
  82         too. */\r
  83         tst r14, #0x10\r
  84         it eq\r
  85         vldmiaeq r0!, {s16-s31}\r
  86 \r
  87         msr psp, r0\r
  88         isb\r
  89         #ifdef WORKAROUND_PMU_CM001 /* XMC4000 specific errata */\r
  90                 #if WORKAROUND_PMU_CM001 == 1\r
  91                         push { r14 }\r
  92                         pop { pc }\r
  93                 #endif\r
  94         #endif\r
  95 \r
  96         bx r14\r
  97 \r
  98 \r
  99 /*-----------------------------------------------------------*/\r
 100 \r
 101 vPortSVCHandler:\r
 102         /* Get the location of the current TCB. */\r
 103         ldr     r3, =pxCurrentTCB\r
 104         ldr r1, [r3]\r
 105         ldr r0, [r1]\r
 106         /* Pop the core registers. */\r
 107         ldmia r0!, {r4-r11, r14}\r
 108         msr psp, r0\r
 109         isb\r
 110         mov r0, #0\r
 111         msr     basepri, r0\r
 112         bx r14\r
 113 \r
 114 /*-----------------------------------------------------------*/\r
 115 \r
 116 vPortStartFirstTask\r
 117         /* Use the NVIC offset register to locate the stack. */\r
 118         ldr r0, =0xE000ED08\r
 119         ldr r0, [r0]\r
 120         ldr r0, [r0]\r
 121         /* Set the msp back to the start of the stack. */\r
 122         msr msp, r0\r
 123         /* Clear the bit that indicates the FPU is in use in case the FPU was used\r
 124         before the scheduler was started - which would otherwise result in the\r
 125         unnecessary leaving of space in the SVC stack for lazy saving of FPU\r
 126         registers. */\r
 127         mov r0, #0\r
 128         msr control, r0\r
 129         /* Call SVC to start the first task. */\r
 130         cpsie i\r
 131         cpsie f\r
 132         dsb\r
 133         isb\r
 134         svc 0\r
 135 \r
 136 /*-----------------------------------------------------------*/\r
 137 \r
 138 vPortEnableVFP:\r
 139         /* The FPU enable bits are in the CPACR. */\r
 140         ldr.w r0, =0xE000ED88\r
 141         ldr     r1, [r0]\r
 142 \r
 143         /* Enable CP10 and CP11 coprocessors, then save back. */\r
 144         orr     r1, r1, #( 0xf << 20 )\r
 145         str r1, [r0]\r
 146         bx      r14\r
 147 \r
 148 \r
 149 \r
 150         END\r
 151 \r