git.sur5r.net Git - freertos/blob - FreeRTOS/Source/portable/IAR/STR91x/ISR_Support.h

   1 /*\r
   2  * FreeRTOS Kernel V10.3.0\r
   3  * Copyright (C) 2020 Amazon.com, Inc. or its affiliates.  All Rights Reserved.\r
   4  *\r
   5  * Permission is hereby granted, free of charge, to any person obtaining a copy of\r
   6  * this software and associated documentation files (the "Software"), to deal in\r
   7  * the Software without restriction, including without limitation the rights to\r
   8  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of\r
   9  * the Software, and to permit persons to whom the Software is furnished to do so,\r
  10  * subject to the following conditions:\r
  11  *\r
  12  * The above copyright notice and this permission notice shall be included in all\r
  13  * copies or substantial portions of the Software.\r
  14  *\r
  15  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR\r
  16  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS\r
  17  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR\r
  18  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER\r
  19  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN\r
  20  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.\r
  21  *\r
  22  * http://www.FreeRTOS.org\r
  23  * http://aws.amazon.com/freertos\r
  24  *\r
  25  * 1 tab == 4 spaces!\r
  26  */\r
  27 \r
  28         EXTERN pxCurrentTCB\r
  29         EXTERN ulCriticalNesting\r
  30 \r
  31 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;\r
  32 ; Context save and restore macro definitions\r
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;\r
  34 \r
  35 portSAVE_CONTEXT MACRO\r
  36 \r
  37         ; Push R0 as we are going to use the register.                                  \r
  38         STMDB   SP!, {R0}\r
  39 \r
  40         ; Set R0 to point to the task stack pointer.                                    \r
  41         STMDB   SP, {SP}^\r
  42         NOP\r
  43         SUB             SP, SP, #4\r
  44         LDMIA   SP!, {R0}\r
  45 \r
  46         ; Push the return address onto the stack.                                               \r
  47         STMDB   R0!, {LR}\r
  48 \r
  49         ; Now we have saved LR we can use it instead of R0.                             \r
  50         MOV             LR, R0\r
  51 \r
  52         ; Pop R0 so we can save it onto the system mode stack.                  \r
  53         LDMIA   SP!, {R0}\r
  54 \r
  55         ; Push all the system mode registers onto the task stack.               \r
  56         STMDB   LR, {R0-LR}^\r
  57         NOP\r
  58         SUB             LR, LR, #60\r
  59 \r
  60         ; Push the SPSR onto the task stack.                                                    \r
  61         MRS             R0, SPSR\r
  62         STMDB   LR!, {R0}\r
  63 \r
  64         LDR             R0, =ulCriticalNesting \r
  65         LDR             R0, [R0]\r
  66         STMDB   LR!, {R0}\r
  67 \r
  68         ; Store the new top of stack for the task.                                              \r
  69         LDR             R1, =pxCurrentTCB\r
  70         LDR             R0, [R1]\r
  71         STR             LR, [R0]\r
  72 \r
  73         ENDM\r
  74 \r
  75 \r
  76 portRESTORE_CONTEXT MACRO\r
  77 \r
  78         ; Set the LR to the task stack.                                                                         \r
  79         LDR             R1, =pxCurrentTCB\r
  80         LDR             R0, [R1]\r
  81         LDR             LR, [R0]\r
  82 \r
  83         ; The critical nesting depth is the first item on the stack.    \r
  84         ; Load it into the ulCriticalNesting variable.                                  \r
  85         LDR             R0, =ulCriticalNesting\r
  86         LDMFD   LR!, {R1}\r
  87         STR             R1, [R0]\r
  88 \r
  89         ; Get the SPSR from the stack.                                                                  \r
  90         LDMFD   LR!, {R0}\r
  91         MSR             SPSR_cxsf, R0\r
  92 \r
  93         ; Restore all system mode registers for the task.                               \r
  94         LDMFD   LR, {R0-R14}^\r
  95         NOP\r
  96 \r
  97         ; Restore the return address.                                                                   \r
  98         LDR             LR, [LR, #+60]\r
  99 \r
 100         ; And return - correcting the offset in the LR to obtain the    \r
 101         ; correct address.                                                                                              \r
 102         SUBS    PC, LR, #4\r
 103 \r
 104         ENDM\r
 105 \r