git.sur5r.net Git - i3/i3/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Run autoreconf -fi to generate a configure script from this file.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([i3], [4.12], [https://github.com/i3/i3/issues])
   6 # For AX_EXTEND_SRCDIR
   7 AX_ENABLE_BUILDDIR
   8 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall no-dist-gzip dist-bzip2])
   9 # Default to silent rules, use V=1 to get verbose compilation output.
  10 AM_SILENT_RULES([yes])
  11 # Make it possible to disable maintainer mode to disable re-generation of build
  12 # system files.
  13 AM_MAINTAINER_MODE([enable])
  14 AC_CONFIG_SRCDIR([libi3/ipc_recv_message.c])
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 # Verify we are using GNU make because we use '%'-style pattern rules in
  19 # Makefile.am, which are a GNU make extension. Pull requests to replace
  20 # '%'-style pattern rules with a more portable alternative are welcome.
  21 AX_CHECK_GNU_MAKE
  22 AS_VAR_IF([_cv_gnu_make_command], [""], [AC_MSG_ERROR([the i3 Makefile.am requires GNU make])])
  23
  24 AX_EXTEND_SRCDIR
  25
  26 AS_IF([test -d ${srcdir}/.git],
  27       [
  28         VERSION="$(git describe --tags --abbrev=0)"
  29         I3_VERSION="$(git describe --tags --always) ($(git log --pretty=format:%cd --date=short -n1), branch \\\"$(git describe --tags --always --all | sed s:heads/::)\\\")"
  30         # Mirrors what libi3/is_debug_build.c does:
  31         is_release=$(test $(echo "${I3_VERSION}" | cut -d '(' -f 1 | wc -m) -lt 10 && echo yes || echo no)
  32       ],
  33       [
  34         VERSION="$(cut -d '-' -f 1 ${srcdir}/I3_VERSION | cut -d ' ' -f 1)"
  35         I3_VERSION="$(cat ${srcdir}/I3_VERSION)"
  36         is_release="$(grep -q non-git ${srcdir}/I3_VERSION && echo no || echo yes)"
  37       ])
  38 MAJOR_VERSION="$(echo ${VERSION} | cut -d '.' -f 1)"
  39 MINOR_VERSION="$(echo ${VERSION} | cut -d '.' -f 2)"
  40 PATCH_VERSION="$(echo ${VERSION} | cut -d '.' -f 3)"
  41 AS_IF([test "x${PATCH_VERSION}" = x], [PATCH_VERSION=0])
  42 AC_DEFINE_UNQUOTED([I3_VERSION], ["${I3_VERSION}"], [i3 version])
  43 AC_DEFINE_UNQUOTED([MAJOR_VERSION], [${MAJOR_VERSION}], [i3 major version])
  44 AC_DEFINE_UNQUOTED([MINOR_VERSION], [${MINOR_VERSION}], [i3 minor version])
  45 AC_DEFINE_UNQUOTED([PATCH_VERSION], [${PATCH_VERSION}], [i3 patch version])
  46
  47 AX_CODE_COVERAGE
  48
  49 dnl is_release must be lowercase because AX_CHECK_ENABLE_DEBUG calls m4_tolower
  50 dnl on its fourth argument.
  51 AX_CHECK_ENABLE_DEBUG([yes], , [UNUSED_NDEBUG], [$is_release])
  52
  53 AC_PROG_CC_C99
  54
  55 AC_DEFINE_UNQUOTED(SYSCONFDIR, "`eval echo $sysconfdir`", [Location of system configuration files])
  56
  57 # For strnlen() and vasprintf().
  58 AC_USE_SYSTEM_EXTENSIONS
  59
  60 # Checks for typedefs, structures, and compiler characteristics.
  61 AC_CHECK_HEADER_STDBOOL
  62 dnl The error message should include the specific type which could not be
  63 dnl found, but I do not see a way to achieve that.
  64 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t], , [AC_MSG_FAILURE([cannot find required type])])
  65
  66 # Checks for library functions.
  67 AC_FUNC_FORK
  68 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  69 AC_FUNC_STRNLEN
  70 AC_CHECK_FUNCS([atexit dup2 ftruncate getcwd gettimeofday localtime_r memchr memset mkdir rmdir setlocale socket strcasecmp strchr strdup strerror strncasecmp strndup strrchr strspn strstr strtol strtoul], , [AC_MSG_FAILURE([cannot find the $ac_func function, which i3 requires])])
  71
  72 # Checks for libraries.
  73
  74 AC_SEARCH_LIBS([floor], [m], , [AC_MSG_FAILURE([cannot find the required floor() function despite trying to link with -lm])])
  75
  76 # libev does not ship with a pkg-config file :(.
  77 AC_SEARCH_LIBS([ev_run], [ev], , [AC_MSG_FAILURE([cannot find the required ev_run() function despite trying to link with -lev])])
  78
  79 AC_SEARCH_LIBS([shm_open], [rt])
  80
  81 AX_PTHREAD
  82
  83 dnl Each prefix corresponds to a source tarball which users might have
  84 dnl downloaded in a newer version and would like to overwrite.
  85 PKG_CHECK_MODULES([LIBSN], [libstartup-notification-1.0])
  86 PKG_CHECK_MODULES([XCB], [xcb xcb-xkb xcb-xinerama xcb-randr])
  87 PKG_CHECK_MODULES([XCB_UTIL], [xcb-event xcb-util])
  88 PKG_CHECK_MODULES([XCB_UTIL_CURSOR], [xcb-cursor])
  89 PKG_CHECK_MODULES([XCB_UTIL_KEYSYMS], [xcb-keysyms])
  90 PKG_CHECK_MODULES([XCB_UTIL_WM], [xcb-icccm])
  91 PKG_CHECK_MODULES([XCB_UTIL_XRM], [xcb-xrm])
  92 PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon xkbcommon-x11])
  93 PKG_CHECK_MODULES([YAJL], [yajl])
  94 PKG_CHECK_MODULES([LIBPCRE], [libpcre >= 8.10])
  95 PKG_CHECK_MODULES([PANGOCAIRO], [cairo >= 1.14.4 pangocairo])
  96
  97 # Checks for programs.
  98 AC_PROG_AWK
  99 AC_PROG_CPP
 100 AC_PROG_INSTALL
 101 AC_PROG_MAKE_SET
 102 AC_PROG_RANLIB
 103 AC_PROG_LN_S
 104
 105 AC_PATH_PROG([PATH_ASCIIDOC], [asciidoc])
 106 AC_PATH_PROG([PATH_XMLTO], [xmlto])
 107 AC_PATH_PROG([PATH_POD2MAN], [pod2man])
 108
 109 AM_CONDITIONAL([BUILD_MANS], [test x$PATH_ASCIIDOC != x && test x$PATH_XMLTO != x && test x$PATH_POD2MAN != x])
 110 AM_CONDITIONAL([BUILD_DOCS], [test x$PATH_ASCIIDOC != x])
 111
 112 AM_PROG_AR
 113
 114 AX_FLAGS_WARN_ALL
 115 AX_CHECK_COMPILE_FLAG([-Wunused-value], [AX_APPEND_FLAG([-Wunused-value], [AM_CFLAGS])])
 116 AC_SUBST(AM_CFLAGS)
 117
 118 # Checks for header files.
 119 AC_CHECK_HEADERS([fcntl.h float.h inttypes.h limits.h locale.h netinet/in.h paths.h stddef.h stdint.h stdlib.h string.h sys/param.h sys/socket.h sys/time.h unistd.h], , [AC_MSG_FAILURE([cannot find the $ac_header header, which i3 requires])])
 120
 121 AC_CONFIG_FILES([Makefile testcases/lib/i3test.pm])
 122 AC_CONFIG_FILES([testcases/complete-run.pl], [chmod +x testcases/complete-run.pl])
 123
 124 # Enable address sanitizer for non-release builds. The performance hit is a
 125 # 50% increase of wallclock time for the testsuite on my machine.
 126 if test x$is_release = xyes; then
 127         default_sanitizers=
 128 else
 129         default_sanitizers=address
 130 fi
 131 AX_SANITIZERS(, [$default_sanitizers], [AC_DEFINE([I3_ASAN_ENABLED], [], [Enable ASAN])])
 132
 133 AC_OUTPUT
 134
 135 if test -z "${BUILD_DOCS_TRUE}"; then
 136         print_BUILD_DOCS=yes
 137 else
 138         print_BUILD_DOCS=no
 139 fi
 140
 141
 142 if test -z "${BUILD_MANS_TRUE}"; then
 143         print_BUILD_MANS=yes
 144 else
 145         print_BUILD_MANS=no
 146 fi
 147
 148 echo \
 149 "--------------------------------------------------------------------------------
 150 build configured:
 151
 152 AS_HELP_STRING([i3 version:], [`echo ${I3_VERSION} | sed 's,\\\\,,g'`])
 153 AS_HELP_STRING([is release version:], [${is_release}])
 154
 155 AS_HELP_STRING([build manpages:], [${print_BUILD_MANS}])
 156 AS_HELP_STRING([build docs:], [${print_BUILD_DOCS}])
 157 AS_HELP_STRING([enable debug flags:], [${ax_enable_debug}])
 158 AS_HELP_STRING([code coverage:], [${CODE_COVERAGE_ENABLED}])
 159 AS_HELP_STRING([enabled sanitizers:], [${ax_enabled_sanitizers}])
 160
 161 To compile, run:
 162
 163   cd `pwd` && make -j8
 164 --------------------------------------------------------------------------------"