git.sur5r.net Git - i3/i3/blob - i3-dmenu-desktop

   1 #!/usr/bin/env perl
   2 # vim:ts=4:sw=4:expandtab
   3 #
   4 # © 2012 Michael Stapelberg
   5 #
   6 # No dependencies except for perl ≥ v5.10
   7
   8 use strict;
   9 use warnings qw(FATAL utf8);
  10 use Data::Dumper;
  11 use IPC::Open2;
  12 use POSIX qw(locale_h);
  13 use File::Find;
  14 use File::Basename qw(basename);
  15 use File::Temp qw(tempfile);
  16 use Getopt::Long;
  17 use Pod::Usage;
  18 use v5.10;
  19 use utf8;
  20 use open ':encoding(UTF-8)';
  21
  22 binmode STDOUT, ':utf8';
  23 binmode STDERR, ':utf8';
  24
  25 # reads in a whole file
  26 sub slurp {
  27     my ($filename) = @_;
  28     my $fh;
  29     if (!open($fh, '<', $filename)) {
  30         warn "Could not open $filename: $!";
  31         return undef;
  32     }
  33     local $/;
  34     my $result;
  35     eval {
  36         $result = <$fh>;
  37     };
  38     if ($@) {
  39         warn "Could not read $filename: $@";
  40         return undef;
  41     } else {
  42         return $result;
  43     }
  44 }
  45
  46 my @entry_types;
  47 my $dmenu_cmd = 'dmenu -i';
  48 my $result = GetOptions(
  49     'dmenu=s' => \$dmenu_cmd,
  50     'entry-type=s' => \@entry_types,
  51     'version' => sub {
  52         say "dmenu-desktop 1.5 © 2012 Michael Stapelberg";
  53         exit 0;
  54     },
  55     'help' => sub {
  56         pod2usage(-exitval => 0);
  57     });
  58
  59 die "Could not parse command line options" unless $result;
  60
  61 # Filter entry types and set default type(s) if none selected
  62 my $valid_types = {
  63     name => 1,
  64     command => 1,
  65     filename => 1,
  66 };
  67 @entry_types = grep { exists($valid_types->{$_}) } @entry_types;
  68 @entry_types = ('name', 'command') unless @entry_types;
  69
  70 # ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
  71 # ┃ Convert LC_MESSAGES into an ordered list of suffixes to search for in the ┃
  72 # ┃ .desktop files (e.g. “Name[de_DE@euro]” for LC_MESSAGES=de_DE.UTF-8@euro  ┃
  73 # ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
  74
  75 # For details on how the transformation of LC_MESSAGES to a list of keys that
  76 # should be looked up works, refer to “Localized values for keys” of the
  77 # “Desktop Entry Specification”:
  78 # http://standards.freedesktop.org/desktop-entry-spec/latest/ar01s04.html
  79 my $lc_messages = setlocale(LC_MESSAGES);
  80
  81 # Ignore the encoding (e.g. .UTF-8)
  82 $lc_messages =~ s/\.[^@]+//g;
  83
  84 my @suffixes = ($lc_messages);
  85
  86 # _COUNTRY and @MODIFIER are present
  87 if ($lc_messages =~ /_[^@]+@/) {
  88     my $no_modifier = $lc_messages;
  89     $no_modifier =~ s/@.*//g;
  90     push @suffixes, $no_modifier;
  91
  92     my $no_country = $lc_messages;
  93     $no_country =~ s/_[^@]+//g;
  94     push @suffixes, $no_country;
  95 }
  96
  97 # Strip _COUNTRY and @MODIFIER if present
  98 $lc_messages =~ s/[_@].*//g;
  99 push @suffixes, $lc_messages;
 100
 101 # ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
 102 # ┃ Read all .desktop files and store the values in which we are interested.  ┃
 103 # ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
 104
 105 my %desktops;
 106 # See http://standards.freedesktop.org/basedir-spec/basedir-spec-latest.html#variables
 107 my $xdg_data_home = $ENV{XDG_DATA_HOME};
 108 $xdg_data_home = $ENV{HOME} . '/.local/share' if
 109     !defined($xdg_data_home) ||
 110     $xdg_data_home eq '' ||
 111     ! -d $xdg_data_home;
 112
 113 my $xdg_data_dirs = $ENV{XDG_DATA_DIRS};
 114 $xdg_data_dirs = '/usr/local/share/:/usr/share/' if
 115     !defined($xdg_data_dirs) ||
 116     $xdg_data_dirs eq '';
 117
 118 my @searchdirs = ("$xdg_data_home/applications/");
 119 for my $dir (split(':', $xdg_data_dirs)) {
 120     push @searchdirs, "$dir/applications/";
 121 }
 122
 123 # Cleanup the paths, maybe some application does not cope with double slashes
 124 # (the field code %k is replaced with the .desktop file location).
 125 @searchdirs = map { s,//,/,g; $_ } @searchdirs;
 126
 127 # To avoid errors by File::Find’s find(), only pass existing directories.
 128 @searchdirs = grep { -d $_ } @searchdirs;
 129
 130 find(
 131     {
 132         wanted => sub {
 133             return unless substr($_, -1 * length('.desktop')) eq '.desktop';
 134             my $relative = $File::Find::name;
 135
 136             # + 1 for the trailing /, which is missing in ::topdir.
 137             substr($relative, 0, length($File::Find::topdir) + 1) = '';
 138
 139             # Don’t overwrite files with the same relative path, we search in
 140             # descending order of importance.
 141             return if exists($desktops{$relative});
 142
 143             $desktops{$relative} = $File::Find::name;
 144         },
 145         no_chdir => 1,
 146     },
 147     @searchdirs
 148 );
 149
 150 my %apps;
 151
 152 for my $file (values %desktops) {
 153     my $base = basename($file);
 154
 155     # _ is an invalid character for a key, so we can use it for our own keys.
 156     $apps{$base}->{_Location} = $file;
 157
 158     # Extract all “Name” and “Exec” keys from the [Desktop Entry] group
 159     # and store them in $apps{$base}.
 160     my %names;
 161     my $content = slurp($file);
 162     next unless defined($content);
 163     my @lines = split("\n", $content);
 164     for my $line (@lines) {
 165         my $first = substr($line, 0, 1);
 166         next if $line eq '' || $first eq '#';
 167         next unless ($line eq '[Desktop Entry]' ..
 168                      ($first eq '[' &&
 169                       substr($line, -1) eq ']' &&
 170                       $line ne '[Desktop Entry]'));
 171         next if $first eq '[';
 172
 173         my ($key, $value) = ($line =~ /^
 174           (
 175             [A-Za-z0-9-]+  # the spec specifies these as valid key characters
 176             (?:\[[^]]+\])? # possibly, there as a locale suffix
 177           )
 178           \s* = \s*        # whitespace around = should be ignored
 179           (.*)             # no restrictions on the values
 180           $/x);
 181
 182         if ($key =~ /^Name/) {
 183             $names{$key} = $value;
 184         } elsif ($key eq 'Exec' ||
 185                  $key eq 'TryExec' ||
 186                  $key eq 'Path' ||
 187                  $key eq 'Type') {
 188             $apps{$base}->{$key} = $value;
 189         } elsif ($key eq 'NoDisplay' ||
 190                  $key eq 'Hidden' ||
 191                  $key eq 'StartupNotify' ||
 192                  $key eq 'Terminal') {
 193             # Values of type boolean must either be string true or false,
 194             # see “Possible value types”:
 195             # http://standards.freedesktop.org/desktop-entry-spec/latest/ar01s03.html
 196             $apps{$base}->{$key} = ($value eq 'true');
 197         }
 198     }
 199
 200     for my $suffix (@suffixes) {
 201         next unless exists($names{"Name[$suffix]"});
 202         $apps{$base}->{Name} = $names{"Name[$suffix]"};
 203         last;
 204     }
 205
 206     # Fallback to unlocalized “Name”.
 207     $apps{$base}->{Name} = $names{Name} unless exists($apps{$base}->{Name});
 208 }
 209
 210 # %apps now looks like this:
 211 #
 212 # %apps = {
 213 #     'evince.desktop' => {
 214 #         'Exec' => 'evince %U',
 215 #         'Name' => 'Dokumentenbetrachter',
 216 #         '_Location' => '/usr/share/applications/evince.desktop'
 217 #       },
 218 #     'gedit.desktop' => {
 219 #         'Exec' => 'gedit %U',
 220 #         'Name' => 'gedit',
 221 #         '_Location' => '/usr/share/applications/gedit.desktop'
 222 #       }
 223 #   };
 224
 225 # ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
 226 # ┃ Turn %apps inside out to provide Name → filename lookup.                  ┃
 227 # ┃ The Name is what we display in dmenu later.                               ┃
 228 # ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
 229
 230 my %choices;
 231 for my $app (keys %apps) {
 232     my $name = $apps{$app}->{Name};
 233
 234     # Don’t try to use .desktop files which don’t have Type=application
 235     next if (!exists($apps{$app}->{Type}) ||
 236              $apps{$app}->{Type} ne 'Application');
 237
 238     # Skip broken files (Type=application, but no Exec key).
 239     if (!exists($apps{$app}->{Exec}) ||
 240         $apps{$app}->{Exec} eq '') {
 241         warn 'File ' . $apps{$app}->{_Location} . ' is broken: it contains Type=Application, but no Exec key/value pair.';
 242         next;
 243     }
 244
 245     # Don’t offer apps which have NoDisplay == true or Hidden == true.
 246     # See http://wiki.xfce.org/howto/customize-menu#hide_menu_entries
 247     # for the difference between NoDisplay and Hidden.
 248     next if (exists($apps{$app}->{NoDisplay}) && $apps{$app}->{NoDisplay}) ||
 249             (exists($apps{$app}->{Hidden}) && $apps{$app}->{Hidden});
 250
 251     if (exists($apps{$app}->{TryExec})) {
 252         my $tryexec = $apps{$app}->{TryExec};
 253         if (substr($tryexec, 0, 1) eq '/') {
 254             # Skip if absolute path is not executable.
 255             next unless -x $tryexec;
 256         } else {
 257             # Search in $PATH for the executable.
 258             my $found = 0;
 259             for my $path (split(':', $ENV{PATH})) {
 260                 next unless -x "$path/$tryexec";
 261                 $found = 1;
 262                 last;
 263             }
 264             next unless $found;
 265         }
 266     }
 267
 268     if ((scalar grep { $_ eq 'name' } @entry_types) > 0) {
 269         if (exists($choices{$name})) {
 270             # There are two .desktop files which contain the same “Name” value.
 271             # I’m not sure if that is allowed to happen, but we disambiguate the
 272             # situation by appending “ (2)”, “ (3)”, etc. to the name.
 273             #
 274             # An example of this happening is exo-file-manager.desktop and
 275             # thunar-settings.desktop, both of which contain “Name=File Manager”.
 276             my $inc = 2;
 277             $inc++ while exists($choices{"$name ($inc)"});
 278             $name = "$name ($inc)";
 279         }
 280
 281         $choices{$name} = $app;
 282     }
 283
 284     if ((scalar grep { $_ eq 'command' } @entry_types) > 0) {
 285         my ($command) = split(' ', $apps{$app}->{Exec});
 286
 287         # Don’t add “geany” if “Geany” is already present.
 288         my @keys = map { lc } keys %choices;
 289         next if (scalar grep { $_ eq lc(basename($command)) } @keys) > 0;
 290
 291         $choices{basename($command)} = $app;
 292     }
 293
 294     if ((scalar grep { $_ eq 'filename' } @entry_types) > 0) {
 295         my $filename = basename($app, '.desktop');
 296
 297         # Don’t add “geany” if “Geany” is already present.
 298         my @keys = map { lc } keys %choices;
 299         next if (scalar grep { $_ eq lc($filename) } @keys) > 0;
 300
 301         $choices{$filename} = $app;
 302     }
 303 }
 304
 305 # %choices now looks like this:
 306 #
 307 # %choices = {
 308 #     'Dokumentenbetrachter' => 'evince.desktop',
 309 #     'gedit' => 'gedit.desktop'
 310 #   };
 311
 312 # ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
 313 # ┃ Run dmenu to ask the user for their choice                                ┃
 314 # ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
 315
 316 # open2 will just make dmenu’s STDERR go to our own STDERR.
 317 my ($dmenu_out, $dmenu_in);
 318 my $pid = eval {
 319     open2($dmenu_out, $dmenu_in, $dmenu_cmd);
 320 } or do {
 321     print STDERR "$@";
 322     say STDERR "Running dmenu failed. Is dmenu installed at all? Try running dmenu -v";
 323     exit 1;
 324 };
 325
 326 binmode $dmenu_in, ':utf8';
 327 binmode $dmenu_out, ':utf8';
 328
 329 # Feed dmenu the possible choices.
 330 say $dmenu_in $_ for sort keys %choices;
 331 close($dmenu_in);
 332
 333 waitpid($pid, 0);
 334 my $status = ($? >> 8);
 335
 336 # Pass on dmenu’s exit status if there was an error.
 337 exit $status unless $status == 0;
 338
 339 my $choice = <$dmenu_out>;
 340 # dmenu ≥ 4.4 adds a newline after the choice
 341 chomp($choice);
 342 my $app;
 343 # Exact match: the user chose “Avidemux (GTK+)”
 344 if (exists($choices{$choice})) {
 345     $app = $apps{$choices{$choice}};
 346     $choice = '';
 347 } else {
 348     # Not an exact match: the user entered “Avidemux (GTK+) ~/movie.mp4”
 349     for my $possibility (keys %choices) {
 350         next unless substr($choice, 0, length($possibility)) eq $possibility;
 351         $app = $apps{$choices{$possibility}};
 352         substr($choice, 0, length($possibility)) = '';
 353         # Remove whitespace separating the entry and arguments.
 354         $choice =~ s/^\s//g;
 355         last;
 356     }
 357     if (!defined($app)) {
 358         warn "Invalid input: “$choice” does not match any application. Trying to execute nevertheless.";
 359         $app->{Name} = '';
 360         $app->{Exec} = $choice;
 361         # We assume that the app is old and does not support startup
 362         # notifications because it doesn’t ship a desktop file.
 363         $app->{StartupNotify} = 0;
 364         $app->{_Location} = '';
 365     }
 366 }
 367
 368 # ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
 369 # ┃ Make i3 start the chosen application.                                     ┃
 370 # ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
 371
 372 my $name = $app->{Name};
 373 my $exec = $app->{Exec};
 374 my $location = $app->{_Location};
 375
 376 # Quote as described by “The Exec key”:
 377 # http://standards.freedesktop.org/desktop-entry-spec/latest/ar01s06.html
 378 sub quote {
 379     my ($str) = @_;
 380     $str =~ s/("|`|\$|\\)/\\$1/g;
 381     $str = qq|"$str"| if $str ne "";
 382     return $str;
 383 }
 384
 385 $choice = quote($choice);
 386 $location = quote($location);
 387 $name = quote($name);
 388
 389 # Remove deprecated field codes, as the spec dictates.
 390 $exec =~ s/%[dDnNvm]//g;
 391
 392 # Replace filename field codes with the rest of the command line.
 393 # Note that we assume the user uses precisely one file name,
 394 # not multiple file names.
 395 $exec =~ s/%[fF]/$choice/g;
 396
 397 # If the program works with URLs,
 398 # we assume the user provided a URL instead of a filename.
 399 # As per the spec, there must be at most one of %f, %u, %F or %U present.
 400 $exec =~ s/%[uU]/$choice/g;
 401
 402 # The translated name of the application.
 403 $exec =~ s/%c/$name/g;
 404
 405 # XXX: Icons are not implemented. Is the complexity (looking up the path if
 406 # only a name is given) actually worth it?
 407 #$exec =~ s/%i/--icon $icon/g;
 408 $exec =~ s/%i//g;
 409
 410 # location of .desktop file
 411 $exec =~ s/%k/$location/g;
 412
 413 # Literal % characters are represented as %%.
 414 $exec =~ s/%%/%/g;
 415
 416 if (exists($app->{Path}) && $app->{Path} ne '') {
 417     $exec = 'cd ' . quote($app->{Path}) . ' && ' . $exec;
 418 }
 419
 420 my $nosn = '';
 421 my $cmd;
 422 if (exists($app->{Terminal}) && $app->{Terminal}) {
 423     # For applications which specify “Terminal=true” (e.g. htop.desktop),
 424     # we need to create a temporary script that contains the full command line
 425     # as the syntax for starting commands with arguments varies from terminal
 426     # emulator to terminal emulator.
 427     # Then, we launch that script with i3-sensible-terminal.
 428     my ($fh, $filename) = tempfile();
 429     binmode($fh, ':utf8');
 430     say $fh <<EOT;
 431 #!/bin/sh
 432 rm $filename
 433 exec $exec
 434 EOT
 435     close($fh);
 436     chmod 0755, $filename;
 437
 438     $cmd = qq|exec i3-sensible-terminal -e "$filename"|;
 439 } else {
 440     # i3 executes applications by passing the argument to i3’s “exec” command
 441     # as-is to $SHELL -c. The i3 parser supports quoted strings: When a string
 442     # starts with a double quote ("), everything is parsed as-is until the next
 443     # double quote which is NOT preceded by a backslash (\).
 444     #
 445     # Therefore, we escape all double quotes (") by replacing them with \"
 446     $exec =~ s/"/\\"/g;
 447
 448     if (exists($app->{StartupNotify}) && !$app->{StartupNotify}) {
 449         $nosn = '--no-startup-id';
 450     }
 451     $cmd = qq|exec $nosn "$exec"|;
 452 }
 453
 454 system('i3-msg', $cmd) == 0 or die "Could not launch i3-msg: $?";
 455
 456 =encoding utf-8
 457
 458 =head1 NAME
 459
 460     i3-dmenu-desktop - run .desktop files with dmenu
 461
 462 =head1 SYNOPSIS
 463
 464     i3-dmenu-desktop [--dmenu='dmenu -i'] [--entry-type=name]
 465
 466 =head1 DESCRIPTION
 467
 468 i3-dmenu-desktop is a script which extracts the (localized) name from
 469 application .desktop files, offers the user a choice via dmenu(1) and then
 470 starts the chosen application via i3 (for startup notification support).
 471 The advantage of using .desktop files instead of dmenu_run(1) is that dmenu_run
 472 offers B<all> binaries in your $PATH, including non-interactive utilities like
 473 "sed". Also, .desktop files contain a proper name, information about whether
 474 the application runs in a terminal and whether it supports startup
 475 notifications.
 476
 477 The .desktop files are searched in $XDG_DATA_HOME/applications (by default
 478 $HOME/.local/share/applications) and in the "applications" subdirectory of each
 479 entry of $XDG_DATA_DIRS (by default /usr/local/share/:/usr/share/).
 480
 481 Files with the same name in $XDG_DATA_HOME/applications take precedence over
 482 files in $XDG_DATA_DIRS, so that you can overwrite parts of the system-wide
 483 .desktop files by copying them to your local directory and making changes.
 484
 485 i3-dmenu-desktop displays the "Name" value in the localized version depending
 486 on LC_MESSAGES as specified in the Desktop Entry Specification.
 487
 488 You can pass a filename or URL (%f/%F and %u/%U field codes in the .desktop
 489 file respectively) by appending it to the name of the application. E.g., if you
 490 want to launch "GNU Emacs 24" with the patch /tmp/foobar.txt, you would type
 491 "emacs", press TAB, type " /tmp/foobar.txt" and press ENTER.
 492
 493 .desktop files with Terminal=true are started using i3-sensible-terminal(1).
 494
 495 .desktop files with NoDisplay=true or Hidden=true are skipped.
 496
 497 UTF-8 is supported, of course, but dmenu does not support displaying all
 498 glyphs. E.g., xfce4-terminal.desktop's Name[fi]=Pääte will be displayed just
 499 fine, but not its Name[ru]=Терминал.
 500
 501 =head1 OPTIONS
 502
 503 =over
 504
 505 =item B<--dmenu=command>
 506
 507 Execute command instead of 'dmenu -i'. This option can be used to pass custom
 508 parameters to dmenu, or to make i3-dmenu-desktop start a custom (patched?)
 509 version of dmenu.
 510
 511 =item B<--entry-type=type>
 512
 513 Display the (localized) "Name" (type = name), the command (type = command) or
 514 the (*.desktop) filename (type = filename) in dmenu. This option can be
 515 specified multiple times.
 516
 517 Examples are "GNU Image Manipulation Program" (type = name), "gimp" (type =
 518 command), and "libreoffice-writer" (type = filename).
 519
 520 =back
 521
 522 =head1 VERSION
 523
 524 Version 1.5
 525
 526 =head1 AUTHOR
 527
 528 Michael Stapelberg, C<< <michael at i3wm.org> >>
 529
 530 =head1 LICENSE AND COPYRIGHT
 531
 532 Copyright 2012 Michael Stapelberg.
 533
 534 This program is free software; you can redistribute it and/or modify it
 535 under the terms of the BSD license.
 536
 537 =cut