git.sur5r.net Git - i3/i3/blob - src/cfgparse.l

   1 /*
   2  * vim:ts=4:sw=4:expandtab
   3  *
   4  */
   5 %option nounput
   6 %option noinput
   7 %option noyy_top_state
   8 %option stack
   9
  10 %{
  11 #include <stdio.h>
  12 #include <string.h>
  13 #include <stdint.h>
  14 #include <xcb/xcb.h>
  15
  16 #include "log.h"
  17 #include "data.h"
  18 #include "config.h"
  19 #include "util.h"
  20 #include "libi3.h"
  21
  22 #include "cfgparse.tab.h"
  23
  24 int yycolumn = 1;
  25
  26 #define YY_DECL int yylex (struct context *context)
  27
  28 #define YY_USER_ACTION { \
  29     context->first_column = yycolumn; \
  30     context->last_column = yycolumn+yyleng-1; \
  31     yycolumn += yyleng; \
  32 }
  33
  34 /* macro to first eat whitespace, then expect a string */
  35 #define WS_STRING do { \
  36     yy_push_state(WANT_STRING); \
  37     yy_push_state(EAT_WHITESPACE); \
  38 } while (0)
  39
  40 #define BAR_TRIPLE_COLOR do { \
  41     yy_push_state(BAR_COLOR); \
  42     yy_push_state(BAR_COLOR); \
  43     yy_push_state(BAR_COLOR); \
  44 } while (0)
  45
  46 %}
  47
  48 EOL     (\r?\n)
  49
  50 %s WANT_STRING
  51 %s WANT_QSTRING
  52 %s BINDSYM_COND
  53 %s ASSIGN_COND
  54 %s ASSIGN_TARGET_COND
  55 %s COLOR_COND
  56 %s OUTPUT_COND
  57 %s FOR_WINDOW_COND
  58 %s EAT_WHITESPACE
  59
  60 %x BUFFER_LINE
  61 %x BAR
  62 %x BAR_MODE
  63 %x BAR_MODIFIER
  64 %x BAR_POSITION
  65 %x BAR_COLORS
  66 %x BAR_COLOR
  67
  68 %x EXEC
  69 %x OPTRELEASE
  70
  71 %%
  72
  73     {
  74         /* This is called when a new line is lexed. We only want the
  75          * first line to match to go into state BUFFER_LINE */
  76         if (context->line_number == 0) {
  77             context->line_number = 1;
  78             BEGIN(INITIAL);
  79             yy_push_state(BUFFER_LINE);
  80         }
  81     }
  82
  83 <BUFFER_LINE>^[^\r\n]*/{EOL}? {
  84     /* save whole line */
  85     context->line_copy = sstrdup(yytext);
  86
  87     yyless(0);
  88     yy_pop_state();
  89     yy_set_bol(true);
  90     yycolumn = 1;
  91 }
  92
  93  /* This part of the lexer handles the bar {} blocks */
  94 <BAR,BAR_MODE,BAR_MODIFIER,BAR_POSITION,BAR_COLORS,BAR_COLOR>[ \t]+ { /* ignore whitespace */ ; }
  95 <BAR>"{"                        { return '{'; }
  96 <BAR>"}"                        { yy_pop_state(); return '}'; }
  97 <BAR>^[ \t]*#[^\n]*             { return TOKCOMMENT; }
  98 <BAR>output                     { WS_STRING; return TOK_BAR_OUTPUT; }
  99 <BAR>tray_output                { WS_STRING; return TOK_BAR_TRAY_OUTPUT; }
 100 <BAR>socket_path                { WS_STRING; return TOK_BAR_SOCKET_PATH; }
 101 <BAR>mode                       { yy_push_state(BAR_MODE); return TOK_BAR_MODE; }
 102 <BAR_MODE>hide                  { yy_pop_state(); return TOK_BAR_HIDE; }
 103 <BAR_MODE>dock                  { yy_pop_state(); return TOK_BAR_DOCK; }
 104 <BAR>modifier                   { yy_push_state(BAR_MODIFIER); return TOK_BAR_MODIFIER; }
 105 <BAR_MODIFIER>control           { yy_pop_state(); return TOK_BAR_CONTROL; }
 106 <BAR_MODIFIER>ctrl              { yy_pop_state(); return TOK_BAR_CONTROL; }
 107 <BAR_MODIFIER>shift             { yy_pop_state(); return TOK_BAR_SHIFT; }
 108 <BAR_MODIFIER>Mod1              { yy_pop_state(); return TOK_BAR_MOD1; }
 109 <BAR_MODIFIER>Mod2              { yy_pop_state(); return TOK_BAR_MOD2; }
 110 <BAR_MODIFIER>Mod3              { yy_pop_state(); return TOK_BAR_MOD3; }
 111 <BAR_MODIFIER>Mod4              { yy_pop_state(); return TOK_BAR_MOD4; }
 112 <BAR_MODIFIER>Mod5              { yy_pop_state(); return TOK_BAR_MOD5; }
 113 <BAR>position                   { yy_push_state(BAR_POSITION); return TOK_BAR_POSITION; }
 114 <BAR_POSITION>bottom            { yy_pop_state(); return TOK_BAR_BOTTOM; }
 115 <BAR_POSITION>top               { yy_pop_state(); return TOK_BAR_TOP; }
 116 <BAR>status_command             { WS_STRING; return TOK_BAR_STATUS_COMMAND; }
 117 <BAR>i3bar_command              { WS_STRING; return TOK_BAR_I3BAR_COMMAND; }
 118 <BAR>font                       { WS_STRING; return TOK_BAR_FONT; }
 119 <BAR>workspace_buttons          { return TOK_BAR_WORKSPACE_BUTTONS; }
 120 <BAR>verbose                    { return TOK_BAR_VERBOSE; }
 121 <BAR>colors                     { yy_push_state(BAR_COLORS); return TOK_BAR_COLORS; }
 122 <BAR_COLORS>"{"                 { return '{'; }
 123 <BAR_COLORS>"}"                 { yy_pop_state(); return '}'; }
 124 <BAR_COLORS>^[ \t]*#[^\n]*      { return TOKCOMMENT; }
 125 <BAR_COLORS>background          { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_BACKGROUND; }
 126 <BAR_COLORS>statusline          { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_STATUSLINE; }
 127 <BAR_COLORS>focused_workspace   { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_FOCUSED_WORKSPACE; }
 128 <BAR_COLORS>active_workspace    { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_ACTIVE_WORKSPACE; }
 129 <BAR_COLORS>inactive_workspace  { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_INACTIVE_WORKSPACE; }
 130 <BAR_COLORS>urgent_workspace    { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_URGENT_WORKSPACE; }
 131 <BAR_COLOR>#[0-9a-fA-F]+        { yy_pop_state(); yylval.string = sstrdup(yytext); return HEXCOLOR; }
 132 <BAR_COLOR>{EOL}                {
 133                                   yy_pop_state();
 134                                   FREE(context->line_copy);
 135                                   context->line_number++;
 136                                   yy_push_state(BUFFER_LINE);
 137                                 }
 138 <BAR,BAR_COLORS,BAR_MODE,BAR_MODIFIER,BAR_POSITION>[a-zA-Z]+ { yylval.string = sstrdup(yytext); return WORD; }
 139
 140
 141
 142 <FOR_WINDOW_COND>"]"            { yy_pop_state(); return ']'; }
 143 <ASSIGN_COND>"["                {
 144                                   /* this is the case for the new assign syntax
 145                                    * that uses criteria */
 146                                   yy_pop_state();
 147                                   yy_push_state(FOR_WINDOW_COND);
 148                                   /* afterwards we will be in ASSIGN_TARGET_COND */
 149                                   return '[';
 150                                 }
 151 <EAT_WHITESPACE>[ \t]*          { yy_pop_state(); }
 152 <EAT_WHITESPACE>{EOL}           { yy_pop_state(); }
 153 <BINDSYM_COND>{EOL}             { yy_pop_state(); }
 154 <WANT_QSTRING>\"[^\"]+\"        {
 155                                   yy_pop_state();
 156                                   /* strip quotes */
 157                                   char *copy = sstrdup(yytext+1);
 158                                   copy[strlen(copy)-1] = '\0';
 159                                   yylval.string = copy;
 160                                   return STR;
 161                                 }
 162 <WANT_STRING>[^\n]+             { yy_pop_state(); yylval.string = sstrdup(yytext); return STR; }
 163 <OUTPUT_COND>[a-zA-Z0-9\/_-]+   { yy_pop_state(); yylval.string = sstrdup(yytext); return OUTPUT; }
 164 ^[ \t]*#[^\n]*                  { return TOKCOMMENT; }
 165 <COLOR_COND>#[0-9a-fA-F]+       { yy_pop_state(); yylval.string = sstrdup(yytext); return HEXCOLOR; }
 166 <COLOR_COND>{EOL}               {
 167                                   yy_pop_state();
 168                                   FREE(context->line_copy);
 169                                   context->line_number++;
 170                                   yy_push_state(BUFFER_LINE);
 171                                 }
 172 <ASSIGN_TARGET_COND>[ \t]*→[ \t]*     { BEGIN(WANT_STRING); }
 173 <ASSIGN_TARGET_COND>[ \t]+      { BEGIN(WANT_STRING); }
 174 <EXEC>--no-startup-id           { printf("no startup id\n"); yy_pop_state(); return TOK_NO_STARTUP_ID; }
 175 <EXEC>.                         { printf("anything else: *%s*\n", yytext); yyless(0); yy_pop_state(); yy_pop_state(); }
 176 <OPTRELEASE>--release           { printf("--release\n"); yy_pop_state(); return TOK_RELEASE; }
 177 <OPTRELEASE>.                   { printf("anything else (optrelease): *%s*\n", yytext); yyless(0); yy_pop_state(); yy_pop_state(); }
 178 [0-9-]+                         { yylval.number = atoi(yytext); return NUMBER; }
 179 bar                             { yy_push_state(BAR); return TOK_BAR; }
 180 mode                            { return TOKMODE; }
 181 bind                            { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
 182 bindcode                        { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); yy_push_state(OPTRELEASE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
 183 bindsym                         { yy_push_state(BINDSYM_COND); yy_push_state(EAT_WHITESPACE); yy_push_state(OPTRELEASE); yy_push_state(EAT_WHITESPACE); return TOKBINDSYM; }
 184 floating_maximum_size           { return TOKFLOATING_MAXIMUM_SIZE; }
 185 floating_minimum_size           { return TOKFLOATING_MINIMUM_SIZE; }
 186 floating_modifier               { return TOKFLOATING_MODIFIER; }
 187 workspace                       { return TOKWORKSPACE; }
 188 output                          { yy_push_state(OUTPUT_COND); yy_push_state(EAT_WHITESPACE); return TOKOUTPUT; }
 189 terminal                        { WS_STRING; return TOKTERMINAL; }
 190 font                            { WS_STRING; return TOKFONT; }
 191 assign                          { yy_push_state(ASSIGN_TARGET_COND); yy_push_state(ASSIGN_COND); return TOKASSIGN; }
 192 set[^\n]*                       { return TOKCOMMENT; }
 193 ipc-socket                      { WS_STRING; return TOKIPCSOCKET; }
 194 ipc_socket                      { WS_STRING; return TOKIPCSOCKET; }
 195 restart_state                   { WS_STRING; return TOKRESTARTSTATE; }
 196 default_orientation             { return TOK_ORIENTATION; }
 197 horizontal                      { return TOK_HORIZ; }
 198 vertical                        { return TOK_VERT; }
 199 auto                            { return TOK_AUTO; }
 200 workspace_layout                { return TOK_WORKSPACE_LAYOUT; }
 201 new_window                      { return TOKNEWWINDOW; }
 202 new_float                       { return TOKNEWFLOAT; }
 203 normal                          { return TOK_NORMAL; }
 204 none                            { return TOK_NONE; }
 205 1pixel                          { return TOK_1PIXEL; }
 206 hide_edge_borders               { return TOK_HIDE_EDGE_BORDERS; }
 207 both                            { return TOK_BOTH; }
 208 focus_follows_mouse             { return TOKFOCUSFOLLOWSMOUSE; }
 209 force_focus_wrapping            { return TOK_FORCE_FOCUS_WRAPPING; }
 210 force_xinerama                  { return TOK_FORCE_XINERAMA; }
 211 force-xinerama                  { return TOK_FORCE_XINERAMA; }
 212 fake_outputs                    { WS_STRING; return TOK_FAKE_OUTPUTS; }
 213 fake-outputs                    { WS_STRING; return TOK_FAKE_OUTPUTS; }
 214 workspace_auto_back_and_forth   { return TOK_WORKSPACE_AUTO_BAF; }
 215 workspace_bar                   { return TOKWORKSPACEBAR; }
 216 popup_during_fullscreen         { return TOK_POPUP_DURING_FULLSCREEN; }
 217 ignore                          { return TOK_IGNORE; }
 218 leave_fullscreen                { return TOK_LEAVE_FULLSCREEN; }
 219 for_window                      {
 220                                   /* Example: for_window [class="urxvt"] border none
 221                                    *
 222                                    * First, we wait for the ']' that finishes a match (FOR_WINDOW_COND)
 223                                    * Then, we require a whitespace (EAT_WHITESPACE)
 224                                    * And the rest of the line is parsed as a string
 225                                    */
 226                                   yy_push_state(WANT_STRING);
 227                                   yy_push_state(EAT_WHITESPACE);
 228                                   yy_push_state(FOR_WINDOW_COND);
 229                                   return TOK_FOR_WINDOW;
 230                                 }
 231 default                         { /* yylval.number = MODE_DEFAULT; */return TOK_DEFAULT; }
 232 stacking                        { /* yylval.number = MODE_STACK; */return TOK_STACKING; }
 233 stacked                         { return TOK_STACKING; }
 234 tabbed                          { /* yylval.number = MODE_TABBED; */return TOK_TABBED; }
 235 stack-limit                     { return TOKSTACKLIMIT; }
 236 cols                            { /* yylval.number = STACK_LIMIT_COLS; */return TOKSTACKLIMIT; }
 237 rows                            { /* yylval.number = STACK_LIMIT_ROWS; */return TOKSTACKLIMIT; }
 238 exec                            { WS_STRING; yy_push_state(EXEC); yy_push_state(EAT_WHITESPACE); return TOKEXEC; }
 239 exec_always                     { WS_STRING; yy_push_state(EXEC); yy_push_state(EAT_WHITESPACE); return TOKEXEC_ALWAYS; }
 240 client.background               { yy_push_state(COLOR_COND); yylval.single_color = &config.client.background; return TOKSINGLECOLOR; }
 241 client.focused                  { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.focused; return TOKCOLOR; }
 242 client.focused_inactive         { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.focused_inactive; return TOKCOLOR; }
 243 client.unfocused                { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.unfocused; return TOKCOLOR; }
 244 client.urgent                   { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.urgent; return TOKCOLOR; }
 245 bar.focused                     { yy_push_state(COLOR_COND); yylval.color = &config.bar.focused; return TOKCOLOR; }
 246 bar.unfocused                   { yy_push_state(COLOR_COND); yylval.color = &config.bar.unfocused; return TOKCOLOR; }
 247 bar.urgent                      { yy_push_state(COLOR_COND); yylval.color = &config.bar.urgent; return TOKCOLOR; }
 248 Mod1                            { yylval.number = BIND_MOD1; return MODIFIER; }
 249 Mod2                            { yylval.number = BIND_MOD2; return MODIFIER; }
 250 Mod3                            { yylval.number = BIND_MOD3; return MODIFIER; }
 251 Mod4                            { yylval.number = BIND_MOD4; return MODIFIER; }
 252 Mod5                            { yylval.number = BIND_MOD5; return MODIFIER; }
 253 Mode_switch                     { yylval.number = BIND_MODE_SWITCH; return MODIFIER; }
 254 control                         { return TOKCONTROL; }
 255 ctrl                            { return TOKCONTROL; }
 256 shift                           { return TOKSHIFT; }
 257
 258 class                           { yy_push_state(WANT_QSTRING); return TOK_CLASS; }
 259 instance                        { yy_push_state(WANT_QSTRING); return TOK_INSTANCE; }
 260 window_role                     { yy_push_state(WANT_QSTRING); return TOK_WINDOW_ROLE; }
 261 id                              { yy_push_state(WANT_QSTRING); return TOK_ID; }
 262 con_id                          { yy_push_state(WANT_QSTRING); return TOK_CON_ID; }
 263 con_mark                        { yy_push_state(WANT_QSTRING); return TOK_MARK; }
 264 title                           { yy_push_state(WANT_QSTRING); return TOK_TITLE; }
 265 urgent                          { yy_push_state(WANT_QSTRING); return TOK_URGENT; }
 266
 267 <*>{EOL}                        {
 268                                   FREE(context->line_copy);
 269                                   context->line_number++;
 270                                   yy_push_state(BUFFER_LINE);
 271                                 }
 272 <BINDSYM_COND>[ \t]+            { yy_pop_state(); yy_push_state(WANT_STRING); }
 273 <OUTPUT_COND>[ \t]+             { yy_pop_state(); yy_push_state(WANT_STRING); }
 274 [ \t]+                          { /* ignore whitespace */ ; }
 275 \"[^\"]+\"                      {
 276                                   /* if ASSIGN_COND then */
 277                                   if (yy_start_stack_ptr > 0)
 278                                       yy_pop_state();
 279                                   /* yylval will be the string, but without quotes */
 280                                   char *copy = sstrdup(yytext+1);
 281                                   copy[strlen(copy)-1] = '\0';
 282                                   yylval.string = copy;
 283                                   return QUOTEDSTRING;
 284                                 }
 285 <ASSIGN_COND>[^ \t\"\[]+        { BEGIN(ASSIGN_TARGET_COND); yylval.string = sstrdup(yytext); return STR_NG; }
 286 <BINDSYM_COND>[a-zA-Z0-9_]+     { yylval.string = sstrdup(yytext); return WORD; }
 287 [a-zA-Z]+                       { yylval.string = sstrdup(yytext); return WORD; }
 288 .                               { return (int)yytext[0]; }
 289
 290 <<EOF>> {
 291     while (yy_start_stack_ptr > 0)
 292         yy_pop_state();
 293     yyterminate();
 294 }
 295
 296 %%