git.sur5r.net Git - i3/i3/blob - src/cfgparse.l

   1 /*
   2  * vim:ts=4:sw=4:expandtab
   3  *
   4  */
   5 %option nounput
   6 %option noinput
   7 %option noyy_top_state
   8 %option stack
   9
  10 %{
  11 #include <stdio.h>
  12 #include <string.h>
  13 #include <stdint.h>
  14 #include <xcb/xcb.h>
  15
  16 #include "log.h"
  17 #include "data.h"
  18 #include "config.h"
  19 #include "util.h"
  20 #include "libi3.h"
  21
  22 #include "cfgparse.tab.h"
  23
  24 int yycolumn = 1;
  25
  26 #define YY_DECL int yylex (struct context *context)
  27
  28 #define YY_USER_ACTION { \
  29     context->first_column = yycolumn; \
  30     context->last_column = yycolumn+yyleng-1; \
  31     yycolumn += yyleng; \
  32 }
  33
  34 /* macro to first eat whitespace, then expect a string */
  35 #define WS_STRING do { \
  36     yy_push_state(WANT_STRING); \
  37     yy_push_state(EAT_WHITESPACE); \
  38 } while (0)
  39
  40 #define BAR_TRIPLE_COLOR do { \
  41     yy_push_state(BAR_COLOR); \
  42     yy_push_state(BAR_COLOR); \
  43     yy_push_state(BAR_COLOR); \
  44 } while (0)
  45
  46 %}
  47
  48 EOL     (\r?\n)
  49
  50 %s WANT_STRING
  51 %s WANT_QSTRING
  52 %s BINDSYM_COND
  53 %s ASSIGN_COND
  54 %s ASSIGN_TARGET_COND
  55 %s COLOR_COND
  56 %s OUTPUT_COND
  57 %s FOR_WINDOW_COND
  58 %s EAT_WHITESPACE
  59
  60 %x BUFFER_LINE
  61 %x BAR
  62 %x BAR_MODE
  63 %x BAR_MODIFIER
  64 %x BAR_POSITION
  65 %x BAR_COLORS
  66 %x BAR_COLOR
  67
  68 %x EXEC
  69
  70 %%
  71
  72     {
  73         /* This is called when a new line is lexed. We only want the
  74          * first line to match to go into state BUFFER_LINE */
  75         if (context->line_number == 0) {
  76             context->line_number = 1;
  77             BEGIN(INITIAL);
  78             yy_push_state(BUFFER_LINE);
  79         }
  80     }
  81
  82 <BUFFER_LINE>^[^\r\n]*/{EOL}? {
  83     /* save whole line */
  84     context->line_copy = sstrdup(yytext);
  85
  86     yyless(0);
  87     yy_pop_state();
  88     yy_set_bol(true);
  89     yycolumn = 1;
  90 }
  91
  92  /* This part of the lexer handles the bar {} blocks */
  93 <BAR,BAR_MODE,BAR_MODIFIER,BAR_POSITION,BAR_COLORS,BAR_COLOR>[ \t]+ { /* ignore whitespace */ ; }
  94 <BAR>"{"                        { return '{'; }
  95 <BAR>"}"                        { yy_pop_state(); return '}'; }
  96 <BAR>^[ \t]*#[^\n]*             { return TOKCOMMENT; }
  97 <BAR>output                     { WS_STRING; return TOK_BAR_OUTPUT; }
  98 <BAR>tray_output                { WS_STRING; return TOK_BAR_TRAY_OUTPUT; }
  99 <BAR>socket_path                { WS_STRING; return TOK_BAR_SOCKET_PATH; }
 100 <BAR>mode                       { yy_push_state(BAR_MODE); return TOK_BAR_MODE; }
 101 <BAR_MODE>hide                  { yy_pop_state(); return TOK_BAR_HIDE; }
 102 <BAR_MODE>dock                  { yy_pop_state(); return TOK_BAR_DOCK; }
 103 <BAR>modifier                   { yy_push_state(BAR_MODIFIER); return TOK_BAR_MODIFIER; }
 104 <BAR_MODIFIER>control           { yy_pop_state(); return TOK_BAR_CONTROL; }
 105 <BAR_MODIFIER>ctrl              { yy_pop_state(); return TOK_BAR_CONTROL; }
 106 <BAR_MODIFIER>shift             { yy_pop_state(); return TOK_BAR_SHIFT; }
 107 <BAR_MODIFIER>Mod1              { yy_pop_state(); return TOK_BAR_MOD1; }
 108 <BAR_MODIFIER>Mod2              { yy_pop_state(); return TOK_BAR_MOD2; }
 109 <BAR_MODIFIER>Mod3              { yy_pop_state(); return TOK_BAR_MOD3; }
 110 <BAR_MODIFIER>Mod4              { yy_pop_state(); return TOK_BAR_MOD4; }
 111 <BAR_MODIFIER>Mod5              { yy_pop_state(); return TOK_BAR_MOD5; }
 112 <BAR>position                   { yy_push_state(BAR_POSITION); return TOK_BAR_POSITION; }
 113 <BAR_POSITION>bottom            { yy_pop_state(); return TOK_BAR_BOTTOM; }
 114 <BAR_POSITION>top               { yy_pop_state(); return TOK_BAR_TOP; }
 115 <BAR>status_command             { WS_STRING; return TOK_BAR_STATUS_COMMAND; }
 116 <BAR>i3bar_command              { WS_STRING; return TOK_BAR_I3BAR_COMMAND; }
 117 <BAR>font                       { WS_STRING; return TOK_BAR_FONT; }
 118 <BAR>workspace_buttons          { return TOK_BAR_WORKSPACE_BUTTONS; }
 119 <BAR>verbose                    { return TOK_BAR_VERBOSE; }
 120 <BAR>colors                     { yy_push_state(BAR_COLORS); return TOK_BAR_COLORS; }
 121 <BAR_COLORS>"{"                 { return '{'; }
 122 <BAR_COLORS>"}"                 { yy_pop_state(); return '}'; }
 123 <BAR_COLORS>^[ \t]*#[^\n]*      { return TOKCOMMENT; }
 124 <BAR_COLORS>background          { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_BACKGROUND; }
 125 <BAR_COLORS>statusline          { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_STATUSLINE; }
 126 <BAR_COLORS>focused_workspace   { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_FOCUSED_WORKSPACE; }
 127 <BAR_COLORS>active_workspace    { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_ACTIVE_WORKSPACE; }
 128 <BAR_COLORS>inactive_workspace  { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_INACTIVE_WORKSPACE; }
 129 <BAR_COLORS>urgent_workspace    { BAR_TRIPLE_COLOR; return TOK_BAR_COLOR_URGENT_WORKSPACE; }
 130 <BAR_COLOR>#[0-9a-fA-F]+        { yy_pop_state(); yylval.string = sstrdup(yytext); return HEXCOLOR; }
 131 <BAR_COLOR>{EOL}                {
 132                                   yy_pop_state();
 133                                   FREE(context->line_copy);
 134                                   context->line_number++;
 135                                   yy_push_state(BUFFER_LINE);
 136                                 }
 137 <BAR,BAR_COLORS,BAR_MODE,BAR_MODIFIER,BAR_POSITION>[a-zA-Z]+ { yylval.string = sstrdup(yytext); return WORD; }
 138
 139
 140
 141 <FOR_WINDOW_COND>"]"            { yy_pop_state(); return ']'; }
 142 <ASSIGN_COND>"["                {
 143                                   /* this is the case for the new assign syntax
 144                                    * that uses criteria */
 145                                   yy_pop_state();
 146                                   yy_push_state(FOR_WINDOW_COND);
 147                                   /* afterwards we will be in ASSIGN_TARGET_COND */
 148                                   return '[';
 149                                 }
 150 <EAT_WHITESPACE>[ \t]*          { yy_pop_state(); }
 151 <WANT_QSTRING>\"[^\"]+\"        {
 152                                   yy_pop_state();
 153                                   /* strip quotes */
 154                                   char *copy = sstrdup(yytext+1);
 155                                   copy[strlen(copy)-1] = '\0';
 156                                   yylval.string = copy;
 157                                   return STR;
 158                                 }
 159 <WANT_STRING>[^\n]+             { yy_pop_state(); yylval.string = sstrdup(yytext); return STR; }
 160 <OUTPUT_COND>[a-zA-Z0-9_-]+     { yy_pop_state(); yylval.string = sstrdup(yytext); return OUTPUT; }
 161 ^[ \t]*#[^\n]*                  { return TOKCOMMENT; }
 162 <COLOR_COND>#[0-9a-fA-F]+       { yy_pop_state(); yylval.string = sstrdup(yytext); return HEXCOLOR; }
 163 <COLOR_COND>{EOL}               {
 164                                   yy_pop_state();
 165                                   FREE(context->line_copy);
 166                                   context->line_number++;
 167                                   yy_push_state(BUFFER_LINE);
 168                                 }
 169 <ASSIGN_TARGET_COND>[ \t]*→[ \t]*     { BEGIN(WANT_STRING); }
 170 <ASSIGN_TARGET_COND>[ \t]+      { BEGIN(WANT_STRING); }
 171 <EXEC>--no-startup-id           { printf("no startup id\n"); yy_pop_state(); return TOK_NO_STARTUP_ID; }
 172 <EXEC>.                         { printf("anything else: *%s*\n", yytext); yyless(0); yy_pop_state(); yy_pop_state(); }
 173 [0-9]+                          { yylval.number = atoi(yytext); return NUMBER; }
 174 bar                             { yy_push_state(BAR); return TOK_BAR; }
 175 mode                            { return TOKMODE; }
 176 bind                            { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
 177 bindcode                        { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
 178 bindsym                         { yy_push_state(BINDSYM_COND); yy_push_state(EAT_WHITESPACE); return TOKBINDSYM; }
 179 floating_modifier               { return TOKFLOATING_MODIFIER; }
 180 workspace                       { return TOKWORKSPACE; }
 181 output                          { yy_push_state(OUTPUT_COND); yy_push_state(EAT_WHITESPACE); return TOKOUTPUT; }
 182 terminal                        { WS_STRING; return TOKTERMINAL; }
 183 font                            { WS_STRING; return TOKFONT; }
 184 assign                          { yy_push_state(ASSIGN_TARGET_COND); yy_push_state(ASSIGN_COND); return TOKASSIGN; }
 185 set[^\n]*                       { return TOKCOMMENT; }
 186 ipc-socket                      { WS_STRING; return TOKIPCSOCKET; }
 187 ipc_socket                      { WS_STRING; return TOKIPCSOCKET; }
 188 restart_state                   { WS_STRING; return TOKRESTARTSTATE; }
 189 default_orientation             { return TOK_ORIENTATION; }
 190 horizontal                      { return TOK_HORIZ; }
 191 vertical                        { return TOK_VERT; }
 192 auto                            { return TOK_AUTO; }
 193 workspace_layout                { return TOK_WORKSPACE_LAYOUT; }
 194 new_window                      { return TOKNEWWINDOW; }
 195 new_float                       { return TOKNEWFLOAT; }
 196 normal                          { return TOK_NORMAL; }
 197 none                            { return TOK_NONE; }
 198 1pixel                          { return TOK_1PIXEL; }
 199 focus_follows_mouse             { return TOKFOCUSFOLLOWSMOUSE; }
 200 force_focus_wrapping            { return TOK_FORCE_FOCUS_WRAPPING; }
 201 force_xinerama                  { return TOK_FORCE_XINERAMA; }
 202 workspace_auto_back_and_forth   { return TOK_WORKSPACE_AUTO_BAF; }
 203 workspace_bar                   { return TOKWORKSPACEBAR; }
 204 popup_during_fullscreen         { return TOK_POPUP_DURING_FULLSCREEN; }
 205 ignore                          { return TOK_IGNORE; }
 206 leave_fullscreen                { return TOK_LEAVE_FULLSCREEN; }
 207 for_window                      {
 208                                   /* Example: for_window [class="urxvt"] border none
 209                                    *
 210                                    * First, we wait for the ']' that finishes a match (FOR_WINDOW_COND)
 211                                    * Then, we require a whitespace (EAT_WHITESPACE)
 212                                    * And the rest of the line is parsed as a string
 213                                    */
 214                                   yy_push_state(WANT_STRING);
 215                                   yy_push_state(EAT_WHITESPACE);
 216                                   yy_push_state(FOR_WINDOW_COND);
 217                                   return TOK_FOR_WINDOW;
 218                                 }
 219 default                         { /* yylval.number = MODE_DEFAULT; */return TOK_DEFAULT; }
 220 stacking                        { /* yylval.number = MODE_STACK; */return TOK_STACKING; }
 221 stacked                         { return TOK_STACKING; }
 222 tabbed                          { /* yylval.number = MODE_TABBED; */return TOK_TABBED; }
 223 stack-limit                     { return TOKSTACKLIMIT; }
 224 cols                            { /* yylval.number = STACK_LIMIT_COLS; */return TOKSTACKLIMIT; }
 225 rows                            { /* yylval.number = STACK_LIMIT_ROWS; */return TOKSTACKLIMIT; }
 226 exec                            { WS_STRING; yy_push_state(EXEC); yy_push_state(EAT_WHITESPACE); return TOKEXEC; }
 227 exec_always                     { WS_STRING; yy_push_state(EXEC); yy_push_state(EAT_WHITESPACE); return TOKEXEC_ALWAYS; }
 228 client.background               { yy_push_state(COLOR_COND); yylval.single_color = &config.client.background; return TOKSINGLECOLOR; }
 229 client.focused                  { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.focused; return TOKCOLOR; }
 230 client.focused_inactive         { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.focused_inactive; return TOKCOLOR; }
 231 client.unfocused                { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.unfocused; return TOKCOLOR; }
 232 client.urgent                   { yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yy_push_state(COLOR_COND); yylval.color = &config.client.urgent; return TOKCOLOR; }
 233 bar.focused                     { yy_push_state(COLOR_COND); yylval.color = &config.bar.focused; return TOKCOLOR; }
 234 bar.unfocused                   { yy_push_state(COLOR_COND); yylval.color = &config.bar.unfocused; return TOKCOLOR; }
 235 bar.urgent                      { yy_push_state(COLOR_COND); yylval.color = &config.bar.urgent; return TOKCOLOR; }
 236 Mod1                            { yylval.number = BIND_MOD1; return MODIFIER; }
 237 Mod2                            { yylval.number = BIND_MOD2; return MODIFIER; }
 238 Mod3                            { yylval.number = BIND_MOD3; return MODIFIER; }
 239 Mod4                            { yylval.number = BIND_MOD4; return MODIFIER; }
 240 Mod5                            { yylval.number = BIND_MOD5; return MODIFIER; }
 241 Mode_switch                     { yylval.number = BIND_MODE_SWITCH; return MODIFIER; }
 242 control                         { return TOKCONTROL; }
 243 ctrl                            { return TOKCONTROL; }
 244 shift                           { return TOKSHIFT; }
 245
 246 class                           { yy_push_state(WANT_QSTRING); return TOK_CLASS; }
 247 instance                        { yy_push_state(WANT_QSTRING); return TOK_INSTANCE; }
 248 window_role                     { yy_push_state(WANT_QSTRING); return TOK_WINDOW_ROLE; }
 249 id                              { yy_push_state(WANT_QSTRING); return TOK_ID; }
 250 con_id                          { yy_push_state(WANT_QSTRING); return TOK_CON_ID; }
 251 con_mark                        { yy_push_state(WANT_QSTRING); return TOK_MARK; }
 252 title                           { yy_push_state(WANT_QSTRING); return TOK_TITLE; }
 253
 254 <*>{EOL}                        {
 255                                   FREE(context->line_copy);
 256                                   context->line_number++;
 257                                   yy_push_state(BUFFER_LINE);
 258                                 }
 259 <BINDSYM_COND>[ \t]+            { yy_pop_state(); yy_push_state(WANT_STRING); }
 260 <OUTPUT_COND>[ \t]+             { yy_pop_state(); yy_push_state(WANT_STRING); }
 261 [ \t]+                          { /* ignore whitespace */ ; }
 262 \"[^\"]+\"                      {
 263                                   /* if ASSIGN_COND then */
 264                                   if (yy_start_stack_ptr > 0)
 265                                       yy_pop_state();
 266                                   /* yylval will be the string, but without quotes */
 267                                   char *copy = sstrdup(yytext+1);
 268                                   copy[strlen(copy)-1] = '\0';
 269                                   yylval.string = copy;
 270                                   return QUOTEDSTRING;
 271                                 }
 272 <ASSIGN_COND>[^ \t\"\[]+        { BEGIN(ASSIGN_TARGET_COND); yylval.string = sstrdup(yytext); return STR_NG; }
 273 <BINDSYM_COND>[a-zA-Z0-9_]+     { yylval.string = sstrdup(yytext); return WORD; }
 274 [a-zA-Z]+                       { yylval.string = sstrdup(yytext); return WORD; }
 275 .                               { return (int)yytext[0]; }
 276
 277 <<EOF>> {
 278     while (yy_start_stack_ptr > 0)
 279         yy_pop_state();
 280     yyterminate();
 281 }
 282
 283 %%