git.sur5r.net Git - i3/i3/blob - testcases/complete-run.pl.in

   1 #!/usr/bin/env perl
   2 # vim:ts=4:sw=4:expandtab
   3 # © 2010 Michael Stapelberg and contributors
   4 package complete_run;
   5 use strict;
   6 use warnings;
   7 use v5.10;
   8 use utf8;
   9 # the following are modules which ship with Perl (>= 5.10):
  10 use Pod::Usage;
  11 use File::Temp qw(tempfile tempdir);
  12 use Getopt::Long;
  13 use POSIX ();
  14 use TAP::Harness;
  15 use TAP::Parser;
  16 use TAP::Parser::Aggregator;
  17 use Time::HiRes qw(time);
  18 use IO::Handle;
  19
  20 # these are shipped with the testsuite
  21 use lib qw(@abs_top_builddir@/testcases/lib @abs_top_srcdir@/testcases/lib @abs_top_srcdir@/AnyEvent-I3/blib/lib);
  22 use i3test::Util qw(slurp);
  23 use StartXServer;
  24 use StatusLine;
  25 use TestWorker;
  26 # the following modules are not shipped with Perl
  27 use AnyEvent;
  28 use AnyEvent::Util;
  29 use AnyEvent::Handle;
  30 use AnyEvent::I3 qw(:all);
  31 use X11::XCB::Connection;
  32 use JSON::XS; # AnyEvent::I3 depends on it, too.
  33
  34 binmode STDOUT, ':utf8';
  35 binmode STDERR, ':utf8';
  36
  37 # Close superfluous file descriptors which were passed by running in a VIM
  38 # subshell or situations like that.
  39 AnyEvent::Util::close_all_fds_except(0, 1, 2);
  40
  41 # convenience wrapper to write to the log file
  42 my $log;
  43 sub Log { say $log "@_" }
  44
  45 my %timings;
  46 my $help = 0;
  47 # Number of tests to run in parallel. Important to know how many Xephyr
  48 # instances we need to start (unless @displays are given). Defaults to
  49 # num_cores * 2.
  50 my $parallel = undef;
  51 my @displays = ();
  52 my %options = (
  53     valgrind => 0,
  54     strace => 0,
  55     xtrace => 0,
  56     coverage => 0,
  57     restart => 0,
  58 );
  59 my $keep_xserver_output = 0;
  60
  61 my $result = GetOptions(
  62     "coverage-testing" => \$options{coverage},
  63     "keep-xserver-output" => \$keep_xserver_output,
  64     "valgrind" => \$options{valgrind},
  65     "strace" => \$options{strace},
  66     "xtrace" => \$options{xtrace},
  67     "display=s" => \@displays,
  68     "parallel=i" => \$parallel,
  69     "help|?" => \$help,
  70 );
  71
  72 pod2usage(-verbose => 2, -exitcode => 0) if $help;
  73
  74 # Check for missing executables
  75 my @binaries = qw(
  76                    @abs_top_builddir@/i3
  77                    @abs_top_builddir@/i3bar/i3bar
  78                    @abs_top_builddir@/i3-config-wizard/i3-config-wizard
  79                    @abs_top_builddir@/i3-dump-log/i3-dump-log
  80                    @abs_top_builddir@/i3-input/i3-input
  81                    @abs_top_builddir@/i3-msg/i3-msg
  82                    @abs_top_builddir@/i3-nagbar/i3-nagbar
  83                );
  84
  85 foreach my $binary (@binaries) {
  86     die "$binary executable not found, did you run “make”?" unless -e $binary;
  87     die "$binary is not an executable" unless -x $binary;
  88 }
  89
  90 my @test_binaries = qw(
  91                         @abs_top_builddir@/test.commands_parser
  92                         @abs_top_builddir@/test.config_parser
  93                         @abs_top_builddir@/test.inject_randr15
  94                     );
  95
  96 foreach my $binary (@test_binaries) {
  97     die "$binary executable not found, did you run “make check”?" unless -e $binary;
  98     die "$binary is not an executable" unless -x $binary;
  99 }
 100
 101 $ENV{PATH} = join(':',
 102     '@abs_top_builddir@/i3-nagbar',
 103     '@abs_top_builddir@/i3-msg',
 104     '@abs_top_builddir@/i3-input',
 105     '@abs_top_builddir@/i3-dump-log',
 106     '@abs_top_builddir@/i3-config-wizard',
 107     '@abs_top_builddir@/i3bar',
 108     '@abs_top_builddir@',
 109     '@abs_top_srcdir@',
 110     $ENV{PATH});
 111
 112 qx(Xephyr -help 2>&1);
 113 die "Xephyr was not found in your path. Please install Xephyr (xserver-xephyr on Debian)." if $?;
 114
 115 @displays = split(/,/, join(',', @displays));
 116 @displays = map { s/ //g; $_ } @displays;
 117
 118 # 2: get a list of all testcases
 119 my @testfiles = @ARGV;
 120
 121 # if no files were passed on command line, run all tests from t/
 122 if (scalar @testfiles == 0) {
 123     @testfiles = <@abs_top_srcdir@/testcases/t/*.t> if @testfiles == 0;
 124 } else {
 125     @testfiles = map {
 126         # Fully qualify each specified file if necessary
 127         if (! -e $_) {
 128             $_ = "@abs_top_srcdir@/testcases/$_";
 129         }
 130         $_
 131     } @testfiles;
 132 }
 133
 134 my $numtests = scalar @testfiles;
 135
 136 # No displays specified, let’s start some Xephyr instances.
 137 if (@displays == 0) {
 138     @displays = start_xserver($parallel, $numtests, $keep_xserver_output);
 139 }
 140
 141 # 1: create an output directory for this test-run
 142 my $outdir = "testsuite-";
 143 $outdir .= POSIX::strftime("%Y-%m-%d-%H-%M-%S-", localtime());
 144 $outdir .= `git describe --tags`;
 145 chomp($outdir);
 146 mkdir($outdir) or die "Could not create $outdir";
 147 unlink("latest") if -l "latest";
 148 symlink("$outdir", "latest") or die "Could not symlink latest to $outdir";
 149
 150
 151 # connect to all displays for two reasons:
 152 # 1: check if the display actually works
 153 # 2: keep the connection open so that i3 is not the only client. this prevents
 154 #    the X server from exiting
 155 my @single_worker;
 156 for my $display (@displays) {
 157     my $screen;
 158     my $x = X11::XCB::Connection->new(display => $display);
 159     if ($x->has_error) {
 160         die "Could not connect to display $display\n";
 161     } else {
 162         # start a TestWorker for each display
 163         push @single_worker, worker($display, $x, $outdir, \%options);
 164     }
 165 }
 166
 167 # Read previous timing information, if available. We will be able to roughly
 168 # predict the test duration and schedule a good order for the tests.
 169 my $timingsjson = slurp('.last_run_timings.json') if -e '.last_run_timings.json';
 170 %timings = %{decode_json($timingsjson)} if length($timingsjson) > 0;
 171
 172 # Re-order the files so that those which took the longest time in the previous
 173 # run will be started at the beginning to not delay the whole run longer than
 174 # necessary.
 175 @testfiles = map  { $_->[0] }
 176              sort { $b->[1] <=> $a->[1] }
 177              map  { [$_, $timings{$_} // 999] } @testfiles;
 178
 179 # Run 000-load-deps.t first to bail out early when dependencies are missing.
 180 my $loadtest = "t/000-load-deps.t";
 181 if ((scalar grep { $_ eq $loadtest } @testfiles) > 0) {
 182     @testfiles = ($loadtest, grep { $_ ne $loadtest } @testfiles);
 183 }
 184
 185 printf("\nRough time estimate for this run: %.2f seconds\n\n", $timings{GLOBAL})
 186     if exists($timings{GLOBAL});
 187
 188 # Forget the old timings, we don’t necessarily run the same set of tests as
 189 # before. Otherwise we would end up with left-overs.
 190 %timings = (GLOBAL => time());
 191
 192 my $logfile = "$outdir/complete-run.log";
 193 open $log, '>', $logfile or die "Could not create '$logfile': $!";
 194 $log->autoflush(1);
 195 say "Writing logfile to '$logfile'...";
 196
 197 # 3: run all tests
 198 my @done;
 199 my $num = @testfiles;
 200 my $harness = TAP::Harness->new({ });
 201
 202 my $aggregator = TAP::Parser::Aggregator->new();
 203 $aggregator->start();
 204
 205 status_init(displays => \@displays, tests => $num);
 206
 207 my $single_cv = AE::cv;
 208
 209 # We start tests concurrently: For each display, one test gets started. Every
 210 # test starts another test after completing.
 211 for (@single_worker) {
 212     $single_cv->begin;
 213     take_job($_, $single_cv, \@testfiles);
 214 }
 215
 216 $single_cv->recv;
 217
 218 $aggregator->stop();
 219
 220 # print empty lines to separate failed tests from statuslines
 221 print "\n\n";
 222
 223 for (@done) {
 224     my ($test, $output) = @$_;
 225     say "no output for $test" unless $output;
 226     Log "output for $test:";
 227     Log $output;
 228     # print error messages of failed tests
 229     say for $output =~ /^not ok.+\n+((?:^#.+\n)+)/mg
 230 }
 231
 232 # 4: print summary
 233 $harness->summary($aggregator);
 234
 235 close $log;
 236
 237 # 5: Save the timings for better scheduling/prediction next run.
 238 $timings{GLOBAL} = time() - $timings{GLOBAL};
 239 open(my $fh, '>', '.last_run_timings.json');
 240 print $fh encode_json(\%timings);
 241 close($fh);
 242
 243 # 6: Print the slowest test files.
 244 my @slowest = map  { $_->[0] }
 245               sort { $b->[1] <=> $a->[1] }
 246               map  { [$_, $timings{$_}] }
 247               grep { !/^GLOBAL$/ } keys %timings;
 248 say '';
 249 say 'The slowest tests are:';
 250 printf("\t%s with %.2f seconds\n", $_, $timings{$_})
 251     for @slowest[0..($#slowest > 4 ? 4 : $#slowest)];
 252
 253 # When we are running precisely one test, print the output. Makes developing
 254 # with a single testcase easier.
 255 if ($numtests == 1) {
 256     say '';
 257     say 'Test output:';
 258     say slurp($logfile);
 259 }
 260
 261 END { cleanup() }
 262
 263 # Report logfiles that match “(Leak|Address)Sanitizer:”.
 264 my @logs_with_leaks;
 265 for my $log (<$outdir/i3-log-for-*>) {
 266     if (slurp($log) =~ /(Leak|Address)Sanitizer:/) {
 267         push @logs_with_leaks, $log;
 268     }
 269 }
 270 if (scalar @logs_with_leaks > 0) {
 271     say "\nThe following test logfiles contain AddressSanitizer or LeakSanitizer reports:";
 272     for my $log (sort @logs_with_leaks) {
 273         say "\t$log";
 274     }
 275 }
 276
 277 exit ($aggregator->failed > 0);
 278
 279 #
 280 # Takes a test from the beginning of @testfiles and runs it.
 281 #
 282 # The TAP::Parser (which reads the test output) will get called as soon as
 283 # there is some activity on the stdout file descriptor of the test process
 284 # (using an AnyEvent->io watcher).
 285 #
 286 # When a test completes and @done contains $num entries, the $cv condvar gets
 287 # triggered to finish testing.
 288 #
 289 sub take_job {
 290     my ($worker, $cv, $tests) = @_;
 291
 292     my $test = shift @$tests
 293         or return $cv->end;
 294
 295     my $display = $worker->{display};
 296
 297     Log status($display, "$test: starting");
 298     $timings{$test} = time();
 299     worker_next($worker, $test);
 300
 301     # create a TAP::Parser with an in-memory fh
 302     my $output;
 303     my $parser = TAP::Parser->new({
 304         source => do { open(my $fh, '<', \$output); $fh },
 305     });
 306
 307     my $ipc = $worker->{ipc};
 308
 309     my $w;
 310     $w = AnyEvent->io(
 311         fh => $ipc,
 312         poll => 'r',
 313         cb => sub {
 314             state $tests_completed = 0;
 315             state $partial = '';
 316
 317             sysread($ipc, my $buf, 4096) or die "sysread: $!";
 318
 319             if ($partial) {
 320                 $buf = $partial . $buf;
 321                 $partial = '';
 322             }
 323
 324             # make sure we feed TAP::Parser complete lines so it doesn't blow up
 325             if (substr($buf, -1, 1) ne "\n") {
 326                 my $nl = rindex($buf, "\n");
 327                 if ($nl == -1) {
 328                     $partial = $buf;
 329                     return;
 330                 }
 331
 332                 # strip partial from buffer
 333                 $partial = substr($buf, $nl + 1, '');
 334             }
 335
 336             # count lines before stripping eof-marker otherwise we might
 337             # end up with for (1 .. 0) { } which would effectivly skip the loop
 338             my $lines = $buf =~ tr/\n//;
 339             my $t_eof = $buf =~ s/^$TestWorker::EOF$//m;
 340
 341             $output .= $buf;
 342
 343             for (1 .. $lines) {
 344                 my $result = $parser->next;
 345                 next unless defined($result);
 346                 if ($result->is_test) {
 347                     $tests_completed++;
 348                     status($display, "$test: [$tests_completed/??] ");
 349                 } elsif ($result->is_bailout) {
 350                     Log status($display, "$test: BAILOUT");
 351                     status_completed(scalar @done);
 352                     say "";
 353                     say "test $test bailed out: " . $result->explanation;
 354                     exit 1;
 355                 }
 356             }
 357
 358             return unless $t_eof;
 359
 360             Log status($display, "$test: finished");
 361             $timings{$test} = time() - $timings{$test};
 362             status_completed(scalar @done);
 363
 364             $aggregator->add($test, $parser);
 365             push @done, [ $test, $output ];
 366
 367             undef $w;
 368             take_job($worker, $cv, $tests);
 369         }
 370     );
 371 }
 372
 373 sub cleanup {
 374     my $exitcode = $?;
 375     $_->() for our @CLEANUP;
 376     exit $exitcode;
 377 }
 378
 379 # must be in a begin block because we C<exit 0> above
 380 BEGIN {
 381     $SIG{$_} = sub {
 382         require Carp; Carp::cluck("Caught SIG$_[0]\n");
 383         cleanup();
 384     } for qw(INT TERM QUIT KILL PIPE)
 385 }
 386
 387 __END__
 388
 389 =head1 NAME
 390
 391 complete-run.pl - Run the i3 testsuite
 392
 393 =head1 SYNOPSIS
 394
 395 complete-run.pl [files...]
 396
 397 =head1 EXAMPLE
 398
 399 To run the whole testsuite on a reasonable number of Xephyr instances (your
 400 running X11 will not be touched), run:
 401   ./complete-run.pl
 402
 403 To run only a specific test (useful when developing a new feature), run:
 404   ./complete-run t/100-fullscreen.t
 405
 406 =head1 OPTIONS
 407
 408 =over 8
 409
 410 =item B<--display>
 411
 412 Specifies which X11 display should be used. Can be specified multiple times and
 413 will parallelize the tests:
 414
 415   # Run tests on the second X server
 416   ./complete-run.pl -d :1
 417
 418   # Run four tests in parallel on some Xephyr servers
 419   ./complete-run.pl -d :1,:2,:3,:4
 420
 421 Note that it is not necessary to specify this anymore. If omitted,
 422 complete-run.pl will start (num_cores * 2) Xephyr instances.
 423
 424 =item B<--valgrind>
 425
 426 Runs i3 under valgrind to find memory problems. The output will be available in
 427 C<latest/valgrind-for-$test.log>.
 428
 429 =item B<--strace>
 430
 431 Runs i3 under strace to trace system calls. The output will be available in
 432 C<latest/strace-for-$test.log>.
 433
 434 =item B<--xtrace>
 435
 436 Runs i3 under xtrace to trace X11 requests/replies. The output will be
 437 available in C<latest/xtrace-for-$test.log>.
 438
 439 =item B<--coverage-testing>
 440
 441 Generates a test coverage report at C<latest/i3-coverage>. Exits i3 cleanly
 442 during tests (instead of kill -9) to make coverage testing work properly.
 443
 444 =item B<--parallel>
 445
 446 Number of Xephyr instances to start (if you don't want to start num_cores * 2
 447 instances for some reason).
 448
 449   # Run all tests on a single Xephyr instance
 450   ./complete-run.pl -p 1
 451
 452 =back