git.sur5r.net Git - i3/i3/blob - testcases/complete-run.pl

   1 #!/usr/bin/env perl
   2 # vim:ts=4:sw=4:expandtab
   3 # © 2010-2011 Michael Stapelberg and contributors
   4 package complete_run;
   5 use strict;
   6 use warnings;
   7 use v5.10;
   8 # the following are modules which ship with Perl (>= 5.10):
   9 use Pod::Usage;
  10 use Cwd qw(abs_path);
  11 use File::Temp qw(tempfile tempdir);
  12 use Getopt::Long;
  13 use POSIX ();
  14 use TAP::Harness;
  15 use TAP::Parser;
  16 use TAP::Parser::Aggregator;
  17 use Time::HiRes qw(time);
  18 use IO::Handle;
  19 # these are shipped with the testsuite
  20 use lib qw(lib);
  21 use StartXDummy;
  22 use StatusLine;
  23 use TestWorker;
  24 # the following modules are not shipped with Perl
  25 use AnyEvent;
  26 use AnyEvent::Util;
  27 use AnyEvent::Handle;
  28 use AnyEvent::I3 qw(:all);
  29 use X11::XCB::Connection;
  30 use JSON::XS; # AnyEvent::I3 depends on it, too.
  31
  32 # Close superfluous file descriptors which were passed by running in a VIM
  33 # subshell or situations like that.
  34 AnyEvent::Util::close_all_fds_except(0, 1, 2);
  35
  36 # convinience wrapper to write to the log file
  37 my $log;
  38 sub Log { say $log "@_" }
  39
  40 my %timings;
  41 my $help = 0;
  42 # Number of tests to run in parallel. Important to know how many Xdummy
  43 # instances we need to start (unless @displays are given). Defaults to
  44 # num_cores * 2.
  45 my $parallel = undef;
  46 my @displays = ();
  47 my %options = (
  48     valgrind => 0,
  49     strace => 0,
  50     xtrace => 0,
  51     coverage => 0,
  52     restart => 0,
  53 );
  54 my $keep_xdummy_output = 0;
  55
  56 my $result = GetOptions(
  57     "coverage-testing" => \$options{coverage},
  58     "keep-xdummy-output" => \$keep_xdummy_output,
  59     "valgrind" => \$options{valgrind},
  60     "strace" => \$options{strace},
  61     "xtrace" => \$options{xtrace},
  62     "display=s" => \@displays,
  63     "parallel=i" => \$parallel,
  64     "help|?" => \$help,
  65 );
  66
  67 pod2usage(-verbose => 2, -exitcode => 0) if $help;
  68
  69 # Check for missing executables
  70 my @binaries = qw(
  71                    ../i3
  72                    ../i3bar/i3bar
  73                    ../i3-config-wizard/i3-config-wizard
  74                    ../i3-dump-log/i3-dump-log
  75                    ../i3-input/i3-input
  76                    ../i3-msg/i3-msg
  77                    ../i3-nagbar/i3-nagbar
  78                );
  79
  80 foreach my $binary (@binaries) {
  81     die "$binary executable not found" unless -e $binary;
  82     die "$binary is not an executable" unless -x $binary;
  83 }
  84
  85 @displays = split(/,/, join(',', @displays));
  86 @displays = map { s/ //g; $_ } @displays;
  87
  88 # 2: get a list of all testcases
  89 my @testfiles = @ARGV;
  90
  91 # if no files were passed on command line, run all tests from t/
  92 @testfiles = <t/*.t> if @testfiles == 0;
  93
  94 my $numtests = scalar @testfiles;
  95
  96 # No displays specified, let’s start some Xdummy instances.
  97 if (@displays == 0) {
  98     @displays = start_xdummy($parallel, $numtests, $keep_xdummy_output);
  99 }
 100
 101 # 1: create an output directory for this test-run
 102 my $outdir = "testsuite-";
 103 $outdir .= POSIX::strftime("%Y-%m-%d-%H-%M-%S-", localtime());
 104 $outdir .= `git describe --tags`;
 105 chomp($outdir);
 106 mkdir($outdir) or die "Could not create $outdir";
 107 unlink("latest") if -e "latest";
 108 symlink("$outdir", "latest") or die "Could not symlink latest to $outdir";
 109
 110
 111 # connect to all displays for two reasons:
 112 # 1: check if the display actually works
 113 # 2: keep the connection open so that i3 is not the only client. this prevents
 114 #    the X server from exiting (Xdummy will restart it, but not quick enough
 115 #    sometimes)
 116 my @single_worker;
 117 for my $display (@displays) {
 118     my $screen;
 119     my $x = X11::XCB::Connection->new(display => $display);
 120     if ($x->has_error) {
 121         die "Could not connect to display $display\n";
 122     } else {
 123         # start a TestWorker for each display
 124         push @single_worker, worker($display, $x, $outdir, \%options);
 125     }
 126 }
 127
 128 # Read previous timing information, if available. We will be able to roughly
 129 # predict the test duration and schedule a good order for the tests.
 130 my $timingsjson = StartXDummy::slurp('.last_run_timings.json');
 131 %timings = %{decode_json($timingsjson)} if length($timingsjson) > 0;
 132
 133 # Re-order the files so that those which took the longest time in the previous
 134 # run will be started at the beginning to not delay the whole run longer than
 135 # necessary.
 136 @testfiles = map  { $_->[0] }
 137              sort { $b->[1] <=> $a->[1] }
 138              map  { [$_, $timings{$_} // 999] } @testfiles;
 139
 140 printf("\nRough time estimate for this run: %.2f seconds\n\n", $timings{GLOBAL})
 141     if exists($timings{GLOBAL});
 142
 143 # Forget the old timings, we don’t necessarily run the same set of tests as
 144 # before. Otherwise we would end up with left-overs.
 145 %timings = (GLOBAL => time());
 146
 147 my $logfile = "$outdir/complete-run.log";
 148 open $log, '>', $logfile or die "Could not create '$logfile': $!";
 149 $log->autoflush(1);
 150 say "Writing logfile to '$logfile'...";
 151
 152 # 3: run all tests
 153 my @done;
 154 my $num = @testfiles;
 155 my $harness = TAP::Harness->new({ });
 156
 157 my $aggregator = TAP::Parser::Aggregator->new();
 158 $aggregator->start();
 159
 160 status_init(displays => \@displays, tests => $num);
 161
 162 my $single_cv = AE::cv;
 163
 164 # We start tests concurrently: For each display, one test gets started. Every
 165 # test starts another test after completing.
 166 for (@single_worker) {
 167     $single_cv->begin;
 168     take_job($_, $single_cv, \@testfiles);
 169 }
 170
 171 $single_cv->recv;
 172
 173 $aggregator->stop();
 174
 175 # print empty lines to seperate failed tests from statuslines
 176 print "\n\n";
 177
 178 for (@done) {
 179     my ($test, $output) = @$_;
 180     say "no output for $test" unless $output;
 181     Log "output for $test:";
 182     Log $output;
 183     # print error messages of failed tests
 184     say for $output =~ /^not ok.+\n+((?:^#.+\n)+)/mg
 185 }
 186
 187 # 4: print summary
 188 $harness->summary($aggregator);
 189
 190 close $log;
 191
 192 # 5: Save the timings for better scheduling/prediction next run.
 193 $timings{GLOBAL} = time() - $timings{GLOBAL};
 194 open(my $fh, '>', '.last_run_timings.json');
 195 print $fh encode_json(\%timings);
 196 close($fh);
 197
 198 # 6: Print the slowest test files.
 199 my @slowest = map  { $_->[0] }
 200               sort { $b->[1] <=> $a->[1] }
 201               map  { [$_, $timings{$_}] }
 202               grep { !/^GLOBAL$/ } keys %timings;
 203 say '';
 204 say 'The slowest tests are:';
 205 printf("\t%s with %.2f seconds\n", $_, $timings{$_})
 206     for @slowest[0..($#slowest > 4 ? 4 : $#slowest)];
 207
 208 # When we are running precisely one test, print the output. Makes developing
 209 # with a single testcase easier.
 210 if ($numtests == 1) {
 211     say '';
 212     say 'Test output:';
 213     say StartXDummy::slurp($logfile);
 214 }
 215
 216 END { cleanup() }
 217
 218 exit 0;
 219
 220 #
 221 # Takes a test from the beginning of @testfiles and runs it.
 222 #
 223 # The TAP::Parser (which reads the test output) will get called as soon as
 224 # there is some activity on the stdout file descriptor of the test process
 225 # (using an AnyEvent->io watcher).
 226 #
 227 # When a test completes and @done contains $num entries, the $cv condvar gets
 228 # triggered to finish testing.
 229 #
 230 sub take_job {
 231     my ($worker, $cv, $tests) = @_;
 232
 233     my $test = shift @$tests
 234         or return $cv->end;
 235
 236     my $display = $worker->{display};
 237
 238     Log status($display, "$test: starting");
 239     $timings{$test} = time();
 240     worker_next($worker, $test);
 241
 242     # create a TAP::Parser with an in-memory fh
 243     my $output;
 244     my $parser = TAP::Parser->new({
 245         source => do { open(my $fh, '<', \$output); $fh },
 246     });
 247
 248     my $ipc = $worker->{ipc};
 249
 250     my $w;
 251     $w = AnyEvent->io(
 252         fh => $ipc,
 253         poll => 'r',
 254         cb => sub {
 255             state $tests_completed = 0;
 256             state $partial = '';
 257
 258             sysread($ipc, my $buf, 4096) or die "sysread: $!";
 259
 260             if ($partial) {
 261                 $buf = $partial . $buf;
 262                 $partial = '';
 263             }
 264
 265             # make sure we feed TAP::Parser complete lines so it doesn't blow up
 266             if (substr($buf, -1, 1) ne "\n") {
 267                 my $nl = rindex($buf, "\n");
 268                 if ($nl == -1) {
 269                     $partial = $buf;
 270                     return;
 271                 }
 272
 273                 # strip partial from buffer
 274                 $partial = substr($buf, $nl + 1, '');
 275             }
 276
 277             # count lines before stripping eof-marker otherwise we might
 278             # end up with for (1 .. 0) { } which would effectivly skip the loop
 279             my $lines = $buf =~ tr/\n//;
 280             my $t_eof = $buf =~ s/^$TestWorker::EOF$//m;
 281
 282             $output .= $buf;
 283
 284             for (1 .. $lines) {
 285                 my $result = $parser->next;
 286                 next unless defined($result);
 287                 if ($result->is_test) {
 288                     $tests_completed++;
 289                     status($display, "$test: [$tests_completed/??] ");
 290                 } elsif ($result->is_bailout) {
 291                     Log status($display, "$test: BAILOUT");
 292                     status_completed(scalar @done);
 293                     say "";
 294                     say "test $test bailed out: " . $result->explanation;
 295                     exit 1;
 296                 }
 297             }
 298
 299             return unless $t_eof;
 300
 301             Log status($display, "$test: finished");
 302             $timings{$test} = time() - $timings{$test};
 303             status_completed(scalar @done);
 304
 305             $aggregator->add($test, $parser);
 306             push @done, [ $test, $output ];
 307
 308             undef $w;
 309             take_job($worker, $cv, $tests);
 310         }
 311     );
 312 }
 313
 314 sub cleanup {
 315     $_->() for our @CLEANUP;
 316     exit;
 317 }
 318
 319 # must be in a begin block because we C<exit 0> above
 320 BEGIN {
 321     $SIG{$_} = sub {
 322         require Carp; Carp::cluck("Caught SIG$_[0]\n");
 323         cleanup();
 324     } for qw(INT TERM QUIT KILL PIPE)
 325 }
 326
 327 __END__
 328
 329 =head1 NAME
 330
 331 complete-run.pl - Run the i3 testsuite
 332
 333 =head1 SYNOPSIS
 334
 335 complete-run.pl [files...]
 336
 337 =head1 EXAMPLE
 338
 339 To run the whole testsuite on a reasonable number of Xdummy instances (your
 340 running X11 will not be touched), run:
 341   ./complete-run.pl
 342
 343 To run only a specific test (useful when developing a new feature), run:
 344   ./complete-run t/100-fullscreen.t
 345
 346 =head1 OPTIONS
 347
 348 =over 8
 349
 350 =item B<--display>
 351
 352 Specifies which X11 display should be used. Can be specified multiple times and
 353 will parallelize the tests:
 354
 355   # Run tests on the second X server
 356   ./complete-run.pl -d :1
 357
 358   # Run four tests in parallel on some Xdummy servers
 359   ./complete-run.pl -d :1,:2,:3,:4
 360
 361 Note that it is not necessary to specify this anymore. If omitted,
 362 complete-run.pl will start (num_cores * 2) Xdummy instances.
 363
 364 =item B<--valgrind>
 365
 366 Runs i3 under valgrind to find memory problems. The output will be available in
 367 C<latest/valgrind-for-$test.log>.
 368
 369 =item B<--strace>
 370
 371 Runs i3 under strace to trace system calls. The output will be available in
 372 C<latest/strace-for-$test.log>.
 373
 374 =item B<--xtrace>
 375
 376 Runs i3 under xtrace to trace X11 requests/replies. The output will be
 377 available in C<latest/xtrace-for-$test.log>.
 378
 379 =item B<--coverage-testing>
 380
 381 Exits i3 cleanly (instead of kill -9) to make coverage testing work properly.
 382
 383 =item B<--parallel>
 384
 385 Number of Xdummy instances to start (if you don’t want to start num_cores * 2
 386 instances for some reason).
 387
 388   # Run all tests on a single Xdummy instance
 389   ./complete-run.pl -p 1