git.sur5r.net Git - i3/i3/blob - testcases/lib/SocketActivation.pm

   1 package SocketActivation;
   2 # vim:ts=4:sw=4:expandtab
   3
   4 use strict;
   5 use warnings;
   6 use IO::Socket::UNIX; # core
   7 use Cwd qw(abs_path); # core
   8 use POSIX qw(:fcntl_h); # core
   9 use AnyEvent::Handle; # not core
  10 use AnyEvent::Util; # not core
  11 use Exporter 'import';
  12 use v5.10;
  13
  14 our @EXPORT = qw(activate_i3);
  15
  16 #
  17 # Starts i3 using socket activation. Creates a listening socket (with bind +
  18 # listen) which is then passed to i3, who in turn calls accept and handles the
  19 # requests.
  20 #
  21 # Since the kernel buffers the connect, the parent process can connect to the
  22 # socket immediately after forking. It then sends a request and waits until it
  23 # gets an answer. Obviously, i3 has to be initialized to actually answer the
  24 # request.
  25 #
  26 # This way, we can wait *precisely* the amount of time which i3 waits to get
  27 # ready, which is a *HUGE* speed gain (and a lot more robust) in comparison to
  28 # using sleep() with a fixed amount of time.
  29 #
  30 # unix_socket_path: Location of the socket to use for the activation
  31 # display: X11 $ENV{DISPLAY}
  32 # configfile: path to the configuration file to use
  33 # logpath: path to the logfile to which i3 will append
  34 # cv: an AnyEvent->condvar which will be triggered once i3 is ready
  35 #
  36 sub activate_i3 {
  37     my %args = @_;
  38
  39     # remove the old unix socket
  40     unlink($args{unix_socket_path});
  41
  42     my $socket = IO::Socket::UNIX->new(
  43         Listen => 1,
  44         Local => $args{unix_socket_path},
  45     );
  46
  47     my $pid = fork;
  48     if (!defined($pid)) {
  49         die "could not fork()";
  50     }
  51     if ($pid == 0) {
  52         $ENV{LISTEN_PID} = $$;
  53         $ENV{LISTEN_FDS} = 1;
  54         delete $ENV{DESKTOP_STARTUP_ID};
  55         delete $ENV{I3SOCK};
  56         # $SHELL could be set to fish, which will horribly break running shell
  57         # commands via i3’s exec feature. This happened e.g. when having
  58         # “set-option -g default-shell "/usr/bin/fish"” in ~/.tmux.conf
  59         delete $ENV{SHELL};
  60         unless ($args{dont_create_temp_dir}) {
  61             $ENV{XDG_RUNTIME_DIR} = '/tmp/i3-testsuite/';
  62             mkdir $ENV{XDG_RUNTIME_DIR};
  63         }
  64         $ENV{DISPLAY} = $args{display};
  65
  66         # We are about to exec, but we did not modify $^F to include $socket
  67         # when creating the socket (because the file descriptor could have a
  68         # number != 3 which would lead to i3 leaking a file descriptor). This
  69         # caused Perl to set the FD_CLOEXEC flag, which would close $socket on
  70         # exec(), effectively *NOT* passing $socket to the new process.
  71         # Therefore, we explicitly clear FD_CLOEXEC (the only flag right now)
  72         # by setting the flags to 0.
  73         POSIX::fcntl($socket, F_SETFD, 0) or die "Could not clear fd flags: $!";
  74
  75         # If the socket does not use file descriptor 3 by chance already, we
  76         # close fd 3 and dup2() the socket to 3.
  77         if (fileno($socket) != 3) {
  78             POSIX::close(3);
  79             POSIX::dup2(fileno($socket), 3);
  80             POSIX::close(fileno($socket));
  81         }
  82
  83         # Make sure no file descriptors are open. Strangely, I got an open file
  84         # descriptor pointing to AnyEvent/Impl/EV.pm when testing.
  85         AnyEvent::Util::close_all_fds_except(0, 1, 2, 3);
  86
  87         # Construct the command to launch i3. Use maximum debug level, disable
  88         # the interactive signalhandler to make it crash immediately instead.
  89         # Also disable logging to SHM since we redirect the logs anyways.
  90         # Force Xinerama because we use Xdmx for multi-monitor tests.
  91         my $i3cmd = q|i3 --shmlog-size=0 --disable-signalhandler|;
  92         if (!defined($args{inject_randr15})) {
  93             $i3cmd .= q| --force-xinerama|;
  94         }
  95         if (!$args{validate_config}) {
  96             # We only set logging if i3 is actually started, but not if we only
  97             # validate the config file. This is to keep logging to a minimum as
  98             # such a test will likely want to inspect the log file.
  99             $i3cmd .= q| -V -d all|;
 100         }
 101
 102         # For convenience:
 103         my $outdir = $args{outdir};
 104         my $test = $args{testname};
 105
 106         if ($args{restart}) {
 107             $i3cmd .= ' -L ' . abs_path('restart-state.golden');
 108         }
 109
 110         if ($args{validate_config}) {
 111             $i3cmd .= ' -C';
 112         }
 113
 114         if ($args{valgrind}) {
 115             $i3cmd =
 116                 qq|valgrind --log-file="$outdir/valgrind-for-$test.log" | .
 117                 qq|--suppressions="./valgrind.supp" | .
 118                 qq|--leak-check=full --track-origins=yes --num-callers=20 | .
 119                 qq|--tool=memcheck -- $i3cmd|;
 120         }
 121
 122         my $logfile = "$outdir/i3-log-for-$test";
 123         # Append to $logfile instead of overwriting because i3 might be
 124         # run multiple times in one testcase.
 125         my $cmd = "exec $i3cmd -c $args{configfile} >>$logfile 2>&1";
 126
 127         if ($args{strace}) {
 128             my $out = "$outdir/strace-for-$test.log";
 129
 130             # We overwrite LISTEN_PID with the correct process ID to make
 131             # socket activation work (LISTEN_PID has to match getpid(),
 132             # otherwise the LISTEN_FDS will be treated as a left-over).
 133             $cmd = qq|strace -fF -s2048 -v -o "$out" -- | .
 134                      'sh -c "export LISTEN_PID=\$\$; ' . $cmd . '"';
 135         }
 136
 137         if ($args{xtrace}) {
 138             my $out = "$outdir/xtrace-for-$test.log";
 139
 140             # See comment in $args{strace} branch.
 141             $cmd = qq|xtrace -n -o "$out" -- | .
 142                      'sh -c "export LISTEN_PID=\$\$; ' . $cmd . '"';
 143         }
 144
 145         if ($args{inject_randr15}) {
 146             # See comment in $args{strace} branch.
 147             $cmd = 'test.inject_randr15 --getmonitors_reply="' .
 148                    $args{inject_randr15} . '" -- ' .
 149                    'sh -c "export LISTEN_PID=\$\$; ' . $cmd . '"';
 150         }
 151
 152         # We need to use the shell due to using output redirections.
 153         exec '/bin/sh', '-c', $cmd;
 154
 155         # if we are still here, i3 could not be found or exec failed. bail out.
 156         exit 1;
 157     }
 158
 159     # close the socket, the child process should be the only one which keeps a file
 160     # descriptor on the listening socket.
 161     $socket->close;
 162
 163     if ($args{validate_config}) {
 164         $args{cv}->send(1);
 165         return $pid;
 166     }
 167
 168     # We now connect (will succeed immediately) and send a request afterwards.
 169     # As soon as the reply is there, i3 is considered ready.
 170     my $cl = IO::Socket::UNIX->new(Peer => $args{unix_socket_path});
 171     my $hdl;
 172     $hdl = AnyEvent::Handle->new(
 173         fh => $cl,
 174         on_error => sub {
 175             $hdl->destroy;
 176             $args{cv}->send(0);
 177         });
 178
 179     # send a get_tree message without payload
 180     $hdl->push_write('i3-ipc' . pack("LL", 0, 4));
 181
 182     # wait for the reply
 183     $hdl->push_read(chunk => 1, => sub {
 184         my ($h, $line) = @_;
 185         $args{cv}->send(1);
 186         undef $hdl;
 187     });
 188
 189     return $pid;
 190 }
 191
 192 1