git.sur5r.net Git - i3/i3/blob - testcases/lib/SocketActivation.pm

   1 package SocketActivation;
   2 # vim:ts=4:sw=4:expandtab
   3
   4 use strict;
   5 use warnings;
   6 use IO::Socket::UNIX; # core
   7 use Cwd qw(abs_path); # core
   8 use POSIX qw(:fcntl_h); # core
   9 use AnyEvent::Handle; # not core
  10 use AnyEvent::Util; # not core
  11 use Exporter 'import';
  12 use v5.10;
  13
  14 our @EXPORT = qw(activate_i3);
  15
  16 #
  17 # Starts i3 using socket activation. Creates a listening socket (with bind +
  18 # listen) which is then passed to i3, who in turn calls accept and handles the
  19 # requests.
  20 #
  21 # Since the kernel buffers the connect, the parent process can connect to the
  22 # socket immediately after forking. It then sends a request and waits until it
  23 # gets an answer. Obviously, i3 has to be initialized to actually answer the
  24 # request.
  25 #
  26 # This way, we can wait *precisely* the amount of time which i3 waits to get
  27 # ready, which is a *HUGE* speed gain (and a lot more robust) in comparison to
  28 # using sleep() with a fixed amount of time.
  29 #
  30 # unix_socket_path: Location of the socket to use for the activation
  31 # display: X11 $ENV{DISPLAY}
  32 # configfile: path to the configuration file to use
  33 # logpath: path to the logfile to which i3 will append
  34 # cv: an AnyEvent->condvar which will be triggered once i3 is ready
  35 #
  36 sub activate_i3 {
  37     my %args = @_;
  38
  39     # remove the old unix socket
  40     unlink($args{unix_socket_path});
  41
  42     my $socket = IO::Socket::UNIX->new(
  43         Listen => 1,
  44         Local => $args{unix_socket_path},
  45     );
  46
  47     my $pid = fork;
  48     if (!defined($pid)) {
  49         die "could not fork()";
  50     }
  51     if ($pid == 0) {
  52         $ENV{LISTEN_PID} = $$;
  53         $ENV{LISTEN_FDS} = 1;
  54         delete $ENV{DESKTOP_STARTUP_ID};
  55         $ENV{DISPLAY} = $args{display};
  56         $ENV{PATH} = join(':',
  57             '../i3-nagbar',
  58             '../i3-msg',
  59             '../i3-config-wizard',
  60             '../i3bar',
  61             '..',
  62             $ENV{PATH}
  63         );
  64
  65         # We are about to exec, but we did not modify $^F to include $socket
  66         # when creating the socket (because the file descriptor could have a
  67         # number != 3 which would lead to i3 leaking a file descriptor). This
  68         # caused Perl to set the FD_CLOEXEC flag, which would close $socket on
  69         # exec(), effectively *NOT* passing $socket to the new process.
  70         # Therefore, we explicitly clear FD_CLOEXEC (the only flag right now)
  71         # by setting the flags to 0.
  72         POSIX::fcntl($socket, F_SETFD, 0) or die "Could not clear fd flags: $!";
  73
  74         # If the socket does not use file descriptor 3 by chance already, we
  75         # close fd 3 and dup2() the socket to 3.
  76         if (fileno($socket) != 3) {
  77             POSIX::close(3);
  78             POSIX::dup2(fileno($socket), 3);
  79             POSIX::close(fileno($socket));
  80         }
  81
  82         # Make sure no file descriptors are open. Strangely, I got an open file
  83         # descriptor pointing to AnyEvent/Impl/EV.pm when testing.
  84         AnyEvent::Util::close_all_fds_except(0, 1, 2, 3);
  85
  86         # Construct the command to launch i3. Use maximum debug level, disable
  87         # the interactive signalhandler to make it crash immediately instead.
  88         # Also disable logging to SHM since we want to redirect the logs anyways.
  89         my $i3cmd = abs_path("../i3") . " -V -d all --disable-signalhandler --shmlog-size=0";
  90
  91         # For convenience:
  92         my $outdir = $args{outdir};
  93         my $test = $args{testname};
  94
  95         if ($args{valgrind}) {
  96             $i3cmd =
  97                 qq|valgrind -v --log-file="$outdir/valgrind-for-$test.log" | .
  98                 qq|--leak-check=full --track-origins=yes --num-callers=20 | .
  99                 qq|--tool=memcheck -- $i3cmd|;
 100         }
 101
 102         my $logfile = "$outdir/i3-log-for-$test";
 103         # Append to $logfile instead of overwriting because i3 might be
 104         # run multiple times in one testcase.
 105         my $cmd = "exec $i3cmd -c $args{configfile} >>$logfile 2>&1";
 106
 107         if ($args{strace}) {
 108             my $out = "$outdir/strace-for-$test.log";
 109
 110             # We overwrite LISTEN_PID with the correct process ID to make
 111             # socket activation work (LISTEN_PID has to match getpid(),
 112             # otherwise the LISTEN_FDS will be treated as a left-over).
 113             $cmd = qq|strace -fF -s2048 -v -o "$out" -- | .
 114                      'sh -c "export LISTEN_PID=\$\$; ' . $cmd . '"';
 115         }
 116
 117         # We need to use the shell due to using output redirections.
 118         exec '/bin/sh', '-c', $cmd;
 119
 120         # if we are still here, i3 could not be found or exec failed. bail out.
 121         exit 1;
 122     }
 123
 124     # close the socket, the child process should be the only one which keeps a file
 125     # descriptor on the listening socket.
 126     $socket->close;
 127
 128     # We now connect (will succeed immediately) and send a request afterwards.
 129     # As soon as the reply is there, i3 is considered ready.
 130     my $cl = IO::Socket::UNIX->new(Peer => $args{unix_socket_path});
 131     my $hdl;
 132     $hdl = AnyEvent::Handle->new(
 133         fh => $cl,
 134         on_error => sub {
 135             $hdl->destroy;
 136             $args{cv}->send(0);
 137         });
 138
 139     # send a get_tree message without payload
 140     $hdl->push_write('i3-ipc' . pack("LL", 0, 4));
 141
 142     # wait for the reply
 143     $hdl->push_read(chunk => 1, => sub {
 144         my ($h, $line) = @_;
 145         $args{cv}->send(1);
 146         undef $hdl;
 147     });
 148
 149     return $pid;
 150 }
 151
 152 1