git.sur5r.net Git - i3/i3/blob - testcases/lib/i3test.pm

   1 package i3test;
   2 # vim:ts=4:sw=4:expandtab
   3 use strict; use warnings;
   4
   5 use File::Temp qw(tmpnam tempfile tempdir);
   6 use Test::Builder;
   7 use X11::XCB::Rect;
   8 use X11::XCB::Window;
   9 use X11::XCB qw(:all);
  10 use AnyEvent::I3;
  11 use EV;
  12 use List::Util qw(first);
  13 use Time::HiRes qw(sleep);
  14 use Cwd qw(abs_path);
  15 use SocketActivation;
  16
  17 use v5.10;
  18
  19 use Exporter ();
  20 our @EXPORT = qw(
  21     get_workspace_names
  22     get_unused_workspace
  23     fresh_workspace
  24     get_ws_content
  25     get_ws
  26     get_focused
  27     open_empty_con
  28     open_window
  29     open_floating_window
  30     get_dock_clients
  31     cmd
  32     sync_with_i3
  33     does_i3_live
  34     exit_gracefully
  35     workspace_exists
  36     focused_ws
  37     get_socket_path
  38     launch_with_config
  39     wait_for_event
  40     wait_for_map
  41     wait_for_unmap
  42 );
  43
  44 my $tester = Test::Builder->new();
  45 my $_cached_socket_path = undef;
  46 my $_sync_window = undef;
  47 my $tmp_socket_path = undef;
  48
  49 BEGIN {
  50     my $window_count = 0;
  51     sub counter_window {
  52         return $window_count++;
  53     }
  54 }
  55
  56 sub import {
  57     my $class = shift;
  58     my $pkg = caller;
  59     eval "package $pkg;
  60 use Test::Most" . (@_ > 0 ? " qw(@_)" : "") . ";
  61 use Data::Dumper;
  62 use AnyEvent::I3;
  63 use Time::HiRes qw(sleep);
  64 use Test::Deep qw(eq_deeply cmp_deeply cmp_set cmp_bag cmp_methods useclass noclass set bag subbagof superbagof subsetof supersetof superhashof subhashof bool str arraylength Isa ignore methods regexprefonly regexpmatches num regexponly scalref reftype hashkeysonly blessed array re hash regexpref hash_each shallow array_each code arrayelementsonly arraylengthonly scalarrefonly listmethods any hashkeys isa);
  65 use v5.10;
  66 use strict;
  67 use warnings;
  68 ";
  69     @_ = ($class);
  70     goto \&Exporter::import;
  71 }
  72
  73 #
  74 # Waits for the next event and calls the given callback for every event to
  75 # determine if this is the event we are waiting for.
  76 #
  77 # Can be used to wait until a window is mapped, until a ClientMessage is
  78 # received, etc.
  79 #
  80 # wait_for_event $x, 0.25, sub { $_[0]->{response_type} == MAP_NOTIFY };
  81 #
  82 sub wait_for_event {
  83     my ($x, $timeout, $cb) = @_;
  84
  85     my $cv = AE::cv;
  86
  87     my $prep = EV::prepare sub {
  88         $x->flush;
  89     };
  90
  91     my $check = EV::check sub {
  92         while (defined(my $event = $x->poll_for_event)) {
  93             if ($cb->($event)) {
  94                 $cv->send(1);
  95                 last;
  96             }
  97         }
  98     };
  99
 100     my $watcher = EV::io $x->get_file_descriptor, EV::READ, sub {
 101         # do nothing, we only need this watcher so that EV picks up the events
 102     };
 103
 104     # Trigger timeout after $timeout seconds (can be fractional)
 105     my $t = AE::timer $timeout, 0, sub { warn "timeout ($timeout secs)"; $cv->send(0) };
 106
 107     my $result = $cv->recv;
 108     undef $t;
 109     return $result;
 110 }
 111
 112 # thin wrapper around wait_for_event which waits for MAP_NOTIFY
 113 # make sure to include 'structure_notify' in the window’s event_mask attribute
 114 sub wait_for_map {
 115     my ($x) = @_;
 116     wait_for_event $x, 2, sub { $_[0]->{response_type} == MAP_NOTIFY };
 117 }
 118
 119 # Wrapper around wait_for_event which waits for UNMAP_NOTIFY. Also calls
 120 # sync_with_i3 to make sure i3 also picked up and processed the UnmapNotify
 121 # event.
 122 sub wait_for_unmap {
 123     my ($x) = @_;
 124     wait_for_event $x, 2, sub { $_[0]->{response_type} == UNMAP_NOTIFY };
 125     sync_with_i3($x);
 126 }
 127
 128 #
 129 # Opens a new window (see X11::XCB::Window), maps it, waits until it got mapped
 130 # and synchronizes with i3.
 131 #
 132 # set dont_map to a true value to avoid mapping
 133 #
 134 # default values:
 135 #     class => WINDOW_CLASS_INPUT_OUTPUT
 136 #     rect => [ 0, 0, 30, 30 ]
 137 #     background_color => '#c0c0c0'
 138 #     event_mask => [ 'structure_notify' ]
 139 #     name => 'Window <n>'
 140 #
 141 sub open_window {
 142     my ($x, $args) = @_;
 143     my %args = ($args ? %$args : ());
 144
 145     my $dont_map = delete $args{dont_map};
 146
 147     $args{class} //= WINDOW_CLASS_INPUT_OUTPUT;
 148     $args{rect} //= [ 0, 0, 30, 30 ];
 149     $args{background_color} //= '#c0c0c0';
 150     $args{event_mask} //= [ 'structure_notify' ];
 151     $args{name} //= 'Window ' . counter_window();
 152
 153     my $window = $x->root->create_child(%args);
 154
 155     return $window if $dont_map;
 156
 157     $window->map;
 158     wait_for_map($x);
 159     # We sync with i3 here to make sure $x->input_focus is updated.
 160     sync_with_i3($x);
 161     return $window;
 162 }
 163
 164 # Thin wrapper around open_window which sets window_type to
 165 # _NET_WM_WINDOW_TYPE_UTILITY to make the window floating.
 166 sub open_floating_window {
 167     my ($x, $args) = @_;
 168     my %args = ($args ? %$args : ());
 169
 170     $args{window_type} = $x->atom(name => '_NET_WM_WINDOW_TYPE_UTILITY');
 171
 172     return open_window($x, \%args);
 173 }
 174
 175 sub open_empty_con {
 176     my ($i3) = @_;
 177
 178     my $reply = $i3->command('open')->recv;
 179     return $reply->{id};
 180 }
 181
 182 sub get_workspace_names {
 183     my $i3 = i3(get_socket_path());
 184     my $tree = $i3->get_tree->recv;
 185     my @outputs = @{$tree->{nodes}};
 186     my @cons;
 187     for my $output (@outputs) {
 188         # get the first CT_CON of each output
 189         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 190         @cons = (@cons, @{$content->{nodes}});
 191     }
 192     [ map { $_->{name} } @cons ]
 193 }
 194
 195 sub get_unused_workspace {
 196     my @names = get_workspace_names();
 197     my $tmp;
 198     do { $tmp = tmpnam() } while ($tmp ~~ @names);
 199     $tmp
 200 }
 201
 202 sub fresh_workspace {
 203     my $unused = get_unused_workspace;
 204     cmd("workspace $unused");
 205     $unused
 206 }
 207
 208 sub get_ws {
 209     my ($name) = @_;
 210     my $i3 = i3(get_socket_path());
 211     my $tree = $i3->get_tree->recv;
 212
 213     my @outputs = @{$tree->{nodes}};
 214     my @workspaces;
 215     for my $output (@outputs) {
 216         # get the first CT_CON of each output
 217         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 218         @workspaces = (@workspaces, @{$content->{nodes}});
 219     }
 220
 221     # as there can only be one workspace with this name, we can safely
 222     # return the first entry
 223     return first { $_->{name} eq $name } @workspaces;
 224 }
 225
 226 #
 227 # returns the content (== tree, starting from the node of a workspace)
 228 # of a workspace. If called in array context, also includes the focus
 229 # stack of the workspace
 230 #
 231 sub get_ws_content {
 232     my ($name) = @_;
 233     my $con = get_ws($name);
 234     return wantarray ? ($con->{nodes}, $con->{focus}) : $con->{nodes};
 235 }
 236
 237 sub get_focused {
 238     my ($ws) = @_;
 239     my $con = get_ws($ws);
 240
 241     my @focused = @{$con->{focus}};
 242     my $lf;
 243     while (@focused > 0) {
 244         $lf = $focused[0];
 245         last unless defined($con->{focus});
 246         @focused = @{$con->{focus}};
 247         my @cons = grep { $_->{id} == $lf } (@{$con->{nodes}}, @{$con->{'floating_nodes'}});
 248         $con = $cons[0];
 249     }
 250
 251     return $lf;
 252 }
 253
 254 sub get_dock_clients {
 255     my $which = shift;
 256
 257     my $tree = i3(get_socket_path())->get_tree->recv;
 258     my @outputs = @{$tree->{nodes}};
 259     # Children of all dockareas
 260     my @docked;
 261     for my $output (@outputs) {
 262         if (!defined($which)) {
 263             @docked = (@docked, map { @{$_->{nodes}} }
 264                                 grep { $_->{type} == 5 }
 265                                 @{$output->{nodes}});
 266         } elsif ($which eq 'top') {
 267             my $first = first { $_->{type} == 5 } @{$output->{nodes}};
 268             @docked = (@docked, @{$first->{nodes}});
 269         } elsif ($which eq 'bottom') {
 270             my @matching = grep { $_->{type} == 5 } @{$output->{nodes}};
 271             my $last = $matching[-1];
 272             @docked = (@docked, @{$last->{nodes}});
 273         }
 274     }
 275     return @docked;
 276 }
 277
 278 sub cmd {
 279     i3(get_socket_path())->command(@_)->recv
 280 }
 281
 282 sub workspace_exists {
 283     my ($name) = @_;
 284     ($name ~~ @{get_workspace_names()})
 285 }
 286
 287 sub focused_ws {
 288     my $i3 = i3(get_socket_path());
 289     my $tree = $i3->get_tree->recv;
 290     my @outputs = @{$tree->{nodes}};
 291     my @cons;
 292     for my $output (@outputs) {
 293         # get the first CT_CON of each output
 294         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 295         my $first = first { $_->{fullscreen_mode} == 1 } @{$content->{nodes}};
 296         return $first->{name}
 297     }
 298 }
 299
 300 #
 301 # Sends an I3_SYNC ClientMessage with a random value to the root window.
 302 # i3 will reply with the same value, but, due to the order of events it
 303 # processes, only after all other events are done.
 304 #
 305 # This can be used to ensure the results of a cmd 'focus left' are pushed to
 306 # X11 and that $x->input_focus returns the correct value afterwards.
 307 #
 308 # See also docs/testsuite for a long explanation
 309 #
 310 sub sync_with_i3 {
 311     my ($x) = @_;
 312
 313     # Since we need a (mapped) window for receiving a ClientMessage, we create
 314     # one on the first call of sync_with_i3. It will be re-used in all
 315     # subsequent calls.
 316     if (!defined($_sync_window)) {
 317         $_sync_window = $x->root->create_child(
 318             class => WINDOW_CLASS_INPUT_OUTPUT,
 319             rect => X11::XCB::Rect->new(x => -15, y => -15, width => 10, height => 10 ),
 320             override_redirect => 1,
 321             background_color => '#ff0000',
 322             event_mask => [ 'structure_notify' ],
 323         );
 324
 325         $_sync_window->map;
 326
 327         wait_for_event $x, 2, sub { $_[0]->{response_type} == MAP_NOTIFY };
 328     }
 329
 330     my $root = $x->get_root_window();
 331     # Generate a random number to identify this particular ClientMessage.
 332     my $myrnd = int(rand(255)) + 1;
 333
 334     # Generate a ClientMessage, see xcb_client_message_t
 335     my $msg = pack "CCSLLLLLLL",
 336          CLIENT_MESSAGE, # response_type
 337          32,     # format
 338          0,      # sequence
 339          $root,  # destination window
 340          $x->atom(name => 'I3_SYNC')->id,
 341
 342          $_sync_window->id,    # data[0]: our own window id
 343          $myrnd, # data[1]: a random value to identify the request
 344          0,
 345          0,
 346          0;
 347
 348     # Send it to the root window -- since i3 uses the SubstructureRedirect
 349     # event mask, it will get the ClientMessage.
 350     $x->send_event(0, $root, EVENT_MASK_SUBSTRUCTURE_REDIRECT, $msg);
 351
 352     # now wait until the reply is here
 353     return wait_for_event $x, 2, sub {
 354         my ($event) = @_;
 355         # TODO: const
 356         return 0 unless $event->{response_type} == 161;
 357
 358         my ($win, $rnd) = unpack "LL", $event->{data};
 359         return ($rnd == $myrnd);
 360     };
 361 }
 362
 363 sub does_i3_live {
 364     my $tree = i3(get_socket_path())->get_tree->recv;
 365     my @nodes = @{$tree->{nodes}};
 366     my $ok = (@nodes > 0);
 367     $tester->ok($ok, 'i3 still lives');
 368     return $ok;
 369 }
 370
 371 # Tries to exit i3 gracefully (with the 'exit' cmd) or kills the PID if that fails
 372 sub exit_gracefully {
 373     my ($pid, $socketpath) = @_;
 374     $socketpath ||= get_socket_path();
 375
 376     my $exited = 0;
 377     eval {
 378         say "Exiting i3 cleanly...";
 379         i3($socketpath)->command('exit')->recv;
 380         $exited = 1;
 381     };
 382
 383     if (!$exited) {
 384         kill(9, $pid) or die "could not kill i3";
 385     }
 386
 387     if ($socketpath =~ m,^/tmp/i3-test-socket-,) {
 388         unlink($socketpath);
 389     }
 390 }
 391
 392 # Gets the socket path from the I3_SOCKET_PATH atom stored on the X11 root window
 393 sub get_socket_path {
 394     my ($cache) = @_;
 395     $cache ||= 1;
 396
 397     if ($cache && defined($_cached_socket_path)) {
 398         return $_cached_socket_path;
 399     }
 400
 401     my $x = X11::XCB::Connection->new;
 402     my $atom = $x->atom(name => 'I3_SOCKET_PATH');
 403     my $cookie = $x->get_property(0, $x->get_root_window(), $atom->id, GET_PROPERTY_TYPE_ANY, 0, 256);
 404     my $reply = $x->get_property_reply($cookie->{sequence});
 405     my $socketpath = $reply->{value};
 406     $_cached_socket_path = $socketpath;
 407     return $socketpath;
 408 }
 409
 410 #
 411 # launches a new i3 process with the given string as configuration file.
 412 # useful for tests which test specific config file directives.
 413 #
 414 # be sure to use !NO_I3_INSTANCE! somewhere in the file to signal
 415 # complete-run.pl that it should not create an instance of i3
 416 #
 417 sub launch_with_config {
 418     my ($config, $dont_add_socket_path) = @_;
 419
 420     $dont_add_socket_path //= 0;
 421
 422     if (!defined($tmp_socket_path)) {
 423         $tmp_socket_path = File::Temp::tempnam('/tmp', 'i3-test-socket-');
 424     }
 425
 426     my ($fh, $tmpfile) = tempfile('i3-test-config-XXXXX', UNLINK => 1);
 427     say $fh $config;
 428     say $fh "ipc-socket $tmp_socket_path" unless $dont_add_socket_path;
 429     close($fh);
 430
 431     my $cv = AnyEvent->condvar;
 432     my $pid = activate_i3(
 433         unix_socket_path => "$tmp_socket_path-activation",
 434         display => $ENV{DISPLAY},
 435         configfile => $tmpfile,
 436         outdir => $ENV{OUTDIR},
 437         logpath => $ENV{LOGPATH},
 438         valgrind => $ENV{VALGRIND},
 439         cv => $cv,
 440     );
 441
 442     # blockingly wait until i3 is ready
 443     $cv->recv;
 444
 445     # force update of the cached socket path in lib/i3test
 446     get_socket_path(0);
 447
 448     return $pid;
 449 }
 450
 451 1