git.sur5r.net Git - i3/i3/blob - testcases/lib/i3test.pm

   1 package i3test;
   2 # vim:ts=4:sw=4:expandtab
   3 use strict; use warnings;
   4
   5 use File::Temp qw(tmpnam tempfile tempdir);
   6 use Test::Builder;
   7 use X11::XCB::Rect;
   8 use X11::XCB::Window;
   9 use X11::XCB qw(:all);
  10 use AnyEvent::I3;
  11 use List::Util qw(first);
  12 use Time::HiRes qw(sleep);
  13 use Cwd qw(abs_path);
  14 use Scalar::Util qw(blessed);
  15 use SocketActivation;
  16
  17 use v5.10;
  18
  19 # preload
  20 use Test::More ();
  21 use Data::Dumper ();
  22
  23 use Exporter ();
  24 our @EXPORT = qw(
  25     get_workspace_names
  26     get_unused_workspace
  27     fresh_workspace
  28     get_ws_content
  29     get_ws
  30     get_focused
  31     open_empty_con
  32     open_window
  33     open_floating_window
  34     get_dock_clients
  35     cmd
  36     sync_with_i3
  37     does_i3_live
  38     exit_gracefully
  39     workspace_exists
  40     focused_ws
  41     get_socket_path
  42     launch_with_config
  43     wait_for_event
  44     wait_for_map
  45     wait_for_unmap
  46     $x
  47 );
  48
  49 my $tester = Test::Builder->new();
  50 my $_cached_socket_path = undef;
  51 my $_sync_window = undef;
  52 my $tmp_socket_path = undef;
  53
  54 our $x;
  55
  56 BEGIN {
  57     my $window_count = 0;
  58     sub counter_window {
  59         return $window_count++;
  60     }
  61 }
  62
  63 my $i3_pid;
  64 my $i3_autostart;
  65
  66 END {
  67
  68     # testcases which start i3 manually should always call exit_gracefully
  69     # on their own. Let’s see, whether they really did.
  70     if (! $i3_autostart) {
  71         return unless $i3_pid;
  72
  73         $tester->ok(undef, 'testcase called exit_gracefully()');
  74     }
  75
  76     # don't trigger SIGCHLD handler
  77     local $SIG{CHLD};
  78
  79     # From perldoc -v '$?':
  80     # Inside an "END" subroutine $? contains the value
  81     # that is going to be given to "exit()".
  82     #
  83     # Since waitpid sets $?, we need to localize it,
  84     # otherwise TAP would be misinterpreted our return status
  85     local $?;
  86
  87     # When measuring code coverage, try to exit i3 cleanly (otherwise, .gcda
  88     # files are not written)
  89     if ($ENV{COVERAGE} || $ENV{VALGRIND}) {
  90         exit_gracefully($i3_pid, "/tmp/nested-$ENV{DISPLAY}");
  91
  92     } else {
  93         kill(9, $i3_pid)
  94             or $tester->BAIL_OUT("could not kill i3");
  95
  96         waitpid $i3_pid, 0;
  97     }
  98 }
  99
 100 sub import {
 101     my ($class, %args) = @_;
 102     my $pkg = caller;
 103
 104     $i3_autostart = delete($args{i3_autostart}) // 1;
 105
 106     my $cv = launch_with_config('-default', dont_block => 1)
 107         if $i3_autostart;
 108
 109     my $test_more_args = '';
 110     $test_more_args = join(' ', 'qw(', %args, ')') if keys %args;
 111     local $@;
 112     eval << "__";
 113 package $pkg;
 114 use Test::More $test_more_args;
 115 use Data::Dumper;
 116 use AnyEvent::I3;
 117 use Time::HiRes qw(sleep);
 118 __
 119     $tester->BAIL_OUT("$@") if $@;
 120     feature->import(":5.10");
 121     strict->import;
 122     warnings->import;
 123
 124     $x ||= i3test::X11->new;
 125     $cv->recv if $i3_autostart;
 126
 127     @_ = ($class);
 128     goto \&Exporter::import;
 129 }
 130
 131 #
 132 # Waits for the next event and calls the given callback for every event to
 133 # determine if this is the event we are waiting for.
 134 #
 135 # Can be used to wait until a window is mapped, until a ClientMessage is
 136 # received, etc.
 137 #
 138 # wait_for_event $x, 0.25, sub { $_[0]->{response_type} == MAP_NOTIFY };
 139 #
 140 sub wait_for_event {
 141     my ($timeout, $cb) = @_;
 142
 143     my $cv = AE::cv;
 144
 145     $x->flush;
 146
 147     # unfortunately, there is no constant for this
 148     my $ae_read = 0;
 149
 150     my $guard = AE::io $x->get_file_descriptor, $ae_read, sub {
 151         while (defined(my $event = $x->poll_for_event)) {
 152             if ($cb->($event)) {
 153                 $cv->send(1);
 154                 last;
 155             }
 156         }
 157     };
 158
 159     # Trigger timeout after $timeout seconds (can be fractional)
 160     my $t = AE::timer $timeout, 0, sub { warn "timeout ($timeout secs)"; $cv->send(0) };
 161
 162     my $result = $cv->recv;
 163     undef $t;
 164     undef $guard;
 165     return $result;
 166 }
 167
 168 # thin wrapper around wait_for_event which waits for MAP_NOTIFY
 169 # make sure to include 'structure_notify' in the window’s event_mask attribute
 170 sub wait_for_map {
 171     my ($win) = @_;
 172     my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 173     wait_for_event 2, sub {
 174         $_[0]->{response_type} == MAP_NOTIFY and $_[0]->{window} == $id
 175     };
 176 }
 177
 178 # Wrapper around wait_for_event which waits for UNMAP_NOTIFY. Also calls
 179 # sync_with_i3 to make sure i3 also picked up and processed the UnmapNotify
 180 # event.
 181 sub wait_for_unmap {
 182     my ($win) = @_;
 183     # my $id = (blessed($win) && $win->isa('X11::XCB::Window')) ? $win->id : $win;
 184     wait_for_event 2, sub {
 185         $_[0]->{response_type} == UNMAP_NOTIFY # and $_[0]->{window} == $id
 186     };
 187     sync_with_i3();
 188 }
 189
 190 #
 191 # Opens a new window (see X11::XCB::Window), maps it, waits until it got mapped
 192 # and synchronizes with i3.
 193 #
 194 # set dont_map to a true value to avoid mapping
 195 #
 196 # if you want to change aspects of your window before it would be mapped,
 197 # set before_map to a coderef. $window gets passed as $_ and as first argument.
 198 #
 199 # if you set both dont_map and before_map, the coderef will be called nevertheless
 200 #
 201 #
 202 # default values:
 203 #     class => WINDOW_CLASS_INPUT_OUTPUT
 204 #     rect => [ 0, 0, 30, 30 ]
 205 #     background_color => '#c0c0c0'
 206 #     event_mask => [ 'structure_notify' ]
 207 #     name => 'Window <n>'
 208 #
 209 sub open_window {
 210     my %args = @_ == 1 ? %{$_[0]} : @_;
 211
 212     my $dont_map = delete $args{dont_map};
 213     my $before_map = delete $args{before_map};
 214
 215     $args{class} //= WINDOW_CLASS_INPUT_OUTPUT;
 216     $args{rect} //= [ 0, 0, 30, 30 ];
 217     $args{background_color} //= '#c0c0c0';
 218     $args{event_mask} //= [ 'structure_notify' ];
 219     $args{name} //= 'Window ' . counter_window();
 220
 221     my $window = $x->root->create_child(%args);
 222
 223     if ($before_map) {
 224         # TODO: investigate why _create is not needed
 225         $window->_create;
 226         $before_map->($window) for $window;
 227     }
 228
 229     return $window if $dont_map;
 230
 231     $window->map;
 232     wait_for_map($window);
 233     return $window;
 234 }
 235
 236 # Thin wrapper around open_window which sets window_type to
 237 # _NET_WM_WINDOW_TYPE_UTILITY to make the window floating.
 238 sub open_floating_window {
 239     my %args = @_ == 1 ? %{$_[0]} : @_;
 240
 241     $args{window_type} = $x->atom(name => '_NET_WM_WINDOW_TYPE_UTILITY');
 242
 243     return open_window(\%args);
 244 }
 245
 246 sub open_empty_con {
 247     my ($i3) = @_;
 248
 249     my $reply = $i3->command('open')->recv;
 250     return $reply->{id};
 251 }
 252
 253 sub get_workspace_names {
 254     my $i3 = i3(get_socket_path());
 255     my $tree = $i3->get_tree->recv;
 256     my @outputs = @{$tree->{nodes}};
 257     my @cons;
 258     for my $output (@outputs) {
 259         # get the first CT_CON of each output
 260         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 261         @cons = (@cons, @{$content->{nodes}});
 262     }
 263     [ map { $_->{name} } @cons ]
 264 }
 265
 266 sub get_unused_workspace {
 267     my @names = get_workspace_names();
 268     my $tmp;
 269     do { $tmp = tmpnam() } while ($tmp ~~ @names);
 270     $tmp
 271 }
 272
 273 sub fresh_workspace {
 274     my $unused = get_unused_workspace;
 275     cmd("workspace $unused");
 276     $unused
 277 }
 278
 279 sub get_ws {
 280     my ($name) = @_;
 281     my $i3 = i3(get_socket_path());
 282     my $tree = $i3->get_tree->recv;
 283
 284     my @outputs = @{$tree->{nodes}};
 285     my @workspaces;
 286     for my $output (@outputs) {
 287         # get the first CT_CON of each output
 288         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 289         @workspaces = (@workspaces, @{$content->{nodes}});
 290     }
 291
 292     # as there can only be one workspace with this name, we can safely
 293     # return the first entry
 294     return first { $_->{name} eq $name } @workspaces;
 295 }
 296
 297 #
 298 # returns the content (== tree, starting from the node of a workspace)
 299 # of a workspace. If called in array context, also includes the focus
 300 # stack of the workspace
 301 #
 302 sub get_ws_content {
 303     my ($name) = @_;
 304     my $con = get_ws($name);
 305     return wantarray ? ($con->{nodes}, $con->{focus}) : $con->{nodes};
 306 }
 307
 308 sub get_focused {
 309     my ($ws) = @_;
 310     my $con = get_ws($ws);
 311
 312     my @focused = @{$con->{focus}};
 313     my $lf;
 314     while (@focused > 0) {
 315         $lf = $focused[0];
 316         last unless defined($con->{focus});
 317         @focused = @{$con->{focus}};
 318         my @cons = grep { $_->{id} == $lf } (@{$con->{nodes}}, @{$con->{'floating_nodes'}});
 319         $con = $cons[0];
 320     }
 321
 322     return $lf;
 323 }
 324
 325 sub get_dock_clients {
 326     my $which = shift;
 327
 328     my $tree = i3(get_socket_path())->get_tree->recv;
 329     my @outputs = @{$tree->{nodes}};
 330     # Children of all dockareas
 331     my @docked;
 332     for my $output (@outputs) {
 333         if (!defined($which)) {
 334             @docked = (@docked, map { @{$_->{nodes}} }
 335                                 grep { $_->{type} == 5 }
 336                                 @{$output->{nodes}});
 337         } elsif ($which eq 'top') {
 338             my $first = first { $_->{type} == 5 } @{$output->{nodes}};
 339             @docked = (@docked, @{$first->{nodes}});
 340         } elsif ($which eq 'bottom') {
 341             my @matching = grep { $_->{type} == 5 } @{$output->{nodes}};
 342             my $last = $matching[-1];
 343             @docked = (@docked, @{$last->{nodes}});
 344         }
 345     }
 346     return @docked;
 347 }
 348
 349 sub cmd {
 350     i3(get_socket_path())->command(@_)->recv
 351 }
 352
 353 sub workspace_exists {
 354     my ($name) = @_;
 355     ($name ~~ @{get_workspace_names()})
 356 }
 357
 358 sub focused_ws {
 359     my $i3 = i3(get_socket_path());
 360     my $tree = $i3->get_tree->recv;
 361     my @outputs = @{$tree->{nodes}};
 362     my @cons;
 363     for my $output (@outputs) {
 364         # get the first CT_CON of each output
 365         my $content = first { $_->{type} == 2 } @{$output->{nodes}};
 366         my $first = first { $_->{fullscreen_mode} == 1 } @{$content->{nodes}};
 367         return $first->{name}
 368     }
 369 }
 370
 371 #
 372 # Sends an I3_SYNC ClientMessage with a random value to the root window.
 373 # i3 will reply with the same value, but, due to the order of events it
 374 # processes, only after all other events are done.
 375 #
 376 # This can be used to ensure the results of a cmd 'focus left' are pushed to
 377 # X11 and that $x->input_focus returns the correct value afterwards.
 378 #
 379 # See also docs/testsuite for a long explanation
 380 #
 381 sub sync_with_i3 {
 382     # Since we need a (mapped) window for receiving a ClientMessage, we create
 383     # one on the first call of sync_with_i3. It will be re-used in all
 384     # subsequent calls.
 385     if (!defined($_sync_window)) {
 386         $_sync_window = open_window(
 387             rect => [ -15, -15, 10, 10 ],
 388             override_redirect => 1,
 389         );
 390     }
 391
 392     my $root = $x->get_root_window();
 393     # Generate a random number to identify this particular ClientMessage.
 394     my $myrnd = int(rand(255)) + 1;
 395
 396     # Generate a ClientMessage, see xcb_client_message_t
 397     my $msg = pack "CCSLLLLLLL",
 398          CLIENT_MESSAGE, # response_type
 399          32,     # format
 400          0,      # sequence
 401          $root,  # destination window
 402          $x->atom(name => 'I3_SYNC')->id,
 403
 404          $_sync_window->id,    # data[0]: our own window id
 405          $myrnd, # data[1]: a random value to identify the request
 406          0,
 407          0,
 408          0;
 409
 410     # Send it to the root window -- since i3 uses the SubstructureRedirect
 411     # event mask, it will get the ClientMessage.
 412     $x->send_event(0, $root, EVENT_MASK_SUBSTRUCTURE_REDIRECT, $msg);
 413
 414     # now wait until the reply is here
 415     return wait_for_event 2, sub {
 416         my ($event) = @_;
 417         # TODO: const
 418         return 0 unless $event->{response_type} == 161;
 419
 420         my ($win, $rnd) = unpack "LL", $event->{data};
 421         return ($rnd == $myrnd);
 422     };
 423 }
 424
 425 sub does_i3_live {
 426     my $tree = i3(get_socket_path())->get_tree->recv;
 427     my @nodes = @{$tree->{nodes}};
 428     my $ok = (@nodes > 0);
 429     $tester->ok($ok, 'i3 still lives');
 430     return $ok;
 431 }
 432
 433 # Tries to exit i3 gracefully (with the 'exit' cmd) or kills the PID if that fails
 434 sub exit_gracefully {
 435     my ($pid, $socketpath) = @_;
 436     $socketpath ||= get_socket_path();
 437
 438     my $exited = 0;
 439     eval {
 440         say "Exiting i3 cleanly...";
 441         i3($socketpath)->command('exit')->recv;
 442         $exited = 1;
 443     };
 444
 445     if (!$exited) {
 446         kill(9, $pid)
 447             or $tester->BAIL_OUT("could not kill i3");
 448     }
 449
 450     if ($socketpath =~ m,^/tmp/i3-test-socket-,) {
 451         unlink($socketpath);
 452     }
 453
 454     waitpid $pid, 0;
 455     undef $i3_pid;
 456 }
 457
 458 # Gets the socket path from the I3_SOCKET_PATH atom stored on the X11 root window
 459 sub get_socket_path {
 460     my ($cache) = @_;
 461     $cache ||= 1;
 462
 463     if ($cache && defined($_cached_socket_path)) {
 464         return $_cached_socket_path;
 465     }
 466
 467     my $atom = $x->atom(name => 'I3_SOCKET_PATH');
 468     my $cookie = $x->get_property(0, $x->get_root_window(), $atom->id, GET_PROPERTY_TYPE_ANY, 0, 256);
 469     my $reply = $x->get_property_reply($cookie->{sequence});
 470     my $socketpath = $reply->{value};
 471     $_cached_socket_path = $socketpath;
 472     return $socketpath;
 473 }
 474
 475 #
 476 # launches a new i3 process with the given string as configuration file.
 477 # useful for tests which test specific config file directives.
 478 sub launch_with_config {
 479     my ($config, %args) = @_;
 480
 481     $tmp_socket_path = "/tmp/nested-$ENV{DISPLAY}";
 482
 483     my ($fh, $tmpfile) = tempfile("i3-cfg-for-$ENV{TESTNAME}-XXXXX", UNLINK => 1);
 484
 485     if ($config ne '-default') {
 486         say $fh $config;
 487     } else {
 488         open(my $conf_fh, '<', './i3-test.config')
 489             or $tester->BAIL_OUT("could not open default config: $!");
 490         local $/;
 491         say $fh scalar <$conf_fh>;
 492     }
 493
 494     say $fh "ipc-socket $tmp_socket_path"
 495         unless $args{dont_add_socket_path};
 496
 497     close($fh);
 498
 499     my $cv = AnyEvent->condvar;
 500     $i3_pid = activate_i3(
 501         unix_socket_path => "$tmp_socket_path-activation",
 502         display => $ENV{DISPLAY},
 503         configfile => $tmpfile,
 504         outdir => $ENV{OUTDIR},
 505         testname => $ENV{TESTNAME},
 506         valgrind => $ENV{VALGRIND},
 507         strace => $ENV{STRACE},
 508         cv => $cv,
 509     );
 510
 511     # force update of the cached socket path in lib/i3test
 512     # as soon as i3 has started
 513     $cv->cb(sub { get_socket_path(0) });
 514
 515     return $cv if $args{dont_block};
 516
 517     # blockingly wait until i3 is ready
 518     $cv->recv;
 519
 520     return $i3_pid;
 521 }
 522
 523 package i3test::X11;
 524 use parent 'X11::XCB::Connection';
 525
 526 sub input_focus {
 527     my $self = shift;
 528     i3test::sync_with_i3();
 529
 530     return $self->SUPER::input_focus(@_);
 531 }
 532
 533 1