git.sur5r.net Git - i3/i3/blob - testcases/t/158-wm_take_focus.t

   1 #!perl
   2 # vim:ts=4:sw=4:expandtab
   3 #
   4 # Please read the following documents before working on tests:
   5 # • https://build.i3wm.org/docs/testsuite.html
   6 #   (or docs/testsuite)
   7 #
   8 # • https://build.i3wm.org/docs/lib-i3test.html
   9 #   (alternatively: perldoc ./testcases/lib/i3test.pm)
  10 #
  11 # • https://build.i3wm.org/docs/ipc.html
  12 #   (or docs/ipc)
  13 #
  14 # • http://onyxneon.com/books/modern_perl/modern_perl_a4.pdf
  15 #   (unless you are already familiar with Perl)
  16 #
  17 # Tests if the WM_TAKE_FOCUS protocol is correctly handled by i3
  18 #
  19 # For more information on the protocol and input handling, see:
  20 # https://tronche.com/gui/x/icccm/sec-4.html#s-4.1.7
  21 #
  22 use i3test;
  23
  24 sub recv_take_focus {
  25     my ($window) = @_;
  26
  27     # sync_with_i3 will send a ClientMessage to i3 and i3 will send the same
  28     # payload back to $window->id.
  29     my $myrnd = sync_with_i3(
  30         window_id => $window->id,
  31         dont_wait_for_event => 1,
  32     );
  33
  34     # We check whether the first received message has the correct payload — if
  35     # not, the received message was a WM_TAKE_FOCUS message.
  36     my $first_event_is_clientmessage;
  37     wait_for_event 2, sub {
  38         my ($event) = @_;
  39         # TODO: const
  40         return 0 unless $event->{response_type} == 161;
  41
  42         my ($win, $rnd) = unpack "LL", $event->{data};
  43         if (!defined($first_event_is_clientmessage)) {
  44             $first_event_is_clientmessage = ($rnd == $myrnd);
  45         }
  46         return ($rnd == $myrnd);
  47     };
  48
  49     return !$first_event_is_clientmessage;
  50 }
  51
  52 subtest 'Window without WM_TAKE_FOCUS', sub {
  53     my $ws = fresh_workspace;
  54
  55     my $window = open_window;
  56
  57     ok(!recv_take_focus($window), 'did not receive ClientMessage');
  58
  59     my ($nodes) = get_ws_content($ws);
  60     my $con = shift @$nodes;
  61     ok($con->{focused}, 'con is focused');
  62
  63     done_testing;
  64 };
  65
  66 # https://tronche.com/gui/x/icccm/sec-4.html#s-4.1.7
  67 # > Clients using the Globally Active model can only use a SetInputFocus request
  68 # > to acquire the input focus when they do not already have it on receipt of one
  69 # > of the following events:
  70 # > * ButtonPress
  71 # > * ButtonRelease
  72 # > * Passive-grabbed KeyPress
  73 # > * Passive-grabbed KeyRelease
  74 #
  75 # Since managing a window happens on a MapNotify (which is absent from this
  76 # list), the window cannot accept input focus, so we should not try to focus
  77 # the window at all.
  78 subtest 'Window with WM_TAKE_FOCUS and without InputHint', sub {
  79     my $ws = fresh_workspace;
  80
  81     my $take_focus = $x->atom(name => 'WM_TAKE_FOCUS');
  82
  83     my $window = open_window({
  84         dont_map => 1,
  85         protocols => [ $take_focus ],
  86     });
  87
  88     # add an (empty) WM_HINTS property without the InputHint
  89     $window->delete_hint('input');
  90
  91     $window->map;
  92
  93     ok(!recv_take_focus($window), 'did not receive ClientMessage');
  94
  95     my ($nodes) = get_ws_content($ws);
  96     my $con = shift @$nodes;
  97     ok($con->{focused}, 'con is focused');
  98
  99     done_testing;
 100 };
 101
 102 # If the InputHint is unspecified, i3 should use the simpler method of focusing
 103 # the window directly rather than using the WM_TAKE_FOCUS protocol.
 104 # XXX: The code paths for an unspecified and set InputHint are
 105 # nearly identical presently, so this is currently used also as a proxy test
 106 # for the latter case.
 107 subtest 'Window with WM_TAKE_FOCUS and unspecified InputHint', sub {
 108     my $ws = fresh_workspace;
 109
 110     my $take_focus = $x->atom(name => 'WM_TAKE_FOCUS');
 111
 112     my $window = open_window({ protocols => [ $take_focus ] });
 113
 114     ok(!recv_take_focus($window), 'did not receive ClientMessage');
 115
 116     my ($nodes) = get_ws_content($ws);
 117     my $con = shift @$nodes;
 118     ok($con->{focused}, 'con is focused');
 119
 120     done_testing;
 121 };
 122
 123 done_testing;