git.sur5r.net Git - i3/i3/blob - testcases/t/517-regress-move-direction-ipc.t

   1 #!perl
   2 # vim:ts=4:sw=4:expandtab
   3 #
   4 # Please read the following documents before working on tests:
   5 # • http://build.i3wm.org/docs/testsuite.html
   6 #   (or docs/testsuite)
   7 #
   8 # • http://build.i3wm.org/docs/lib-i3test.html
   9 #   (alternatively: perldoc ./testcases/lib/i3test.pm)
  10 #
  11 # • http://build.i3wm.org/docs/ipc.html
  12 #   (or docs/ipc)
  13 #
  14 # • http://onyxneon.com/books/modern_perl/modern_perl_a4.pdf
  15 #   (unless you are already familiar with Perl)
  16 #
  17 # Make sure the command `move <direction>` properly sends the workspace focus
  18 # ipc event required for i3bar to be properly updated and redrawn.
  19 #
  20 # Bug still in: 4.6-195-g34232b8
  21 use i3test i3_autostart => 0;
  22
  23 my $config = <<EOT;
  24 # i3 config file (v4)
  25 font -misc-fixed-medium-r-normal--13-120-75-75-C-70-iso10646-1
  26
  27 fake-outputs 1024x768+0+0,1024x768+1024+0
  28 workspace ws-left output fake-0
  29 workspace ws-right output fake-1
  30 EOT
  31
  32 my $pid = launch_with_config($config);
  33
  34 my $i3 = i3(get_socket_path());
  35 $i3->connect()->recv;
  36
  37 # subscribe to the 'focus' ipc event
  38 my $focus = AnyEvent->condvar;
  39 $i3->subscribe({
  40     workspace => sub {
  41         my ($event) = @_;
  42         if ($event->{change} eq 'focus') {
  43             $focus->send($event);
  44         }
  45     }
  46 })->recv;
  47
  48 # give up after 0.5 seconds
  49 my $timer = AnyEvent->timer(
  50     after => 0.5,
  51     cb => sub {
  52         $focus->send(0);
  53     }
  54 );
  55
  56 # open two windows on the left output
  57 cmd 'workspace ws-left';
  58 open_window;
  59 open_window;
  60
  61 # move a window over to the right output
  62 cmd 'move right';
  63 my $event = $focus->recv;
  64
  65 ok($event, 'moving from workspace with two windows triggered focus ipc event');
  66 is($event->{current}->{name}, 'ws-right', 'focus event gave the right workspace');
  67 is(@{$event->{current}->{nodes}}, 1, 'focus event gave the right number of windows on the workspace');
  68
  69 # reset and try again
  70 $focus = AnyEvent->condvar;
  71 cmd 'workspace ws-left; move right';
  72 $event = $focus->recv;
  73 ok($event, 'moving from workspace with one window triggered focus ipc event');
  74 is($event->{current}->{name}, 'ws-right', 'focus event gave the right workspace');
  75 is(@{$event->{current}->{nodes}}, 2, 'focus event gave the right number of windows on the workspace');
  76
  77 exit_gracefully($pid);
  78
  79 done_testing;