git.sur5r.net Git - minitube/blob - minitube.pro

   1 INCLUDEPATH += /usr/include/phonon
   2 CONFIG += release
   3 TEMPLATE = app
   4
   5 # TODO Saner string behaviour
   6 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   7 TARGET = minitube
   8 mac {
   9     TARGET = Minitube
  10     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.4
  11 }
  12 QT += network \
  13     xml \
  14     phonon
  15 include(src/qtsingleapplication/qtsingleapplication.pri)
  16 include(src/thlibrary/thlibrary.pri)
  17 HEADERS += src/MainWindow.h \
  18     src/SearchView.h \
  19     src/MediaView.h \
  20     src/AboutView.h \
  21     src/youtubesearch.h \
  22     src/video.h \
  23     src/youtubestreamreader.h \
  24     src/View.h \
  25     src/searchlineedit.h \
  26     src/urllineedit.h \
  27     src/spacer.h \
  28     src/Constants.h \
  29     src/iconloader/qticonloader.h \
  30     src/faderwidget/FaderWidget.h \
  31     src/ListModel.h \
  32     src/playlist/PrettyItemDelegate.h \
  33     src/networkaccess.h \
  34     src/videomimedata.h \
  35     src/global.h \
  36     src/updatechecker.h \
  37     src/playlistwidget.h \
  38     src/searchparams.h \
  39     src/minisplitter.h \
  40     src/loadingwidget.h \
  41     src/videoareawidget.h \
  42     src/googlesuggest.h \
  43     src/videowidget.h \
  44     src/flickcharm.h \
  45     src/videodefinition.h
  46 SOURCES += src/main.cpp \
  47     src/MainWindow.cpp \
  48     src/SearchView.cpp \
  49     src/MediaView.cpp \
  50     src/AboutView.cpp \
  51     src/youtubesearch.cpp \
  52     src/youtubestreamreader.cpp \
  53     src/searchlineedit.cpp \
  54     src/urllineedit.cpp \
  55     src/spacer.cpp \
  56     src/video.cpp \
  57     src/iconloader/qticonloader.cpp \
  58     src/faderwidget/FaderWidget.cpp \
  59     src/ListModel.cpp \
  60     src/playlist/PrettyItemDelegate.cpp \
  61     src/videomimedata.cpp \
  62     src/updatechecker.cpp \
  63     src/networkaccess.cpp \
  64     src/playlistwidget.cpp \
  65     src/searchparams.cpp \
  66     src/minisplitter.cpp \
  67     src/loadingwidget.cpp \
  68     src/videoareawidget.cpp \
  69     src/googlesuggest.cpp \
  70     src/videowidget.cpp \
  71     src/flickcharm.cpp \
  72     src/videodefinition.cpp
  73 RESOURCES += resources.qrc
  74 DESTDIR = build/target/
  75 OBJECTS_DIR = build/obj/
  76 MOC_DIR = build/moc/
  77 RCC_DIR = build/rcc/
  78
  79 # Tell Qt Linguist that we use UTF-8 strings in our sources
  80 CODECFORTR = UTF-8
  81 CODECFORSRC = UTF-8
  82 include(locale/locale.pri)
  83
  84 # deploy
  85 DISTFILES += CHANGES \
  86     COPYING
  87 mac {
  88     CONFIG += x86 \
  89         ppc
  90     QMAKE_INFO_PLIST = Info.plist
  91     ICON = minitube.icns
  92 }
  93 unix {
  94     isEmpty(PREFIX):PREFIX = /usr
  95     BINDIR = $$PREFIX/bin
  96     INSTALLS += target
  97     target.path = $$BINDIR
  98     DATADIR = $$PREFIX/share
  99     PKGDATADIR = $$DATADIR/minitube
 100     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 101         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 102     INSTALLS += translations \
 103         desktop \
 104         iconsvg \
 105         icon16 \
 106         icon32 \
 107         icon48 \
 108         icon64 \
 109         icon128 \
 110         icon256
 111     translations.path = $$PKGDATADIR
 112     translations.files += $$DESTDIR/locale
 113     desktop.path = $$DATADIR/applications
 114     desktop.files += minitube.desktop
 115     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 116     iconsvg.files += data/minitube.svg
 117     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 118     icon16.files += data/16x16/minitube.png
 119     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 120     icon32.files += data/32x32/minitube.png
 121     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 122     icon48.files += data/48x48/minitube.png
 123     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 124     icon64.files += data/64x64/minitube.png
 125     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 126     icon128.files += data/128x128/minitube.png
 127     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 128     icon256.files += data/256x256/minitube.png
 129 }
 130 win32:RC_FILE = minitube.rc