git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 2.1.3
   4 DEFINES += APP_VERSION="$$VERSION"
   5
   6 APP_NAME = Minitube
   7 DEFINES += APP_NAME="$$APP_NAME"
   8
   9 APP_UNIX_NAME = minitube
  10 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  11
  12 DEFINES *= QT_NO_DEBUG_OUTPUT
  13 DEFINES *= QT_USE_QSTRINGBUILDER
  14 DEFINES += QT_STRICT_ITERATORS
  15
  16 TARGET = minitube
  17 QT += network xml phonon sql script
  18 include(src/qtsingleapplication/qtsingleapplication.pri)
  19 HEADERS += \
  20     src/video.h \
  21     src/searchlineedit.h \
  22     src/urllineedit.h \
  23     src/spacer.h \
  24     src/constants.h \
  25     src/playlistitemdelegate.h \
  26     src/networkaccess.h \
  27     src/videomimedata.h \
  28     src/global.h \
  29     src/updatechecker.h \
  30     src/searchparams.h \
  31     src/minisplitter.h \
  32     src/loadingwidget.h \
  33     src/videoareawidget.h \
  34     src/autocomplete.h \
  35     src/videodefinition.h \
  36     src/fontutils.h \
  37     src/globalshortcuts.h \
  38     src/globalshortcutbackend.h \
  39     src/downloadmanager.h \
  40     src/downloaditem.h \
  41     src/downloadview.h \
  42     src/downloadmodel.h \
  43     src/downloadlistview.h \
  44     src/downloadsettings.h \
  45     src/suggester.h \
  46     src/channelsuggest.h \
  47     src/temporary.h \
  48     src/segmentedcontrol.h \
  49     src/playlistview.h \
  50     src/refinesearchwidget.h \
  51     src/refinesearchbutton.h \
  52     src/sidebarwidget.h \
  53     src/homeview.h \
  54     src/aboutview.h \
  55     src/mainwindow.h \
  56     src/mediaview.h \
  57     src/searchview.h \
  58     src/view.h \
  59     src/playlistmodel.h \
  60     src/videosource.h \
  61     src/ytsearch.h \
  62     src/ytstandardfeed.h \
  63     src/standardfeedsview.h \
  64     src/ytregions.h \
  65     src/ytcategories.h \
  66     src/ytfeedreader.h \
  67     src/ytsuggester.h \
  68     src/videosourcewidget.h \
  69     src/regionsview.h \
  70     src/ytsinglevideosource.h \
  71     src/sidebarheader.h \
  72     src/utils.h \
  73     src/diskcache.h \
  74     src/gridwidget.h \
  75     src/painterutils.h \
  76     src/database.h \
  77     src/ytuser.h \
  78     src/channelaggregator.h \
  79     src/channelmodel.h \
  80     src/aggregatevideosource.h \
  81     src/channelview.h \
  82     src/channelitemdelegate.h \
  83     src/jsfunctions.h \
  84     src/seekslider.h
  85 SOURCES += src/main.cpp \
  86     src/searchlineedit.cpp \
  87     src/urllineedit.cpp \
  88     src/spacer.cpp \
  89     src/video.cpp \
  90     src/videomimedata.cpp \
  91     src/updatechecker.cpp \
  92     src/networkaccess.cpp \
  93     src/searchparams.cpp \
  94     src/minisplitter.cpp \
  95     src/loadingwidget.cpp \
  96     src/videoareawidget.cpp \
  97     src/autocomplete.cpp \
  98     src/videodefinition.cpp \
  99     src/constants.cpp \
 100     src/fontutils.cpp \
 101     src/globalshortcuts.cpp \
 102     src/globalshortcutbackend.cpp \
 103     src/downloadmanager.cpp \
 104     src/downloaditem.cpp \
 105     src/downloadview.cpp \
 106     src/downloadmodel.cpp \
 107     src/downloadlistview.cpp \
 108     src/downloadsettings.cpp \
 109     src/channelsuggest.cpp \
 110     src/temporary.cpp \
 111     src/segmentedcontrol.cpp \
 112     src/playlistview.cpp \
 113     src/refinesearchwidget.cpp \
 114     src/refinesearchbutton.cpp \
 115     src/sidebarwidget.cpp \
 116     src/homeview.cpp \
 117     src/mainwindow.cpp \
 118     src/mediaview.cpp \
 119     src/aboutview.cpp \
 120     src/searchview.cpp \
 121     src/playlistitemdelegate.cpp \
 122     src/playlistmodel.cpp \
 123     src/videosource.cpp \
 124     src/ytsearch.cpp \
 125     src/ytstandardfeed.cpp \
 126     src/standardfeedsview.cpp \
 127     src/ytregions.cpp \
 128     src/ytcategories.cpp \
 129     src/ytfeedreader.cpp \
 130     src/ytsuggester.cpp \
 131     src/videosourcewidget.cpp \
 132     src/regionsview.cpp \
 133     src/ytsinglevideosource.cpp \
 134     src/sidebarheader.cpp \
 135     src/utils.cpp \
 136     src/diskcache.cpp \
 137     src/gridwidget.cpp \
 138     src/painterutils.cpp \
 139     src/database.cpp \
 140     src/ytuser.cpp \
 141     src/channelaggregator.cpp \
 142     src/channelmodel.cpp \
 143     src/aggregatevideosource.cpp \
 144     src/channelview.cpp \
 145     src/channelitemdelegate.cpp \
 146     src/jsfunctions.cpp \
 147     src/seekslider.cpp
 148 RESOURCES += resources.qrc
 149 DESTDIR = build/target/
 150 OBJECTS_DIR = build/obj/
 151 MOC_DIR = build/moc/
 152 RCC_DIR = build/rcc/
 153
 154 # Tell Qt Linguist that we use UTF-8 strings in our sources
 155 CODECFORTR = UTF-8
 156 CODECFORSRC = UTF-8
 157 include(locale/locale.pri)
 158
 159 # deploy
 160 DISTFILES += CHANGES COPYING
 161 unix:!mac {
 162     INCLUDEPATH += /usr/include/phonon
 163     QT += dbus
 164     HEADERS += src/gnomeglobalshortcutbackend.h
 165     SOURCES += src/gnomeglobalshortcutbackend.cpp
 166     isEmpty(PREFIX):PREFIX = /usr
 167     BINDIR = $$PREFIX/bin
 168     INSTALLS += target
 169     target.path = $$BINDIR
 170     DATADIR = $$PREFIX/share
 171     PKGDATADIR = $$DATADIR/minitube
 172     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 173         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 174     INSTALLS += translations \
 175         desktop \
 176         iconsvg \
 177         icon16 \
 178         icon22 \
 179         icon32 \
 180         icon48 \
 181         icon64 \
 182         icon128 \
 183         icon256 \
 184         icon512
 185     translations.path = $$PKGDATADIR
 186     translations.files += $$DESTDIR/locale
 187     desktop.path = $$DATADIR/applications
 188     desktop.files += minitube.desktop
 189     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 190     iconsvg.files += data/minitube.svg
 191     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 192     icon16.files += data/16x16/minitube.png
 193     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 194     icon22.files += data/22x22/minitube.png
 195     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 196     icon32.files += data/32x32/minitube.png
 197     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 198     icon48.files += data/48x48/minitube.png
 199     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 200     icon64.files += data/64x64/minitube.png
 201     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 202     icon128.files += data/128x128/minitube.png
 203     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 204     icon256.files += data/256x256/minitube.png
 205     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 206     icon512.files += data/512x512/minitube.png
 207 }
 208 mac|win32|contains(DEFINES, APP_UBUNTU):include(local/local.pri)