git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  98 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  99 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
 100 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 101 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 102 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 103         no, [yes no])dnl
 104
 105 dnl ----------------------------------------------------------------
 106 dnl General "with" options
 107 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 108
 109 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 110         auto, [auto yes no] )
 111 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 112         auto, [auto yes no] )
 113 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 114         auto, [auto k5 k5only k425 kth k4 afs yes no])
 115 OL_ARG_WITH(readline,[  --with-readline with readline support],
 116         auto, [auto yes no] )
 117 OL_ARG_WITH(threads,[  --with-threads   use threads],
 118         auto, [auto nt posix mach pth lwp yes no manual] )
 119 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 120         auto, [auto ssleay openssl yes no] )
 121 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 122         auto, [auto yes no manual] )
 123
 124 dnl ----------------------------------------------------------------
 125 dnl Server options
 126 dnl ----------------------------------------------------------------
 127 dnl LDAPD OPTIONS
 128 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 129 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 130
 131 dnl ----------------------------------------------------------------
 132 dnl SLAPD OPTIONS
 133 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 134 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 135 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 136 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 137 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 138 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 139 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 140 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 141 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 142 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 143 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 144 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 145 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 146 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 147
 148 dnl SLAPD Backend options
 149 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 150 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 151         [static dynamic])
 152 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 153 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 154         [static dynamic])
 155 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 156 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 157         [auto db2 db mdbm gdbm ndbm manual])
 158 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 159         [static dynamic])
 160 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 161         [auto btree hash])
 162
 163 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 164 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 165         [static dynamic])
 166 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 167 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 168         [static dynamic])
 169 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 170 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 171         [static dynamic])
 172 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 173 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 174         [static dynamic])
 175
 176 dnl ----------------------------------------------------------------
 177 dnl SLURPD OPTIONS
 178 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 179 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 180
 181 dnl ----------------------------------------------------------------
 182 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 183 AC_ENABLE_STATIC
 184 dnl AC_DISABLE_SHARED
 185 AC_ENABLE_SHARED
 186
 187 dnl ----------------------------------------------------------------
 188
 189 dnl General "enable" options
 190 # validate options
 191 if test $ol_enable_dns = yes ; then
 192         if test $ol_enable_referrals = no ; then
 193                 AC_MSG_ERROR([DNS requires --enable-referrals])
 194         fi
 195         if test $ol_enable_referrals = auto ; then
 196                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 197                 ol_enable_referrals=yes
 198         fi
 199 fi
 200
 201 if test $ol_enable_slapd = no ; then
 202         dnl SLAPD was specificallly disabled
 203         if test $ol_enable_bdb2 = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 205         fi
 206         if test $ol_enable_ldap = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 208         fi
 209         if test $ol_enable_ldbm = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 211         fi
 212         if test $ol_enable_passwd = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 214         fi
 215         if test $ol_enable_perl = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 217         fi
 218         if test $ol_enable_shell = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 220         fi
 221         if test $ol_enable_tcl = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 223         fi
 224         if test $ol_enable_modules = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 226         fi
 227         if test $ol_enable_multimaster = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 229         fi
 230         if test $ol_enable_wrappers = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 232         fi
 233         if test $ol_enable_phonetic = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 235         fi
 236         if test $ol_enable_quipu = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 238         fi
 239         if test $ol_enable_rlookups = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 241         fi
 242         if test $ol_enable_aci = yes ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 244         fi
 245         if test $ol_enable_discreteaci = yes ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 247         fi
 248         if test $ol_with_ldbm_api != auto ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 250         fi
 251         if test $ol_with_ldbm_type != auto ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 253         fi
 254         if test $ol_with_bdb2_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 256         fi
 257         if test $ol_with_ldap_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 259         fi
 260         if test $ol_with_ldbm_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 262         fi
 263         if test $ol_with_passwd_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 265         fi
 266         if test $ol_with_perl_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 268         fi
 269         if test $ol_with_shell_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 271         fi
 272         if test $ol_with_tcl_module != static ; then
 273                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 274         fi
 275         if test $ol_enable_slurpd = yes ; then
 276                 AC_MSG_ERROR([slurpd requires slapd])
 277         fi
 278
 279         # force settings to no
 280         ol_enable_bdb2=no
 281         ol_enable_ldap=no
 282         ol_enable_ldbm=no
 283         ol_enable_passwd=no
 284         ol_enable_perl=no
 285         ol_enable_shell=no
 286         ol_enable_tcl=no
 287
 288         ol_enable_modules=no
 289         ol_enable_multimaster=no
 290         ol_enable_phonetic=no
 291         ol_enable_quipu=no
 292         ol_enable_rlookups=no
 293         ol_enable_aci=no
 294         ol_enable_discreteaci=no
 295         ol_enable_wrappers=no
 296         ol_enable_dynamic=no
 297
 298         ol_with_ldbm_api=no
 299         ol_with_ldbm_type=no
 300
 301         ol_with_bdb2_module=static
 302         ol_with_ldap_module=static
 303         ol_with_ldbm_module=static
 304         ol_with_passwd_module=static
 305         ol_with_perl_module=static
 306         ol_with_shell_module=static
 307         ol_with_tcl_module=static
 308
 309         ol_enable_slurpd=no
 310
 311 elif test $ol_enable_ldbm = no ; then
 312         dnl SLAPD without LDBM
 313
 314         if test $ol_with_ldbm_api != auto ; then
 315                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 316         fi
 317
 318         if test $ol_with_ldbm_type != auto ; then
 319                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 320         fi
 321
 322         if test $ol_with_ldbm_module != static ; then
 323                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 324         fi
 325
 326         if test $ol_enable_bdb2 = yes ; then
 327                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 328         fi
 329
 330         if test $ol_enable_modules != yes -a \
 331                 $ol_enable_ldap = no -a \
 332                 $ol_enable_passwd = no -a \
 333                 $ol_enable_perl = no -a \
 334                 $ol_enable_shell = no -a \
 335                 $ol_enable_tcl = no ; then
 336                 AC_MSG_ERROR([slapd requires a backend])
 337         fi
 338
 339         ol_with_ldbm_api=no
 340         ol_with_ldbm_type=no
 341         ol_with_ldbm_module=static
 342
 343 elif test $ol_enable_bdb2 = yes ; then
 344         dnl SLAPD with BDB2
 345
 346         if test $ol_with_ldbm_api != auto -a \
 347                 $ol_with_ldbm_api != db2 ; then
 348                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 349         fi
 350
 351         ol_with_ldbm_api=db2
 352
 353 else
 354         dnl SLAPD with LDBM
 355
 356         if test $ol_enable_bdb2 != no ; then
 357                 if test $ol_with_ldbm_api != auto -a \
 358                         $ol_with_ldbm_api != db2 ; then
 359                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 360                         ol_enable_bdb2=no
 361                 fi
 362         fi
 363
 364         if test $ol_with_ldbm_api = gdbm -a \
 365                 $ol_with_ldbm_type = btree ; then
 366                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 367         fi
 368         if test $ol_with_ldbm_api = mdbm -a \
 369                 $ol_with_ldbm_type = btree ; then
 370                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 371         fi
 372         if test $ol_with_ldbm_api = ndbm -a \
 373                 $ol_with_ldbm_type = btree ; then
 374                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 375         fi
 376 fi
 377
 378 if test $ol_enable_slurpd = yes ; then
 379         dnl SLURPD was specifically enabled
 380         if test $ol_with_threads = no ; then
 381                 AC_MSG_ERROR([slurpd requires threads])
 382         fi
 383 fi
 384
 385 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 386         if test $ol_with_kerberos = no ; then
 387                 AC_MSG_ERROR([options require --with-kerberos])
 388         fi
 389 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 390         if test $ol_with_kerberos != auto ; then
 391                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 392         else
 393                 ol_with_kerberos=no
 394         fi
 395 fi
 396
 397 AC_MSG_RESULT(done)
 398
 399 dnl ----------------------------------------------------------------
 400 dnl Initialize vars
 401 LDAP_LIBS=
 402 LDIF_LIBS=
 403 LDBM_LIBS=
 404 LTHREAD_LIBS=
 405 LUTIL_LIBS=
 406
 407 LDAPD_LIBS=
 408 SLAPD_LIBS=
 409 SLURPD_LIBS=
 410
 411 BUILD_LDAPD=no
 412 BUILD_SLAPD=no
 413 BUILD_SLURPD=no
 414
 415 BUILD_BDB2=no
 416 BUILD_LDAP=no
 417 BUILD_LDBM=no
 418 BUILD_PASSWD=no
 419 BUILD_PERL=no
 420 BUILD_QUIPU=no
 421 BUILD_SHELL=no
 422 BUILD_TCL=no
 423 BUILD_THREAD=no
 424
 425 BUILD_BDB2_DYNAMIC=static
 426 BUILD_LDAP_DYNAMIC=static
 427 BUILD_LDBM_DYNAMIC=static
 428 BUILD_PASSWD_DYNAMIC=static
 429 BUILD_PERL_DYNAMIC=static
 430 BUILD_SHELL_DYNAMIC=static
 431 BUILD_TCL_DYNAMIC=static
 432
 433 SLAPD_MODULES_LDFLAGS=
 434 SLAPD_MODULES_CPPFLAGS=
 435 SLAPD_MODULES_LIST=
 436
 437 SLAPD_PERL_LDFLAGS=
 438 MOD_PERL_LDFLAGS=
 439 PERL_CPPFLAGS=
 440
 441 MOD_TCL_LIB=
 442 KRB4_LIBS=
 443 KRB5_LIBS=
 444 READLINE_LIBS=
 445 SASL_LIBS=
 446 TERMCAP_LIBS=
 447 TLS_LIBS=
 448 MODULES_LIBS=
 449
 450 dnl ================================================================
 451 dnl Checks for programs
 452
 453 dnl AC_PROG_INSTALL
 454
 455 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 456
 457 dnl ----------------------------------------------------------------
 458 dnl
 459 dnl Determine which C translator to use
 460 dnl
 461
 462 dnl AIX Thread requires we use cc_r or xlc_r.
 463 dnl But only do this IF AIX and CC is not set
 464 dnl and threads are auto|yes|posix.
 465 dnl
 466 dnl If we find cc_r|xlc_r, force pthreads and assume
 467 dnl             pthread_create is in $LIBS (ie: don't bring in
 468 dnl             any additional thread libraries)
 469 dnl If we do not find cc_r|xlc_r, disable threads
 470
 471 ol_aix_threads=no
 472 case "$target" in
 473 *-*-aix*) dnl all AIX is not a good idea.
 474         if test -z "$CC" ; then
 475                 case "$ol_with_threads" in
 476                 auto | yes |  posix) ol_aix_threads=yes ;;
 477                 esac
 478         fi
 479 ;;
 480 esac
 481
 482 if test $ol_aix_threads = yes ; then
 483         if test -z "${CC}" ; then
 484                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 485
 486                 if test "$CC" = cc ; then
 487                         dnl no CC! don't allow --with-threads
 488                         if test $ol_with_threads != auto ; then
 489                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 490                         else
 491                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 492                         fi
 493                         ol_with_threads=no
 494                 fi
 495         fi
 496
 497         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 498                 ol_with_threads=posix
 499                 ol_cv_pthread_create=yes
 500         fi
 501 fi
 502
 503 if test -z "${CC}"; then
 504         AC_CHECK_PROGS(CC,cc)
 505 fi
 506
 507 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 508 dnl (for now, let autoconf sort this out)
 509 dnl CFLAGS=${CFLAGS-""}
 510
 511 AC_LIBTOOL_WIN32_DLL
 512 AC_LIBTOOL_DLOPEN
 513 AC_PROG_LIBTOOL
 514
 515 AC_PROG_AWK
 516 OL_PROG_LN_H
 517 AC_PROG_LN_S
 518
 519 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 520         LN_S="$LN_H"
 521 fi
 522
 523 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 524         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 525 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 526 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 527
 528 dnl ----------------------------------------------------------------
 529 dnl Perl
 530 ol_link_perl=no
 531 if test $ol_enable_perl != no ; then
 532         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 533
 534         if test "no$PERLBIN" = "no" ; then
 535                 if test $ol_enable_perl = yes ; then
 536                         AC_MSG_ERROR([could not locate perl])
 537                 fi
 538
 539         else
 540                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 541                 if test x"$ol_with_perl_module" = "xstatic" ; then
 542                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 543                 else
 544                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 545                 fi
 546                 dnl should check perl version
 547                 ol_link_perl=yes
 548         fi
 549 fi
 550
 551 AC_PROG_CPP
 552
 553 dnl ----------------------------------------------------------------
 554 dnl Cross compiling checks
 555 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 556         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 557
 558 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 559         AC_MSG_WARN([programs compiled here do run here...])
 560         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 561
 562 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 563         AC_MSG_WARN([programs compiled here do not run here...])
 564         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 565 fi
 566
 567 dnl ----------------------------------------------------------------
 568 dnl Checks for UNIX Variants
 569 AC_AIX
 570 AC_ISC_POSIX
 571 AC_MINIX
 572
 573 dnl ----------------------------------------------------------------
 574 dnl Checks for system services
 575 AC_CYGWIN
 576 AC_MINGW32
 577 AC_EXEEXT
 578 AC_OBJEXT
 579
 580 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 581
 582 dnl ----------------------------------------------------------------
 583 dnl BeOS requires -lbe -lroot -lnet
 584 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 585
 586 dnl ----------------------------------------------------------------
 587 dnl OpenLDAP requires STDC features
 588 AM_PROG_CC_STDC
 589 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 590         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 591 fi
 592
 593 dnl ----------------------------------------------------------------
 594 dnl Check cc depend flags
 595 OL_MKDEPEND
 596 if test "${ol_cv_mkdep}" = no ; then
 597         # this will soon become an error
 598         AC_MSG_WARN([do not know how to generate dependencies])
 599 fi
 600
 601 dnl ----------------------------------------------------------------
 602 dnl Check for module support
 603 ol_link_modules=no
 604 if test $ol_enable_modules != no ; then
 605         AC_CHECK_HEADERS(ltdl.h)
 606
 607         if test $ac_cv_header_ltdl_h = no ; then
 608                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 609         fi
 610
 611         AC_CHECK_LIB(ltdl, lt_dlinit, [
 612             MODULES_LIBS=-lltdl
 613             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 614         ])
 615
 616         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 617                 AC_MSG_ERROR([could not locate libtool -lltdl])
 618         fi
 619         ol_link_modules=yes
 620 else
 621         ol_with_bdb2_module=static
 622         ol_with_ldap_module=static
 623         ol_with_ldbm_module=static
 624         ol_with_passwd_module=static
 625         ol_with_perl_module=static
 626         ol_with_shell_module=static
 627         ol_with_tcl_module=static
 628 fi
 629
 630 dnl ----------------------------------------------------------------
 631 dnl Checks for header files.
 632 OL_HEADER_STDC
 633
 634 if test $ol_cv_header_stdc != yes; then
 635         AC_MSG_WARN([could not locate Standard C compliant headers])
 636 fi
 637
 638 AC_HEADER_DIRENT
 639 AC_HEADER_SYS_WAIT
 640 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 641 if test $am_cv_sys_posix_termios = yes ; then
 642         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 643                 [define if you have POSIX termios])
 644 fi
 645
 646 AC_CHECK_HEADERS(       \
 647         arpa/inet.h             \
 648         arpa/nameser.h  \
 649         assert.h                \
 650         conio.h                 \
 651         crypt.h                 \
 652         direct.h                \
 653         errno.h                 \
 654         fcntl.h                 \
 655         filio.h                 \
 656         getopt.h                \
 657         grp.h                   \
 658         io.h                    \
 659         libutil.h               \
 660         limits.h                \
 661         locale.h                \
 662         netinet/tcp.h   \
 663         malloc.h                \
 664         memory.h                \
 665         psap.h                  \
 666         pwd.h                   \
 667         process.h               \
 668         resolv.h                \
 669         sgtty.h                 \
 670         shadow.h                \
 671         stddef.h                \
 672         string.h                \
 673         strings.h               \
 674         sysexits.h              \
 675         sys/file.h              \
 676         sys/filio.h             \
 677         sys/errno.h             \
 678         sys/ioctl.h             \
 679         sys/param.h             \
 680         sys/resource.h  \
 681         sys/select.h    \
 682         sys/socket.h    \
 683         sys/syslog.h    \
 684         sys/time.h              \
 685         sys/types.h             \
 686         syslog.h                \
 687         termios.h               \
 688         unistd.h                \
 689         winsock.h               \
 690 )
 691
 692
 693 dnl ----------------------------------------------------------------
 694 dnl Checks for libraries
 695
 696 dnl HP-UX requires -lV3
 697 AC_CHECK_LIB(V3, sigset)
 698
 699 dnl Gotta check for winsock manually
 700 if test $ac_cv_header_winsock_h = yes; then
 701         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 702         AC_TRY_LINK([#include <winsock.h>],[
 703                         socket(0,0,0);
 704                         select(0,NULL,NULL,NULL,NULL);
 705                         closesocket(0);
 706                         gethostname(NULL,0);
 707         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 708
 709         if test $ol_cv_winsock = yes ; then
 710                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 711                 ac_cv_func_socket=yes
 712                 ac_cv_func_select=yes
 713                 ac_cv_func_closesocket=yes
 714                 ac_cv_func_gethostname=yes
 715         fi
 716 fi
 717
 718 dnl Find socket()
 719 dnl Likely combinations:
 720 dnl             -lsocket [ -lnsl_s | -lnsl ]
 721 dnl             -linet
 722
 723 AC_CHECK_FUNC(socket, :, [
 724 dnl hopefully we won't include too many libraries
 725         AC_CHECK_LIB(socket, main)
 726         AC_CHECK_LIB(net, main)
 727         AC_CHECK_LIB(nsl_s, main)
 728         AC_CHECK_LIB(nsl, main)
 729         AC_CHECK_LIB(inet, socket)
 730         AC_CHECK_LIB(gen, main)
 731 ])
 732
 733 dnl require select
 734 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 735
 736 if test "${ac_cv_header_winsock_h}" != yes; then
 737     dnl Select arg types
 738     dnl (if this detection becomes permenent, it and the select() detection
 739     dnl should be done before the yielding select test)
 740     AC_FUNC_SELECT_ARGTYPES
 741 fi
 742
 743 dnl check to see if system call automatically restart
 744 dnl AC_SYS_RESTARTABLE_SYSCALLS
 745
 746 dnl ----------------------------------------------------------------
 747 dnl require POSIX regex
 748 AC_CHECK_HEADERS( regex.h )
 749 if test "$ac_cv_header_regex_h" != yes ; then
 750         AC_MSG_ERROR([POSIX regex.h required.])
 751 fi
 752 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 753
 754 OL_POSIX_REGEX
 755 if test "$ol_cv_c_posix_regex" = no ; then
 756         AC_MSG_ERROR([broken POSIX regex!])
 757 fi
 758
 759 dnl ----------------------------------------------------------------
 760 dnl Check for resolver routines
 761 AC_CHECK_FUNC(res_search,:)
 762 if test $ac_cv_func_res_search = no ; then
 763         AC_CHECK_LIB(bind, res_search)
 764         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 765 fi
 766
 767 if test $ac_cv_func_res_search = no ; then
 768         AC_CHECK_LIB(bind, __res_search)
 769         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 770 fi
 771
 772 if test $ac_cv_func_res_search = no ; then
 773         AC_CHECK_LIB(resolv, res_search)
 774         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 775 fi
 776
 777 if test "$ac_cv_func_res_search" = yes ; then
 778         AC_DEFINE(HAVE_RES_SEARCH,1,
 779                 [define if you have res_search()])
 780 elif test $ol_enable_dns = yes ; then
 781         AC_MSG_ERROR([--enable-dns requires res_search])
 782 elif test $ol_enable_dns != no ; then
 783         AC_MSG_WARN([no res_search, disabling DNS support])
 784 fi
 785
 786
 787 dnl ----------------------------------------------------------------
 788 dnl ISODE tests
 789 ol_link_isode=no
 790 if test $ol_enable_ldapd != no ; then
 791         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 792
 793         dnl look for ISODE libraries
 794         AC_CHECK_LIB(xtpp, main, [
 795                 ol_link_isode=yes
 796                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 797                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 798                 ],:,[-lxtdsap -lxtisode -losi])
 799         AC_CHECK_LIB(dsap, main, [
 800                 ol_link_isode=yes
 801                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 802                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 803                 ],:,[-lisode])
 804         AC_CHECK_LIB(isode, main, [
 805                 ol_link_isode=yes
 806                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 807                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 808                 ],:)
 809 fi
 810
 811 if test $ol_link_isode != no; then
 812         AC_CHECK_LIB(pp, main, [
 813                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 814                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 815                 ],:)
 816
 817         AC_PATH_PROG(PEPSY, pepsy)
 818 fi
 819
 820 dnl ----------------------------------------------------------------
 821 dnl QUIPU
 822 if test $ol_enable_quipu != no ; then
 823         AC_CHECK_HEADERS(quipu/commonarg.h)
 824
 825         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 826                 BUILD_QUIPU=yes
 827         elif test $ol_enable_quipu = auto ; then
 828                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 829         else
 830                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 831         fi
 832 fi
 833
 834 dnl ----------------------------------------------------------------
 835 dnl Kerberos
 836 ol_link_kbind=no
 837 ol_link_kpasswd=no
 838 ol_link_krb5=no
 839 ol_link_krb4=no
 840
 841 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 842         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 843
 844         AC_CHECK_HEADERS(krb5.h)
 845
 846         if test $ac_cv_header_krb5_h = yes ; then
 847                 dnl lazy check for Heimdal Kerberos
 848                 AC_CHECK_HEADERS(heim_err.h)
 849                 if test $ac_cv_header_heim_err_h = yes ; then
 850                         krb5_impl=heimdal
 851                 else
 852                         krb5_impl=mit
 853                 fi
 854
 855                 if test $krb5_impl = mit; then
 856                         AC_CHECK_LIB(krb5, main,
 857                                 [have_krb5=yes
 858                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 859                                 [have_krb5=no],
 860                                 [-lcrypto -lcom_err])
 861
 862                 elif test $krb5_impl = heimdal; then
 863                         AC_CHECK_LIB(krb5, main,
 864                                 [have_krb5=yes
 865                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 866                                 [have_krb5=no],
 867                                 [-ldes -lasn1 -lroken -lcom_err])
 868
 869                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 870                                 [define if you have HEIMDAL Kerberos])
 871                 else
 872                         have_krb5=no
 873                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 874                 fi
 875
 876                 if test $have_krb5 = yes ; then
 877                         ol_link_krb5=yes
 878
 879                         AC_DEFINE(HAVE_KRB5, 1,
 880                                 [define if you have Kerberos V])
 881
 882                         if test $ol_enable_kpasswd != no ; then
 883                                 ol_link_kpasswd=yes;
 884                         fi
 885
 886                         if test $ol_with_kerberos = k5only ; then
 887                                 ol_with_kerberos=found
 888                         fi
 889
 890                 elif test $ol_with_kerberos != auto ; then
 891                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 892                 fi
 893
 894         fi
 895 fi
 896
 897 if test $ol_link_krb5 = yes -a \
 898         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 899
 900         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 901
 902         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 903                 if test $krb5_impl = mit; then
 904                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 905                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 906                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 907
 908                 elif test $krb5_impl = heimdal; then
 909                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 910                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 911                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 912
 913                 else
 914                         have_425=no
 915                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 916                 fi
 917
 918                 if test $have_k425 = yes ; then
 919                         ol_with_kerberos=found
 920                         ol_link_krb4=yes
 921
 922                         AC_DEFINE(HAVE_KRB425, 1,
 923                                 [define if you have Kerberos V with IV support])
 924                         AC_DEFINE(HAVE_KRB4, 1,
 925                                 [define if you have Kerberos IV])
 926
 927                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 928                                 [ol_cv_var_des_debug], [
 929                                 dnl save the flags
 930                                 save_LIBS="$LIBS"
 931                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 932                                 AC_TRY_LINK([
 933 #include <kerberosIV/krb.h>
 934 #include <kerberosIV/des.h>
 935 extern int des_debug;
 936 ],[
 937 des_debug = 1;
 938 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 939                                 dnl restore the LIBS
 940                                 LIBS="$save_LIBS"
 941                         ])
 942
 943                         if test $ol_cv_var_des_debug = yes ; then
 944                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 945                                         [define if you have Kerberos des_debug])
 946                         fi
 947
 948                         LIBS="$save_LIBS"
 949                 fi
 950         fi
 951 fi
 952
 953 if test $ol_link_krb5 = yes ; then
 954         ol_with_kerberos=found
 955 fi
 956
 957 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 958         -o $ol_with_kerberos = kth ; then
 959
 960         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 961
 962         if test $ac_cv_header_krb_h = yes ; then
 963                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 964
 965                 if test $have_k4 = yes ; then
 966                         ol_with_kerberos=found
 967                         ol_link_krb4=yes
 968
 969                         AC_DEFINE(HAVE_KRB4, 1,
 970                                 [define if you have Kerberos IV])
 971
 972                         KRB4_LIBS="-lkrb -ldes"
 973
 974                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 975                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 976                                         [define if you have Kth Kerberos])
 977                         fi
 978                 fi
 979         fi
 980 fi
 981
 982 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 983         ol_link_kpasswd=yes;
 984 fi
 985
 986 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 987         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 988
 989 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 990         AC_MSG_ERROR([Kerberos detection failed.])
 991 fi
 992
 993 dnl ----------------------------------------------------------------
 994 dnl TLS/SSL
 995 ol_link_tls=no
 996 if test $ol_with_tls != no ; then
 997
 998         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 999
1000         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
1001                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1002                         [have_ssleay=yes
1003                         need_rsaref=no],
1004                         [have_ssleay=no],
1005                         [-lcrypto])
1006
1007                 if test $have_ssleay = no ; then
1008                         AC_CHECK_LIB(ssl, SSL_library_init,
1009                                 [have_ssleay=yes
1010                                 need_rsaref=no], [have_ssleay=no],
1011                                 [-lcrypto])
1012                 fi
1013
1014                 if test $have_ssleay = no ; then
1015                         AC_CHECK_LIB(ssl, ssl3_accept,
1016                                 [have_ssleay=yes
1017                                 need_rsaref=yes], [have_ssleay=no],
1018                                 [-lcrypto -lRSAglue -lrsaref])
1019                 fi
1020
1021                 if test $have_ssleay = yes ; then
1022                         ol_with_tls=found
1023                         ol_link_tls=yes
1024
1025                         AC_DEFINE(HAVE_SSLEAY, 1,
1026                                 [define if you have SSLeay or OpenSSL])
1027
1028                         if test $need_rsaref = yes; then
1029                                 AC_DEFINE(HAVE_RSAREF, 1,
1030                                         [define if you have RSAref])
1031
1032                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1033                         else
1034                                 TLS_LIBS="-lssl -lcrypto"
1035                         fi
1036                 fi
1037         fi
1038 fi
1039
1040 if test $ol_link_tls = yes ; then
1041         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1042 fi
1043
1044 dnl ----------------------------------------------------------------
1045 dnl Tests for reentrant functions necessary to build a
1046 dnl thread_safe -lldap.
1047 AC_CHECK_FUNCS(         \
1048         ctime_r                 \
1049         gethostbyname_r gethostbyaddr_r \
1050 )
1051
1052 if test "$ac_cv_func_ctime_r" = no ; then
1053         ol_cv_func_ctime_r_nargs=0
1054 else
1055         OL_FUNC_CTIME_R_NARGS
1056 dnl     OL_FUNC_CTIME_R_TYPE
1057 fi
1058
1059 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1060         OL_FUNC_GETHOSTBYNAME_R_NARGS
1061 else
1062         ol_cv_func_gethostbyname_r_nargs=0
1063 fi
1064
1065 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1066         OL_FUNC_GETHOSTBYADDR_R_NARGS
1067 else
1068         ol_cv_func_gethostbyaddr_r_nargs=0
1069 fi
1070
1071 if test "$ac_cv_func_ctime_r" = yes \
1072         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1073         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1074         -a "$ac_cv_func_gethostbyname_r" = yes \
1075         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1076         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1077         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1078         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1079         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1080         ; then
1081
1082         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1083 fi
1084
1085 dnl ----------------------------------------------------------------
1086 dnl Threads?
1087 ol_link_threads=no
1088
1089 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1090         -o $ol_with_threads = nt ; then
1091
1092         OL_NT_THREADS
1093
1094         if test "$ol_cv_nt_threads" = yes ; then
1095         ol_link_threads=nt
1096         ol_with_threads=found
1097         ol_with_yielding_select=yes
1098
1099                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1100                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1101         fi
1102
1103         if test $ol_with_threads = nt ; then
1104                 AC_MSG_ERROR([could not locate NT Threads])
1105         fi
1106 fi
1107
1108 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1109         -o $ol_with_threads = posix ; then
1110
1111         AC_CHECK_HEADERS(pthread.h)
1112
1113         if test $ac_cv_header_pthread_h = yes ; then
1114                 OL_POSIX_THREAD_VERSION
1115
1116                 if test $ol_cv_pthread_version = final ; then
1117                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1118                                 [define if pthreads API compatible with final spec])
1119                 elif test $ol_cv_pthread_version = draft4 ; then
1120                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1121                                 [define if pthreads API compatible with draft4 spec])
1122                 else
1123                         AC_MSG_ERROR([unknown pthread version])
1124                 fi
1125
1126                 # consider threads found
1127                 ol_with_threads=found
1128
1129                 OL_HEADER_LINUX_THREADS
1130                 OL_HEADER_GNU_PTH_PTHREAD_H
1131
1132                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1133                         AC_CHECK_HEADERS(sched.h)
1134                 fi
1135
1136                 dnl Now the hard part, how to link?
1137                 dnl
1138                 dnl currently supported checks:
1139                 dnl
1140                 dnl Check for no flags
1141                 dnl     pthread_create() in $LIBS
1142                 dnl
1143                 dnl Check special pthread (final) flags
1144                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1145                 dnl     pthread_create() with -kthread (FreeBSD)
1146                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1147                 dnl     pthread_create() with -pthreads (?)
1148                 dnl     pthread_create() with -mthreads (AIX)
1149                 dnl     pthread_create() with -thread (?)
1150                 dnl
1151                 dnl Check pthread (final) libraries
1152                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1153                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1154                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1155                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1156                 dnl     pthread_create() in -lpthread (many)
1157                 dnl     pthread_create() in -lc_r (FreeBSD)
1158                 dnl
1159                 dnl Check pthread (draft4) flags (depreciated)
1160                 dnl     pthread_create() with -threads (OSF/1)
1161                 dnl
1162                 dnl Check pthread (draft4) libraries (depreciated)
1163                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1164                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1165                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1166                 dnl     pthread_create() in -lpthreads (many)
1167                 dnl
1168
1169                 dnl pthread_create in $LIBS
1170                 AC_CACHE_CHECK([for pthread_create in default libraries],
1171                         ol_cv_pthread_create,[
1172                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1173                         [ol_cv_pthread_create=yes],
1174                         [ol_cv_pthread_create=no],
1175                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1176                                 [ol_cv_pthread_create=yes],
1177                                 [ol_cv_pthread_create=no])])])
1178
1179                 if test $ol_cv_pthread_create != no ; then
1180                         ol_link_threads=posix
1181                         ol_link_pthreads=""
1182                 fi
1183
1184 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1185                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1186                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1187                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1188                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1189                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1190
1191                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1192                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1193                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1194                         [ol_cv_pthread_lpthread_lmach_lexc])
1195 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1196 dnl                     [ol_cv_pthread_lpthread_lexc])
1197
1198                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1199                         [ol_cv_pthread_lib_lpthread_woff])
1200
1201                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1202                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1203
1204                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1205
1206                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1207                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1208                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1209                         [ol_cv_pthread_lpthreads_lmach_lexc])
1210                 OL_PTHREAD_TRY([-lpthreads -lexc],
1211                         [ol_cv_pthread_lpthreads_lexc])
1212
1213                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1214
1215                 if test $ol_link_threads != no ; then
1216                         AC_DEFINE(HAVE_PTHREADS,1,
1217                                 [define if you have POSIX Threads])
1218
1219                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1220
1221                         dnl save flags
1222                         save_CPPFLAGS="$CPPFLAGS"
1223                         save_LIBS="$LIBS"
1224                         LIBS="$LTHREAD_LIBS $LIBS"
1225
1226                         dnl All POSIX Thread (final) implementations should have
1227                         dnl sched_yield instead of pthread yield.
1228                         dnl check for both
1229                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1230
1231                         if test $ac_cv_func_sched_yield = no -a \
1232                                 $ac_cv_func_pthread_yield = no ; then
1233                                 dnl Digital UNIX has sched_yield() in -lrt
1234                                 AC_CHECK_LIB(rt, sched_yield,
1235                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1236                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1237                                                 [Define if you have the sched_yield function.])
1238                                         ac_cv_func_sched_yield=yes],
1239                                         [ac_cv_func_sched_yield=no])
1240                         fi
1241                         if test $ac_cv_func_sched_yield = no -a \
1242                                 $ac_cv_func_pthread_yield = no ; then
1243                                 dnl Solaris has sched_yield() stub in -lposix4
1244                                 dnl but we'll use thr_yield instead.
1245                                 AC_CHECK_FUNCS(thr_yield)
1246                         fi
1247                         if test $ac_cv_func_sched_yield = no -a \
1248                                 $ac_cv_func_pthread_yield = no -a \
1249                                 "$ac_cv_func_thr_yield" = no ; then
1250                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1251                         fi
1252
1253                         dnl Check functions for compatibility
1254                         AC_CHECK_FUNCS(pthread_kill)
1255
1256                         dnl Check for pthread_detach with <pthread.h> inclusion
1257                         dnl as it's symbol may have been mangled.
1258                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1259                                 [ol_cv_func_pthread_detach], [
1260                                 dnl save the flags
1261                                 AC_TRY_LINK([
1262 #include <pthread.h>
1263 #ifndef NULL
1264 #define NULL (void*)0
1265 #endif
1266 ],
1267                                         [pthread_detach(NULL);],
1268                                         [ol_cv_func_pthread_detach=yes],
1269                                         [ol_cv_func_pthread_detach=no])
1270                         ])
1271
1272                         if test $ol_cv_func_pthread_detach = no ; then
1273                                 AC_MSG_ERROR([could not locate pthread_detach()])
1274                         fi
1275
1276                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1277                                 [define if you have pthread_detach function])
1278
1279                         dnl Check for setconcurreny functions
1280                         AC_CHECK_FUNCS( \
1281                                 pthread_setconcurrency \
1282                                 pthread_getconcurrency \
1283                                 thr_setconcurrency \
1284                                 thr_getconcurrency \
1285                         )
1286
1287                         OL_SYS_LINUX_THREADS
1288                         OL_LINUX_THREADS
1289
1290                         if test $ol_cv_linux_threads = error; then
1291                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1292                         fi
1293
1294                         AC_CACHE_CHECK([if pthread_create() works],
1295                                 ol_cv_pthread_create_works,[
1296                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1297                                 [ol_cv_pthread_create_works=yes],
1298                                 [ol_cv_pthread_create_works=no],
1299                                 [dnl assume yes
1300                                 ol_cv_pthread_create_works=yes])])
1301
1302                         if test $ol_cv_pthread_create_works = no ; then
1303                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1304                         fi
1305
1306                         dnl Check if select causes an yield
1307                         if test $ol_with_yielding_select = auto ; then
1308                                 AC_CACHE_CHECK([if select yields when using pthreads],
1309                                         ol_cv_pthread_select_yields,[
1310                                 AC_TRY_RUN([
1311 #include <sys/types.h>
1312 #include <sys/time.h>
1313 #include <unistd.h>
1314 #include <pthread.h>
1315 #ifndef NULL
1316 #define NULL (void*) 0
1317 #endif
1318
1319 static int fildes[2];
1320
1321 static void *task(p)
1322         void *p;
1323 {
1324         int i;
1325         struct timeval tv;
1326
1327         fd_set rfds;
1328
1329         tv.tv_sec=10;
1330         tv.tv_usec=0;
1331
1332         FD_ZERO(&rfds);
1333         FD_SET(fildes[0], &rfds);
1334
1335         /* we're not interested in any fds */
1336         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1337
1338         if(i < 0) {
1339                 perror("select");
1340                 exit(10);
1341         }
1342
1343         exit(0); /* if we exit here, the select blocked the whole process */
1344 }
1345
1346 int main(argc, argv)
1347         int argc;
1348         char **argv;
1349 {
1350         pthread_t t;
1351
1352         /* create a pipe to select */
1353         if(pipe(&fildes[0])) {
1354                 perror("select");
1355                 exit(1);
1356         }
1357
1358 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1359         (void) pthread_setconcurrency(2);
1360 #else
1361 #ifdef HAVE_THR_SETCONCURRENCY
1362         /* Set Solaris LWP concurrency to 2 */
1363         thr_setconcurrency(2);
1364 #endif
1365 #endif
1366
1367 #if HAVE_PTHREADS_D4
1368         pthread_create(&t, pthread_attr_default, task, NULL);
1369 #else
1370         pthread_create(&t, NULL, task, NULL);
1371 #endif
1372
1373 #if HAVE_SCHED_YIELD
1374         sched_yield();  /* make sure task runs first */
1375 #else
1376 #ifdef HAVE_PTHREAD_YIELD
1377         pthread_yield();        /* make sure task runs first */
1378 #endif
1379 #endif
1380
1381         exit(2);
1382 }],
1383                                 [ol_cv_pthread_select_yields=no],
1384                                 [ol_cv_pthread_select_yields=yes],
1385                                 [ol_cv_pthread_select_yields=cross])])
1386
1387                                 if test $ol_cv_pthread_select_yields = cross ; then
1388                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1389                                 fi
1390
1391                                 if test $ol_cv_pthread_select_yields = yes ; then
1392                                         ol_with_yielding_select=yes
1393                                 fi
1394                         fi
1395
1396                         dnl restore flags
1397                         CPPFLAGS="$save_CPPFLAGS"
1398                         LIBS="$save_LIBS"
1399                 else
1400                         AC_MSG_ERROR([could not link with POSIX Threads])
1401                 fi
1402         fi
1403
1404         if test $ol_with_threads = posix ; then
1405                 AC_MSG_ERROR([could not locate POSIX Threads])
1406         fi
1407 fi
1408
1409 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1410         -o $ol_with_threads = mach ; then
1411
1412         dnl check for Mach CThreads
1413         AC_CHECK_HEADERS(mach/cthreads.h)
1414         if test $ac_cv_header_mach_cthreads_h = yes ; then
1415                 ol_with_threads=found
1416
1417                 dnl check for cthread support in current $LIBS
1418                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1419
1420                 if test $ol_link_threads = no ; then
1421                         dnl try -all_load
1422                         dnl this test needs work
1423                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1424                                 [ol_cv_cthread_all_load], [
1425                                 dnl save the flags
1426                                 save_LIBS="$LIBS"
1427                                 LIBS="-all_load $LIBS"
1428                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1429                                         cthread_fork((void *)0, (void *)0);
1430                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1431                                 dnl restore the LIBS
1432                                 LIBS="$save_LIBS"
1433                         ])
1434
1435                         if test $ol_cv_cthread_all_load = yes ; then
1436                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1437                                 ol_link_threads=mach
1438                         fi
1439                 fi
1440
1441                 if test $ol_link_threads != no ; then
1442                         : check for cthread specific functionality here
1443                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1444                                 [define if you have Mach Cthreads])
1445                 else
1446                         AC_MSG_ERROR([could not link with Mach CThreads])
1447                 fi
1448         fi
1449
1450         if test $ol_with_threads = mach ; then
1451                 AC_MSG_ERROR([could not locate Mach CThreads])
1452         fi
1453 fi
1454
1455 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1456         -o $ol_with_threads = pth ; then
1457
1458         AC_CHECK_HEADERS(pth.h)
1459
1460         if test $ac_cv_header_pth_h = yes ; then
1461                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1462
1463                 if test $have_pth = yes ; then
1464                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1465                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1466                         ol_link_threads=pth
1467
1468                         if test $ol_with_yielding_select = auto ; then
1469                                 ol_with_yielding_select=yes
1470                         fi
1471                 fi
1472         fi
1473 fi
1474
1475 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1476         -o $ol_with_threads = lwp ; then
1477
1478         dnl check for SunOS5 LWP
1479         AC_CHECK_HEADERS(thread.h synch.h)
1480         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1481                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1482
1483                 if test $have_thr = yes ; then
1484                         AC_DEFINE(HAVE_THR,1,
1485                                 [if you have Solaris LWP (thr) package])
1486                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1487                         ol_link_threads=thr
1488
1489                         if test $ol_with_yielding_select = auto ; then
1490                                 ol_with_yielding_select=yes
1491                         fi
1492
1493                         dnl Check for setconcurreny functions
1494                         AC_CHECK_FUNCS( \
1495                                 thr_setconcurrency \
1496                                 thr_getconcurrency \
1497                         )
1498                 fi
1499         fi
1500
1501         dnl check for SunOS4 LWP
1502         AC_CHECK_HEADERS(lwp/lwp.h)
1503         if test $ac_cv_header_lwp_lwp_h = yes ; then
1504                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1505
1506                 if test $have_lwp = yes ; then
1507                         AC_DEFINE(HAVE_LWP,1,
1508                                 [if you have SunOS LWP package])
1509                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1510                         ol_link_threads=lwp
1511
1512                         if test $ol_with_yielding_select = auto ; then
1513                                 ol_with_yielding_select=no
1514                         fi
1515                 fi
1516         fi
1517 fi
1518
1519 if test $ol_with_yielding_select = yes ; then
1520         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1521                 [define if select implicitly yields])
1522 fi
1523
1524 if test $ol_with_threads = manual ; then
1525         dnl User thinks he can manually configure threads.
1526         ol_link_threads=yes
1527
1528         AC_MSG_WARN([thread defines and link options must be set manually])
1529
1530         AC_CHECK_HEADERS(pthread.h sched.h)
1531         AC_CHECK_FUNCS(sched_yield pthread_yield)
1532         OL_HEADER_LINUX_THREADS
1533
1534         AC_CHECK_HEADERS(mach/cthreads.h)
1535         AC_CHECK_HEADERS(lwp/lwp.h)
1536         AC_CHECK_HEADERS(thread.h synch.h)
1537 fi
1538
1539 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1540         dnl needed to get reentrant/threadsafe versions
1541         dnl
1542         AC_DEFINE(REENTRANT,1)
1543         AC_DEFINE(_REENTRANT,1)
1544         AC_DEFINE(THREAD_SAFE,1)
1545         AC_DEFINE(_THREAD_SAFE,1)
1546         AC_DEFINE(THREADSAFE,1)
1547         AC_DEFINE(_THREADSAFE,1)
1548         AC_DEFINE(_SGI_MP_SOURCE,1)
1549
1550         dnl The errno declaration may dependent upon _REENTRANT.
1551         dnl If it does, we must link with thread support.
1552         AC_CACHE_CHECK([for thread specific errno],
1553                 [ol_cv_errno_thread_specific], [
1554                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1555                         [ol_cv_errno_thread_specific=yes],
1556                         [ol_cv_errno_thread_specific=no])
1557         ])
1558
1559         dnl The h_errno declaration may dependent upon _REENTRANT.
1560         dnl If it does, we must link with thread support.
1561         AC_CACHE_CHECK([for thread specific h_errno],
1562                 [ol_cv_h_errno_thread_specific], [
1563                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1564                         [ol_cv_h_errno_thread_specific=yes],
1565                         [ol_cv_h_errno_thread_specific=no])
1566         ])
1567
1568         if test $ol_cv_errno_thread_specific != yes \
1569                 -o $ol_cv_h_errno_thread_specific != yes ; then
1570                 LIBS="$LTHREAD_LIBS $LIBS"
1571                 LTHREAD_LIBS=""
1572         fi
1573
1574 dnl When in thread environment, use
1575 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1576 dnl                     || defined( HAVE_FUNC_R )
1577 dnl                     func_r(...);
1578 dnl             #else
1579 dnl             #       if defined( HAVE_THREADS )
1580 dnl                             /* lock */
1581 dnl             #       endif
1582 dnl                             func(...);
1583 dnl             #       if defined( HAVE_THREADS )
1584 dnl                             /* unlock */
1585 dnl             #       endif
1586 dnl             #endif
1587 dnl
1588 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1589 dnl             _POSIX_REENTRANT_FUNCTIONS
1590 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1591 dnl             _POSIX_THREADSAFE_FUNCTIONS
1592 dnl
1593 dnl             and is currently defined in lthread.h
1594 dnl
1595 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1596 dnl
1597 dnl libldap/*.c should only include <lthread.h> iff
1598 dnl LDAP_R_COMPILE is defined.  ie:
1599 dnl             #ifdef LDAP_R_COMPILE
1600 dnl             #       include LDAP_R_COMPILE
1601 dnl             #endif
1602 dnl
1603 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1604 dnl specifically for compiling the threadsafe version of
1605 dnl     the ldap library (-lldap_r).
1606 dnl
1607 dnl     dnl check for reentrant/threadsafe functions
1608 dnl     dnl
1609 dnl     dnl note: these should only be used when linking
1610 dnl     dnl       with $LTHREAD_LIBS
1611 dnl     dnl
1612 dnl     save_CPPFLAGS="$CPPFLAGS"
1613 dnl     save_LIBS="$LIBS"
1614 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1615 dnl     AC_CHECK_FUNCS( \
1616 dnl             gmtime_r \
1617 dnl             gethostbyaddr_r gethostbyname_r \
1618 dnl             feof_unlocked unlocked_feof \
1619 dnl             putc_unlocked unlocked_putc \
1620 dnl             flockfile ftrylockfile \
1621 dnl     )
1622 dnl     CPPFLAGS="$save_CPPFLAGS"
1623 dnl     LIBS="$save_LIBS"
1624 fi
1625
1626 if test $ol_link_threads = no ; then
1627         if test $ol_with_threads = yes ; then
1628                 AC_MSG_ERROR([no suitable thread support])
1629         fi
1630
1631         if test $ol_with_threads = auto ; then
1632                 AC_MSG_WARN([no suitable thread support, disabling threads])
1633                 ol_with_threads=no
1634         fi
1635
1636         AC_DEFINE(NO_THREADS,1,
1637                 [define if you have (or want) no threads])
1638         LTHREAD_LIBS=""
1639 fi
1640
1641 if test $ol_link_threads != no ; then
1642         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1643 fi
1644
1645 dnl ----------------------------------------------------------------
1646
1647 ol_link_ldbm=no
1648 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1649         OL_BERKELEY_DB2
1650
1651         if test $ol_cv_berkeley_db2 = yes ; then
1652                 ol_link_ldbm=db2
1653                 ol_with_ldbm_api=db2
1654
1655                 if test $ol_with_ldbm_type = hash ; then
1656                         AC_DEFINE(LDBM_USE_DBHASH,1,
1657                                 [define this to use DBHASH w/ LDBM backend])
1658                 else
1659                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1660                                 [define this to use DBBTREE w/ LDBM backend])
1661                 fi
1662
1663                 OL_BERKELEY_DB2_DB_THREAD
1664
1665                 dnl $ol_cv_lib_db2 should be yes or -ldb
1666                 dnl (it could be no, but that would be an error
1667                 if test $ol_cv_lib_db2 != yes ; then
1668                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1669                 fi
1670         fi
1671 fi
1672
1673 ol_link_bdb2=no
1674 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1675         if test $ol_cv_berkeley_db2_db_thread != no ; then
1676                 ol_link_bdb2=yes
1677         else
1678                 AC_MSG_WARN([Installed BerkeleyDB does not provide DB_THREAD support.])
1679         fi
1680 fi
1681
1682 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1683         OL_BERKELEY_DB
1684
1685         if test $ol_cv_berkeley_db = yes ; then
1686                 ol_link_ldbm=db
1687                 ol_with_ldbm_api=db
1688
1689                 if test $ol_with_ldbm_type = hash ; then
1690                         AC_DEFINE(LDBM_USE_DBHASH,1,
1691                                 [define this to use DBHASH w/ LDBM backend])
1692                 else
1693                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1694                                 [define this to use DBBTREE w/ LDBM backend])
1695                 fi
1696
1697                 dnl $ol_cv_lib_db should be yes or -ldb
1698                 dnl (it could be no, but that would be an error
1699                 if test $ol_cv_lib_db != yes ; then
1700                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1701                 fi
1702         fi
1703 fi
1704
1705 if test $ol_with_ldbm_api = manual ; then
1706         dnl User thinks he can manually configure LDBM api.
1707         ol_link_ldbm=yes
1708
1709         AC_MSG_WARN([LDBM defines and link options must be set manually])
1710
1711         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1712 fi
1713
1714 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1715         AC_MSG_WARN(Could not find LDBM with BTREE support)
1716         ol_with_ldbm_api=none
1717 fi
1718
1719 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1720         OL_MDBM
1721
1722         if test $ol_cv_mdbm = yes ; then
1723                 ol_link_ldbm=mdbm
1724                 ol_with_ldbm_api=mdbm
1725                 if test $ol_cv_lib_mdbm != yes ; then
1726                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1727                 fi
1728         fi
1729 fi
1730
1731 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1732         OL_GDBM
1733
1734         if test $ol_cv_gdbm = yes ; then
1735                 ol_link_ldbm=gdbm
1736                 ol_with_ldbm_api=gdbm
1737
1738                 if test $ol_cv_lib_gdbm != yes ; then
1739                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1740                 fi
1741         fi
1742 fi
1743
1744 if test $ol_with_ldbm_api = auto ; then
1745         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1746 elif test $ol_with_ldbm_api = ndbm ; then
1747         OL_NDBM
1748
1749         if test $ol_cv_ndbm = yes ; then
1750                 ol_link_ldbm=ndbm
1751                 ol_with_ldbm_api=ndbm
1752
1753                 if test $ol_cv_lib_ndbm != yes ; then
1754                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1755                 fi
1756         fi
1757 fi
1758
1759 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1760         AC_MSG_WARN(could not find suitable LDBM backend)
1761         if test $ol_enable_ldbm = yes ; then
1762                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1763         fi
1764
1765         AC_MSG_WARN(disabling LDBM)
1766         ol_enable_ldbm=no
1767 fi
1768
1769 dnl ----------------------------------------------------------------
1770 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1771         LINK_BINS_DYNAMIC="yes"
1772 else
1773         LINK_BINS_DYNAMIC="no"
1774 fi
1775
1776 dnl ----------------------------------------------------------------
1777 if test $ol_enable_wrappers != no ; then
1778         AC_CHECK_HEADERS(tcpd.h)
1779
1780         if test $ac_cv_header_tcpd_h != yes ; then
1781                 have_wrappers=no
1782         else
1783                 AC_TRY_COMPILE([
1784 int allow_severity = 0;
1785 int deny_severity  = 0;
1786                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1787         fi
1788
1789         if test $have_wrappers = yes ; then
1790                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1791                 WRAP_LIBS="-lwrap"
1792
1793                 dnl We add another check for -lnsl since some libwrap's
1794                 dnl need it, but it isn't always included from above
1795                 AC_CHECK_LIB(nsl, main)
1796         else
1797                 AC_MSG_WARN(could not find -lwrap)
1798                 if test $ol_enable_wrappers = yes ; then
1799                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1800                 fi
1801
1802                 AC_MSG_WARN(disabling wrappers support)
1803                 ol_enable_wrappers=no
1804                 WRAP_LIBS=""
1805         fi
1806 fi
1807
1808 dnl ----------------------------------------------------------------
1809 if test $ol_enable_syslog != no ; then
1810         AC_CHECK_FUNC(openlog)
1811         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1812                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1813         fi
1814         ol_enable_syslog=$ac_cv_func_openlog
1815 fi
1816
1817 dnl ----------------------------------------------------------------
1818 if test $ol_enable_dmalloc != no ; then
1819         AC_CHECK_HEADERS(dmalloc.h)
1820         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1821 fi
1822
1823 dnl ----------------------------------------------------------------
1824 dnl TCL
1825 if test $ol_enable_tcl != no ; then
1826         AC_CHECK_HEADERS(tcl.h)
1827
1828         if test $ac_cv_header_tcl_h != yes ; then
1829                 have_tcl=no
1830         else
1831                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1832                         AC_CHECK_LIB($lib,main,
1833                           [have_tcl=yes
1834                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1835                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1836                            else
1837                                MOD_TCL_LIB="-l${lib}"
1838                            fi;break],[have_tcl=no])
1839                 done
1840         fi
1841
1842         if test $have_tcl != yes ; then
1843                 AC_MSG_WARN([could not find -ltcl])
1844                 if test $ol_enable_tcl = yes ; then
1845                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1846                 fi
1847
1848                 ol_enable_tcl=no
1849         fi
1850 fi
1851
1852 dnl ----------------------------------------------------------------
1853 dnl ud needs termcap (should insert check here)
1854 ol_link_termcap=no
1855 AC_CHECK_HEADERS(termcap.h ncurses.h)
1856
1857 if test $ol_link_termcap = no ; then
1858         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1859         if test $have_termcap = yes ; then
1860                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1861                 ol_link_termcap=yes
1862                 TERMCAP_LIBS=-ltermcap
1863         fi
1864 fi
1865
1866 if test $ol_link_termcap = no ; then
1867         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1868         if test $have_ncurses = yes ; then
1869                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1870                 ol_link_termcap=yes
1871                 TERMCAP_LIBS=-lncurses
1872         fi
1873 fi
1874
1875 if test $ol_link_termcap = no ; then
1876         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1877         TERMCAP_LIBS=
1878 fi
1879
1880 dnl ----------------------------------------------------------------
1881 dnl
1882 dnl Check for Cyrus SASL
1883 dnl
1884 ol_link_sasl=no
1885 if test $ol_with_cyrus_sasl != no ; then
1886         AC_CHECK_HEADER(sasl.h)
1887
1888         if test $ac_cv_header_sasl_h = yes ; then
1889                 AC_CHECK_LIB(sasl, sasl_client_init,
1890                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1891
1892                 if test $have_cyrus_sasl != no ; then
1893                         SASL_LIBS="-lsasl"
1894                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1895                         ol_link_sasl=yes
1896                 fi
1897         fi
1898
1899         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1900                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1901         fi
1902 fi
1903
1904 dnl ----------------------------------------------------------------
1905 dnl Check for entropy sources
1906 if test $cross_compiling != yes ; then
1907         dev=no
1908         if test -r /dev/urandom ; then
1909                 dev="/dev/urandom";
1910         elif test -r /idev/urandom ; then
1911                 dev="/idev/urandom";
1912         elif test -r /dev/srandom ; then
1913                 dev="/dev/srandom";
1914         elif test -r /dev/random ; then
1915                 dev="/dev/random";
1916         elif test -r /idev/random ; then
1917                 dev="/idev/random";
1918         fi
1919
1920         if test $dev != no ; then
1921                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1922         fi
1923 fi
1924
1925 dnl ----------------------------------------------------------------
1926 dnl
1927 dnl Check for fetch URL support
1928 dnl             should be extended to support other fetch URL APIs
1929 dnl
1930 ol_link_fetch=no
1931 if test $ol_with_fetch != no ; then
1932         OL_LIB_FETCH
1933
1934         if test $ol_cv_lib_fetch != no ; then
1935                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1936                 ol_link_fetch=freebsd
1937
1938         elif test $ol_with_fetch != auto ; then
1939                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1940         fi
1941 fi
1942
1943 dnl ----------------------------------------------------------------
1944 dnl
1945 dnl Check for GNU readline
1946 dnl
1947 ol_link_readline=no
1948 if test $ol_with_readline != no ; then
1949         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1950
1951         if test $ac_cv_header_readline_readline_h = yes ; then
1952                 save_LIBS="$LIBS"
1953                 LIBS="$TERMCAP_LIBS $LIBS"
1954                 AC_CHECK_LIB(readline, readline,
1955                         [have_readline=yes], [have_readline=no])
1956                 LIBS="$save_LIBS"
1957
1958                 if test $have_readline = yes ; then
1959                         ol_with_readline=found
1960                         ol_link_readline=yes
1961
1962                         READLINE_LIBS="-lreadline"
1963                 fi
1964         fi
1965 fi
1966
1967 if test $ol_link_readline = yes ; then
1968         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1969 fi
1970
1971
1972 dnl ----------------------------------------------------------------
1973 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1974 if test $ol_enable_crypt != no ; then
1975         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1976                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1977                         have_crypt=yes], [have_crypt=no])])
1978
1979         if test $have_crypt = yes ; then
1980                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1981         else
1982                 AC_MSG_WARN(could not find crypt)
1983                 if test $ol_enable_crypt = yes ; then
1984                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1985                 fi
1986
1987                 AC_MSG_WARN(disabling crypt support)
1988                 ol_enable_crypt=no
1989         fi
1990 fi
1991
1992 dnl ----------------------------------------------------------------
1993 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1994 if test $ol_enable_proctitle != no ; then
1995         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1996                 AC_CHECK_LIB(util, setproctitle,
1997                         [have_setproctitle=yes
1998                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1999                         [have_setproctitle=no
2000                         LIBOBJS="$LIBOBJS setproctitle.o"
2001                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2002
2003         if test $have_setproctitle = yes ; then
2004                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2005                         [define if setproctitle(3) is available])
2006         fi
2007 fi
2008
2009 dnl ----------------------------------------------------------------
2010 dnl Checks for typedefs, structures, and compiler characteristics.
2011 AC_TYPE_MODE_T
2012 AC_TYPE_OFF_T
2013 AC_TYPE_PID_T
2014 AM_TYPE_PTRDIFF_T
2015 AC_TYPE_SIGNAL
2016 AC_TYPE_SIZE_T
2017
2018 AC_CHECK_TYPE(ssize_t, [signed int])
2019 AC_CHECK_TYPE(caddr_t,  [char *])
2020
2021 OL_TYPE_SOCKLEN_T
2022 AC_STRUCT_ST_BLKSIZE
2023 AC_HEADER_TIME
2024 AC_STRUCT_TM
2025 AC_TYPE_UID_T
2026 OL_TYPE_SIG_ATOMIC_T
2027
2028 dnl AC_TYPE_GETGROUPS
2029
2030 OL_STRUCT_PASSWD_PW_GECOS
2031 OL_STRUCT_PASSWD_PW_PASSWD
2032
2033 OL_C_UPPER_LOWER
2034 AC_C_CONST
2035 OL_C_VOLATILE
2036
2037 if test $cross_compiling = yes ; then
2038         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2039 else
2040         AC_C_BIGENDIAN
2041 fi
2042
2043 AC_COMPILE_CHECK_SIZEOF(short)
2044 AC_COMPILE_CHECK_SIZEOF(int)
2045 AC_COMPILE_CHECK_SIZEOF(long)
2046
2047 if test "$ac_cv_sizeof_int" -lt 4 ; then
2048         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2049
2050         AC_DEFINE(LBER_INT_T,long)
2051 else
2052         AC_DEFINE(LBER_INT_T,int)
2053 fi
2054
2055 AC_DEFINE(LBER_LEN_T,long)
2056 AC_DEFINE(LBER_SOCKET_T,int)
2057 AC_DEFINE(LBER_TAG_T,long)
2058
2059 dnl ----------------------------------------------------------------
2060 dnl Checks for library functions.
2061 AC_FUNC_MEMCMP
2062 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2063 AC_FUNC_STRFTIME
2064 dnl AM_FUNC_STRTOD
2065
2066 OL_FUNC_INET_ATON
2067
2068 dnl Check for NT specific routines
2069 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2070
2071 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2072         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2073 ])
2074
2075 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2076         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2077 ])
2078
2079 AC_FUNC_VPRINTF
2080
2081 if test $ac_cv_func_vprintf = yes ; then
2082         dnl check for vsnprintf
2083         AC_CHECK_FUNCS(vsnprintf vsprintf)
2084 fi
2085
2086 AC_CHECK_FUNCS(         \
2087         bcopy                   \
2088         closesocket             \
2089         endgrent                \
2090         endpwent                \
2091         flock                   \
2092         getdtablesize   \
2093         getgrgid                \
2094         gethostname             \
2095         getpass                 \
2096         getpwuid                \
2097         getpwnam                \
2098         getspnam                \
2099         gettimeofday    \
2100         initgroups              \
2101         lockf                   \
2102         memcpy                  \
2103         memmove                 \
2104         mkstemp                 \
2105         pipe                    \
2106         read                    \
2107         recv                    \
2108         recvfrom                \
2109         setpwfile               \
2110         setgid                  \
2111         setegid                 \
2112         setsid                  \
2113         setuid                  \
2114         seteuid                 \
2115         sigaction               \
2116         signal                  \
2117         sigset                  \
2118         snprintf                \
2119         strdup                  \
2120         strerror                \
2121         strpbrk                 \
2122         strrchr                 \
2123         strsep                  \
2124         strstr                  \
2125         strtol                  \
2126         strtoul                 \
2127         strspn                  \
2128         sysconf                 \
2129         waitpid                 \
2130         wait4                   \
2131         write                   \
2132         send                    \
2133         sendto                  \
2134 )
2135
2136 dnl We actually may need to replace more than this.
2137 AC_REPLACE_FUNCS(getopt tempnam)
2138
2139 if test "$ac_cv_func_getopt" != yes; then
2140     LIBSRCS="$LIBSRCS getopt.c"
2141 fi
2142
2143 if test "$ac_cv_func_tempnam" != yes; then
2144     LIBSRCS="$LIBSRCS tempnam.c"
2145 fi
2146
2147 dnl ----------------------------------------------------------------
2148 # Check Configuration
2149 OL_SYS_ERRLIST
2150
2151 dnl ----------------------------------------------------------------
2152 dnl Sort out defines
2153
2154 if test "$ol_enable_debug" != no ; then
2155         AC_DEFINE(LDAP_DEBUG,1,
2156                 [define this to add debugging code])
2157 fi
2158 if test "$ol_enable_syslog" = yes ; then
2159         AC_DEFINE(LDAP_SYSLOG,1,
2160                 [define this to add syslog code])
2161 fi
2162 if test "$ol_enable_libui" = yes ; then
2163         AC_DEFINE(LDAP_LIBUI,1,
2164                 [define this for LDAP User Interface support])
2165 fi
2166 if test "$ol_enable_cache" = no ; then
2167         AC_DEFINE(LDAP_NOCACHE,1,
2168                 [define this to remove -lldap cache support])
2169 fi
2170 if test "$ol_link_kbind" != no ; then
2171         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2172 fi
2173 if test "$ol_enable_dns" != no ; then
2174         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
2175 fi
2176 if test "$ol_enable_proctitle" != no ; then
2177         AC_DEFINE(LDAP_PROCTITLE,1,
2178                 [define this for LDAP process title support])
2179 fi
2180 if test "$ol_enable_referrals" != no ; then
2181         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2182 fi
2183 if test "$ol_enable_cldap" != no ; then
2184         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2185 fi
2186 if test "$ol_enable_ldapi" != no; then
2187         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2188 fi
2189
2190 if test "$ol_enable_cleartext" != no ; then
2191         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2192 fi
2193 if test "$ol_enable_crypt" != no ; then
2194         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2195 fi
2196 if test "$ol_link_kpasswd" != no ; then
2197         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2198 fi
2199 if test "$ol_enable_multimaster" != no ; then
2200         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2201 fi
2202 if test "$ol_enable_phonetic" != no ; then
2203         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2204 fi
2205 if test "$ol_enable_rlookups" != no ; then
2206         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2207 fi
2208 if test "$ol_enable_aci" != no ; then
2209         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2210 fi
2211 if test "$ol_enable_discreteaci" != no ; then
2212         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
2213 fi
2214
2215 if test "$ol_link_modules" != no ; then
2216         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2217         BUILD_SLAPD=yes
2218         SLAPD_MODULES_LDFLAGS="-dlopen self"
2219 fi
2220
2221 if test "$ol_link_bdb2" != no ; then
2222         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2223         BUILD_SLAPD=yes
2224         BUILD_BDB2=yes
2225         if test "$ol_with_bdb2_module" != static ; then
2226                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2227                         [define to support dynamic BDB2 backend])
2228                 BUILD_BDB2=mod
2229                 BUILD_BDB2_DYNAMIC=shared
2230                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2231         fi
2232 fi
2233
2234 if test "$ol_enable_ldap" != no ; then
2235         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2236         BUILD_SLAPD=yes
2237         BUILD_LDAP=yes
2238         if test "$ol_with_ldap_module" != static ; then
2239                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2240                         [define to support dynamic LDAP backend])
2241                 BUILD_LDAP=mod
2242                 BUILD_LDAP_DYNAMIC=shared
2243                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2244         fi
2245 fi
2246
2247 if test "$ol_link_ldbm" != no ; then
2248         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2249         BUILD_SLAPD=yes
2250         BUILD_LDBM=yes
2251         if test "$ol_with_ldbm_module" != static ; then
2252                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2253                         [define to support dynamic LDBM backend])
2254                 BUILD_LDBM=mod
2255                 BUILD_LDBM_DYNAMIC=shared
2256                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2257         fi
2258 fi
2259
2260 if test "$ol_enable_passwd" != no ; then
2261         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2262         BUILD_SLAPD=yes
2263         BUILD_PASSWD=yes
2264         if test "$ol_with_passwd_module" != static ; then
2265                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2266                         [define to support dynamic PASSWD backend])
2267                 BUILD_PASSWD=mod
2268                 BUILD_PASSWD_DYNAMIC=shared
2269                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2270         fi
2271 fi
2272
2273 if test "$ol_link_perl" != no ; then
2274         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2275         BUILD_SLAPD=yes
2276         BUILD_PERL=yes
2277         if test "$ol_with_perl_module" != static ; then
2278                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2279                         [define to support dynamic PERL backend])
2280                 BUILD_PERL=mod
2281                 BUILD_PERL_DYNAMIC=shared
2282                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2283         fi
2284 fi
2285
2286 if test "$ol_enable_shell" != no ; then
2287         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2288         BUILD_SLAPD=yes
2289         BUILD_SHELL=yes
2290         if test "$ol_with_shell_module" != static ; then
2291                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2292                         [define to support dynamic SHELL backend])
2293                 BUILD_SHELL=mod
2294                 BUILD_SHELL_DYNAMIC=shared
2295                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2296         fi
2297 fi
2298
2299 if test "$ol_enable_tcl" != no ; then
2300         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2301         BUILD_SLAPD=yes
2302         BUILD_TCL=yes
2303         if test "$ol_with_tcl_module" != static; then
2304                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2305                         [define to support dynamic TCL backend])
2306                 BUILD_TCL=mod
2307                 BUILD_TCL_DYNAMIC=shared
2308                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2309         fi
2310 fi
2311
2312 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2313         $BUILD_SLAPD = yes ; then
2314         BUILD_SLURPD=yes
2315 fi
2316
2317 if test "$ol_link_isode" != no ; then
2318         BUILD_LDAPD=yes
2319 fi
2320
2321 dnl ----------------------------------------------------------------
2322
2323 if test "$LINK_BINS_DYNAMIC" = yes; then
2324     LIB_LINKAGE=DYN
2325     LT_LIB_LINKAGE=shared
2326 else
2327     LIB_LINKAGE=STAT
2328     LT_LIB_LINKAGE=static
2329 fi
2330
2331 if test "$ac_cv_mingw32" = yes ; then
2332     PLAT=NT
2333     DYN_EXT=dll
2334 else
2335     PLAT=UNIX
2336     DYN_EXT=so
2337 fi
2338
2339 AC_SUBST(LIBSRCS)
2340
2341 AC_SUBST(PLAT)
2342 AC_SUBST(LIB_LINKAGE)
2343 AC_SUBST(LT_LIB_LINKAGE)
2344 AC_SUBST(DYN_EXT)
2345
2346 AC_SUBST(BUILD_LDAPD)
2347 AC_SUBST(BUILD_SLAPD)
2348   AC_SUBST(BUILD_BDB2)
2349   AC_SUBST(BUILD_LDAP)
2350   AC_SUBST(BUILD_LDBM)
2351   AC_SUBST(BUILD_PASSWD)
2352   AC_SUBST(BUILD_PERL)
2353   AC_SUBST(BUILD_QUIPU)
2354   AC_SUBST(BUILD_SHELL)
2355   AC_SUBST(BUILD_TCL)
2356   AC_SUBST(BUILD_BDB2_DYNAMIC)
2357   AC_SUBST(BUILD_LDAP_DYNAMIC)
2358   AC_SUBST(BUILD_LDBM_DYNAMIC)
2359   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2360   AC_SUBST(BUILD_PERL_DYNAMIC)
2361   AC_SUBST(BUILD_SHELL_DYNAMIC)
2362   AC_SUBST(BUILD_TCL_DYNAMIC)
2363 AC_SUBST(BUILD_SLURPD)
2364
2365 AC_SUBST(LDAP_LIBS)
2366 AC_SUBST(LDAPD_LIBS)
2367 AC_SUBST(LDIF_LIBS)
2368 AC_SUBST(SLAPD_LIBS)
2369 AC_SUBST(SLURPD_LIBS)
2370 AC_SUBST(LDBM_LIBS)
2371 AC_SUBST(LTHREAD_LIBS)
2372 AC_SUBST(LUTIL_LIBS)
2373 AC_SUBST(WRAP_LIBS)
2374 AC_SUBST(MOD_TCL_LIB)
2375 AC_SUBST(LINK_BINS_DYNAMIC)
2376
2377 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2378 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2379 AC_SUBST(SLAPD_MODULES_LIST)
2380
2381 AC_SUBST(PERL_CPPFLAGS)
2382 AC_SUBST(SLAPD_PERL_LDFLAGS)
2383 AC_SUBST(MOD_PERL_LDFLAGS)
2384
2385 AC_SUBST(KRB4_LIBS)
2386 AC_SUBST(KRB5_LIBS)
2387 AC_SUBST(READLINE_LIBS)
2388 AC_SUBST(SASL_LIBS)
2389 AC_SUBST(TERMCAP_LIBS)
2390 AC_SUBST(TLS_LIBS)
2391 AC_SUBST(MODULES_LIBS)
2392
2393 dnl ----------------------------------------------------------------
2394 dnl final output
2395 dnl
2396
2397 AC_OUTPUT( \
2398 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2399 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2400 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2401 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2402 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2403 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2404 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2405 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2406 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2407 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2408 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2409 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2410 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2411 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2412 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2413 include/Makefile:build/top.mk:include/Makefile.in \
2414 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2415 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2416 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2417 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2418 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2419 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2420 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2421 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2422 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2423 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2424 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2425 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2426 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2427 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2428 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2429 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2430 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2431 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2432 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2433 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2434 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2435 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2436 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2437 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2438 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2439 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2440 ,[
2441 date > stamp-h
2442 echo Please \"make depend\" to build dependencies
2443 ])