git.sur5r.net Git - bacula/bacula/blob - regress/win32/scripts/install_bacula.cmd

   1 REM Arguments:
   2 REM    1 = Debug or Release
   3 REM    2 = email address
   4 REM    3 = mail server
   5 REM    4 = tape device
   6 REM    5 = changer device or nul
   7 REM    6 = tape1 device or nul
   8
   9 SETLOCAL ENABLEDELAYEDEXPANSION
  10
  11 SET CATS=create_sqlite3_database.cmd drop_sqlite3_database.cmd drop_sqlite3_tables.cmd grant_sqlite3_privileges.cmd make_sqlite3_catalog_backup.cmd make_sqlite3_tables.cmd
  12
  13 SET CONFS=bacula-dir.conf.in bacula-fd.conf.in bacula-sd.conf.in bconsole.conf.in
  14
  15 CALL scripts\bacula stop
  16
  17 IF NOT EXIST bin MKDIR bin
  18
  19 COPY build\src\win32\installer\%1\*.exe bin >nul
  20 COPY build\src\win32\installer\%1\*.dll bin >nul
  21 COPY build\src\win32\installer\%1\*.manifest bin >nul
  22 COPY build\src\win32\%1\*.pdb bin >nul
  23 COPY build\src\win32\installer\%1\query.sql bin >nul
  24
  25 COPY bin\cats_sqlite3.dll bin\bacula_cats3.dll >nul
  26
  27 FOR /f %%i IN ( 'cmd /c openssl.exe rand -base64 33 2^>nul' ) DO SET CLIENT_PASSWORD=%%i
  28 FOR /f %%i IN ( 'cmd /c openssl.exe rand -base64 33 2^>nul' ) DO SET STORAGE_PASSWORD=%%i
  29 FOR /f %%i IN ( 'cmd /c openssl.exe rand -base64 33 2^>nul' ) DO SET DIRECTOR_PASSWORD=%%i
  30 FOR /f %%i IN ( 'cmd /c openssl.exe rand -base64 33 2^>nul' ) DO SET MONITOR_PASSWORD=%%i
  31
  32 ECHO s;@director_name@;localhost-dir;g >install.sed
  33 ECHO s;@director_port@;8101;g >>install.sed
  34 ECHO s;@storage_name@;localhost-sd;g >>install.sed
  35 ECHO s;@storage_port@;8103;g >>install.sed
  36 ECHO s;@client_name@;localhost-fd;g >>install.sed
  37 ECHO s;@client_port@;8102;g >>install.sed
  38
  39 REM ECHO s;@DISTVER@;$R2;
  40
  41 ECHO s;@working_dir@;%CD:\=\\\\%\\\\working;g >>install.sed
  42 ECHO s;@working_dir_cmd@;%CD:\=\\%\\working;g >>install.sed
  43 ECHO s;@bin_dir@;%CD:\=\\\\%\\\\bin;g >>install.sed;
  44 ECHO s;@bin_dir_cmd@;%CD:\=\\%\\bin;g >>install.sed
  45 ECHO s;@BUILD_DIR@;%CD:\=/%/build;g >>install.sed
  46 ECHO s;@director_address@;localhost;g >>install.sed
  47 ECHO s;@client_address@;localhost;g >>install.sed
  48 ECHO s;@storage_address@;localhost;g >>install.sed
  49 ECHO s;@client_maxjobs@;2;g >>install.sed
  50 ECHO s;@client_password@;%CLIENT_PASSWORD%;g >>install.sed
  51 ECHO s;@storage_maxjobs@;10;g >>install.sed
  52 ECHO s;@storage_password@;%STORAGE_PASSWORD%;g >>install.sed
  53 ECHO s;@director_maxjobs@;1;g >>install.sed
  54 ECHO s;@director_password@;%DIRECTOR_PASSWORD%;g >>install.sed
  55 ECHO s;@job_email@;%2;g >>install.sed
  56 ECHO s;@smtp_host@;%3;g >>install.sed
  57 ECHO s;@monitor_name@;localhost-mon;g >>install.sed
  58 ECHO s;@monitor_password@;%MONITOR_PASSWORD%;g >>install.sed
  59 ECHO s;@tape_drive@;%4;g >>install.sed
  60 ECHO s;@autochanger@;%5;g >>install.sed
  61 ECHO s;@changer_path@;%6;g >>install.sed
  62 ECHO s;@tape_drive1@;%7;g >>install.sed
  63
  64 FOR %%i in ( %CATS% ) DO (
  65    SET NAME=%%i
  66    SET TARGET=bin\!NAME:sqlite3=bacula!
  67    tools\sed -f install.sed build\src\win32\installer\%1\!NAME! > !TARGET!
  68 )
  69
  70 FOR %%i in ( %CONFS% ) DO tools\sed -f install.sed build\src\win32\installer\%%i > bin\%%~ni
  71
  72 tools\sed -f install.sed build\src\win32\installer\%1\make_sqlite3_tables.sql > bin\make_sqlite3_tables.sql
  73 tools\sed -f install.sed build\src\win32\installer\%1\mtx-changer.cmd > bin\mtx-changer.cmd
  74
  75 CALL scripts\bacula uninstall
  76 CALL scripts\bacula install %CD%\bin