git.sur5r.net Git - cc65/blob - libsrc/vic20/joy/vic20-stdjoy.s

   1 ;
   2 ; Standard joystick driver for the VIC20. May be used multiple times when linked
   3 ; to the statically application.
   4 ;
   5 ; Ullrich von Bassewitz, 2002-12-20
   6 ; Using code from Steve Schmidtke
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "vic20.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "JUMPTABLE"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Button state masks (8 values)
  29
  30         .byte   $02                     ; JOY_UP
  31         .byte   $04                     ; JOY_DOWN
  32         .byte   $08                     ; JOY_LEFT
  33         .byte   $80                     ; JOY_RIGHT
  34         .byte   $10                     ; JOY_FIRE
  35         .byte   $00                     ; JOY_FIRE2 unavailable
  36         .byte   $00                     ; Future expansion
  37         .byte   $00                     ; Future expansion
  38
  39 ; Jump table.
  40
  41         .addr   INSTALL
  42         .addr   UNINSTALL
  43         .addr   COUNT
  44         .addr   READ
  45         .addr   0                       ; IRQ entry unused
  46
  47 ; ------------------------------------------------------------------------
  48 ; Constants
  49
  50 JOY_COUNT       = 1             ; Number of joysticks we support
  51
  52
  53 ; ------------------------------------------------------------------------
  54 ; Data.
  55
  56
  57 .code
  58
  59 ; ------------------------------------------------------------------------
  60 ; INSTALL routine. Is called after the driver is loaded into memory. If
  61 ; possible, check if the hardware is present and determine the amount of
  62 ; memory available.
  63 ; Must return an JOY_ERR_xx code in a/x.
  64 ;
  65
  66 INSTALL:
  67         lda     #<JOY_ERR_OK
  68         ldx     #>JOY_ERR_OK
  69 ;       rts                     ; Run into UNINSTALL instead
  70
  71 ; ------------------------------------------------------------------------
  72 ; UNINSTALL routine. Is called before the driver is removed from memory.
  73 ; Can do cleanup or whatever. Must not return anything.
  74 ;
  75
  76 UNINSTALL:
  77         rts
  78
  79
  80 ; ------------------------------------------------------------------------
  81 ; COUNT: Return the total number of available joysticks in a/x.
  82 ;
  83
  84 COUNT:
  85         lda     #<JOY_COUNT
  86         ldx     #>JOY_COUNT
  87         rts
  88
  89 ; ------------------------------------------------------------------------
  90 ; READ: Read a particular joystick passed in A.
  91 ; The current implemenation will ignore the joystick number because we do only
  92 ; have one joystick
  93
  94 READ:   lda     #$7F            ; mask for VIA2 JOYBIT: sw3
  95         ldx     #$C3            ; mask for VIA1 JOYBITS: sw0,sw1,sw2,sw4
  96         sei                     ; necessary?
  97
  98         ldy     VIA2_DDRB       ; remember the date of DDRB
  99         sta     VIA2_DDRB       ; set JOYBITS on this VIA for input
 100         lda     VIA2_JOY        ; read JOYBIT: sw3
 101         sty     VIA2_DDRB       ; restore the state of DDRB
 102         asl                     ; Shift sw3 into carry
 103
 104         ldy     VIA1_DDRA       ; remember the state of DDRA
 105         stx     VIA1_DDRA       ; set JOYBITS on this VIA for input
 106         lda     VIA1_JOY        ; read JOYBITS: sw0,sw1,sw2,sw4
 107         sty     VIA1_DDRA       ; restore the state of DDRA
 108
 109         cli                     ; necessary?
 110         ror                     ; Shift sw3 into bit 7
 111         and     #$9E            ; Mask relevant bits
 112         eor     #$9E            ; Active states are inverted
 113
 114         rts
 115
 116