git.sur5r.net Git - glabels/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.63)
   4
   5 AC_INIT([glabels],[2.3.pre0svn],[http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116])
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7
   8 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   9
  10 AM_MAINTAINER_MODE
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  12
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 IT_PROG_INTLTOOL([0.21])
  16
  17 PKG_PROG_PKG_CONFIG
  18
  19 LT_INIT
  20
  21 GNOME_DOC_INIT
  22 GTK_DOC_CHECK(1.0)
  23
  24 AC_SEARCH_LIBS([strerror],[cposix])
  25 AC_PROG_CC
  26 AC_PROG_INSTALL
  27
  28 GNOME_COMPILE_WARNINGS
  29
  30 AC_PATH_PROG(GLIB_GENMARSHAL,         glib-genmarshal)
  31 AC_PATH_PROG(GDK_PIXBUF_CSOURCE,      gdk-pixbuf-csource)
  32 AC_PATH_PROG(UPDATE_MIME_DATABASE,    update-mime-database)
  33 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database)
  34
  35 dnl ---------------------------------------------------------------------------
  36 dnl - GLABELS branch
  37 dnl ---------------------------------------------------------------------------
  38 GLABELS_BRANCH=glabels-3.0
  39 AC_SUBST(GLABELS_BRANCH)
  40
  41 dnl ---------------------------------------------------------------------------
  42 dnl - LIBGLABELS branch
  43 dnl ---------------------------------------------------------------------------
  44 LIBGLABELS_BRANCH=libglabels-3.0
  45 AC_SUBST(LIBGLABELS_BRANCH)
  46
  47 dnl ---------------------------------------------------------------------------
  48 dnl - LIBGLABELS API versioning
  49 dnl ---------------------------------------------------------------------------
  50 dnl From the libtool manual:
  51 dnl 1. Start with version information of `0:0:0' for each libtool library.
  52 dnl 2. Update the version information only immediately before a public release.
  53 dnl    More frequent updates are unnecessary, and only guarantee that the current
  54 dnl    interface number gets larger faster.
  55 dnl 3. If the library source code has changed at all since the last update, then increment
  56 dnl    revision (`c:r:a' becomes `c:r+1:a').
  57 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  58 dnl    increment current, and set revision to 0.
  59 dnl 5. If any interfaces have been added since the last public release, then increment age.
  60 dnl 6. If any interfaces have been removed since the last public release, then set age
  61 dnl    to 0.
  62 LIBGLABELS_C=7
  63 LIBGLABELS_R=0
  64 LIBGLABELS_A=0
  65
  66 LIBGLABELS_API_VERSION=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  67 AC_SUBST(LIBGLABELS_API_VERSION)
  68
  69 dnl ---------------------------------------------------------------------------
  70 dnl - Library dependencies
  71 dnl ---------------------------------------------------------------------------
  72 dnl Required dependencies
  73 GLIB_REQUIRED=2.22.0
  74 GTK_REQUIRED=2.18.0
  75 GCONF_REQUIRED=2.28.0
  76 LIBXML_REQUIRED=2.7.0
  77
  78 dnl Optional dependencies
  79 LIBEBOOK_REQUIRED=2.28.0
  80 LIBBARCODE_REQUIRED=0.98
  81 LIBQRENCODE_REQUIRED=3.1.0
  82 LIBIEC16022_REQUIRED=0.2.4
  83
  84 dnl Make above strings available for packaging files (e.g. rpm spec files)
  85 AC_SUBST(GLIB_REQUIRED)
  86 AC_SUBST(GTK_REQUIRED)
  87 AC_SUBST(GCONF_REQUIRED)
  88 AC_SUBST(LIBXML_REQUIRED)
  89 AC_SUBST(LIBEBOOK_REQUIRED)
  90 AC_SUBST(LIBBARCODE_REQUIRED)
  91 AC_SUBST(LIBQRENCODE_REQUIRED)
  92 AC_SUBST(LIBIEC16022_REQUIRED)
  93
  94
  95 dnl ---------------------------------------------------------------------------
  96 dnl - GLABELS prerequisites
  97 dnl ---------------------------------------------------------------------------
  98 PKG_CHECK_MODULES(GLABELS, [\
  99         glib-2.0 >= $GLIB_REQUIRED \
 100         gtk+-2.0 >= $GTK_REQUIRED \
 101         gconf-2.0 >= $GCONF_REQUIRED \
 102         libxml-2.0 >= $LIBXML_REQUIRED \
 103 ])
 104
 105 AC_SUBST(GLABELS_CFLAGS)
 106 AC_SUBST(GLABELS_LIBS)
 107
 108
 109 dnl ---------------------------------------------------------------------------
 110 dnl - LIBGLABELS more modest prerequisites
 111 dnl ---------------------------------------------------------------------------
 112 PKG_CHECK_MODULES(LIBGLABELS, [\
 113         glib-2.0 >= $GLIB_REQUIRED \
 114         gconf-2.0 >= $GCONF_REQUIRED \
 115         libxml-2.0 >= $LIBXML_REQUIRED \
 116 ])
 117
 118 AC_SUBST(LIBGLABELS_CFLAGS)
 119 AC_SUBST(LIBGLABELS_LIBS)
 120
 121
 122 dnl ---------------------------------------------------------------------------
 123 dnl - Check for optional evolution data server
 124 dnl ---------------------------------------------------------------------------
 125 AC_ARG_WITH(libebook,
 126             [AS_HELP_STRING([--without-libebook],[build without Evolution Data Server support])])
 127 have_libebook=no
 128 if test "x$with_libebook" != xno; then
 129         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
 130                           [have_libebook=yes], [have_libebook=no])
 131 fi
 132
 133 if test "x$have_libebook" = "xyes"; then
 134         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
 135         AC_SUBST(LIBEBOOK_CFLAGS)
 136         AC_SUBST(LIBEBOOK_LIBS)
 137 fi
 138
 139
 140 dnl ---------------------------------------------------------------------------
 141 dnl - Check for optional GNU Barcode backend
 142 dnl ---------------------------------------------------------------------------
 143 AC_ARG_WITH(libbarcode,
 144             [AS_HELP_STRING([--without-libbarcode],[build without GNU Barcode support])])
 145 have_libbarcode=no
 146 if test "x$with_libbarcode" != xno; then
 147    AC_CHECK_LIB(barcode, Barcode_Create,
 148                 [have_libbarcode=yes], [have_libbarcode=no])
 149 fi
 150
 151 if test "x$have_libbarcode" = "xyes"; then
 152         AC_DEFINE(HAVE_LIBBARCODE,1,[Define to 1 for GNU Barcode support])
 153         LIBBARCODE_CFLAGS=""
 154         LIBBARCODE_LIBS="-lbarcode"
 155         AC_SUBST(LIBBARCODE_CFLAGS)
 156         AC_SUBST(LIBBARCODE_LIBS)
 157 else
 158         help_libbarcode="(See http://www.gnu.org/software/barcode/barcode.html)"
 159 fi
 160
 161
 162 dnl ---------------------------------------------------------------------------
 163 dnl - Check for optional QRencode Barcode backend
 164 dnl ---------------------------------------------------------------------------
 165 AC_ARG_WITH(libqrencode,
 166             [AS_HELP_STRING([--without-libqrencode],[build without QR code support])])
 167 have_libqrencode=no
 168 if test "x$with_libqrencode" != xno; then
 169         PKG_CHECK_MODULES(LIBQRENCODE, libqrencode >= $LIBQRENCODE_REQUIRED,
 170                           [have_libqrencode=yes], [have_libqrencode=no])
 171 fi
 172
 173 if test "x$have_libqrencode" = "xyes"; then
 174         AC_DEFINE(HAVE_LIBQRENCODE,1,[Define to 1 for QR code support])
 175         AC_SUBST(LIBQRENCODE_CFLAGS)
 176         AC_SUBST(LIBQRENCODE_LIBS)
 177 else
 178         help_libqrencode="(See http://megaui.net/fukuchi/works/qrencode/index.en.html)"
 179 fi
 180
 181
 182 dnl ---------------------------------------------------------------------------
 183 dnl - Check for IEC16022 Barcode backend
 184 dnl ---------------------------------------------------------------------------
 185 AC_ARG_WITH(libiec16022,
 186             [AS_HELP_STRING([--without-libiec16022],[build without IEC 16022 support])])
 187 have_libiec16022=no
 188 if test "x$with_libiec16022" != xno; then
 189         PKG_CHECK_MODULES(LIBIEC16022, libiec16022 >= $LIBIEC16022_REQUIRED,
 190                           [have_libiec16022=yes], [have_libiec16022=no])
 191 fi
 192
 193 if test "x$have_libiec16022" = "xyes"; then
 194         AC_DEFINE(HAVE_LIBIEC16022,1,[Define to 1 for IEC 16022 support])
 195         AC_SUBST(LIBIEC16022_CFLAGS)
 196         AC_SUBST(LIBIEC16022_LIBS)
 197 else
 198         help_libiec16022="(See http://datenfreihafen.org/projects/iec16022.html)"
 199 fi
 200
 201
 202 dnl ---------------------------------------------------------------------------
 203 dnl - Enable deprecation testing
 204 dnl ---------------------------------------------------------------------------
 205 AC_ARG_ENABLE(deprecations,
 206               [AS_HELP_STRING([--enable-deprecations],[warn about deprecated usages [default=no]])],,
 207               [enable_deprecations=no])
 208
 209 if test "x$enable_deprecations" = "xyes"; then
 210    DISABLE_DEPRECATED_CFLAGS="\
 211 -DG_DISABLE_DEPRECATED \
 212 -DGDK_DISABLE_DEPRECATED \
 213 -DGTK_DISABLE_DEPRECATED \
 214 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 215 "
 216    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 217 fi
 218
 219
 220 dnl ---------------------------------------------------------------------------
 221 dnl - Disable updating of mime and desktop databases
 222 dnl ---------------------------------------------------------------------------
 223 AC_ARG_ENABLE(update-mimedb, AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]]),,
 224               enable_update_mimedb=yes)
 225 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 226
 227 AC_ARG_ENABLE(update-desktopdb, AS_HELP_STRING([--disable-update-desktopdb],[disable the update-desktop-database after install [default=no]]),,
 228               enable_update_desktopdb=yes)
 229 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 230
 231
 232 dnl ---------------------------------------------------------------------------
 233 dnl - i18n support
 234 dnl ---------------------------------------------------------------------------
 235 GETTEXT_PACKAGE=glabels
 236 AC_SUBST(GETTEXT_PACKAGE)
 237 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 238
 239 AM_GLIB_GNU_GETTEXT
 240
 241
 242 dnl ---------------------------------------------------------------------------
 243 dnl - Makefiles, etc.
 244 dnl ---------------------------------------------------------------------------
 245 AC_CONFIG_FILES([
 246 Makefile
 247 libglabels/Makefile
 248 libglabels/${LIBGLABELS_BRANCH}.pc
 249 src/Makefile
 250 src/pixmaps/Makefile
 251 src/stock-pixmaps/Makefile
 252 data/Makefile
 253 data/pixmaps/Makefile
 254 data/mime/Makefile
 255 data/builder/Makefile
 256 data/desktop/Makefile
 257 data/man/Makefile
 258 templates/Makefile
 259 po/Makefile.in
 260 help/Makefile
 261 docs/Makefile
 262 docs/libglabels/Makefile
 263 glabels.spec
 264 ])
 265 AC_OUTPUT
 266
 267
 268 dnl ---------------------------------------------------------------------------
 269 dnl - Print configuration information
 270 dnl ---------------------------------------------------------------------------
 271 echo "
 272
 273 Configuration:
 274
 275         Package ................. ${PACKAGE}-${VERSION}
 276         Installation prefix ..... ${prefix}
 277         Source code location .... ${srcdir}
 278         Compiler ................ ${CC}
 279
 280
 281 Optional data merge backends:
 282
 283         Evolution Data Server ... ${have_libebook}
 284
 285
 286 Optional barcode backends:
 287
 288         GNU Barcode ............. ${have_libbarcode} ${help_libbarcode}
 289         QR Code ................. ${have_libqrencode} ${help_libqrencode}
 290         IEC 16022 ............... ${have_libiec16022} ${help_libiec16022}
 291
 292
 293 "
 294
 295
 296 cat ${srcdir}/MESSAGE-OF-DOOM
 297