git.sur5r.net Git - glabels/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.2.8, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8 GNOME_DOC_INIT
   9
  10 AM_MAINTAINER_MODE
  11 AM_CONFIG_HEADER(config.h)
  12
  13 AC_PROG_INTLTOOL([0.21])
  14 PKG_PROG_PKG_CONFIG
  15
  16 AM_PROG_LIBTOOL
  17
  18 AC_ISC_POSIX
  19 AC_PROG_CC
  20 AM_PROG_CC_STDC
  21 AC_HEADER_STDC
  22
  23 GNOME_COMPILE_WARNINGS
  24
  25 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  26
  27 GTK_DOC_CHECK(1.0)
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl - LIBGLABELS API versioning
  31 dnl ---------------------------------------------------------------------------
  32 dnl From the libtool manual:
  33 dnl 1. Start with version information of `0:0:0' for each libtool library.
  34 dnl 2. Update the version information only immediately before a public release.
  35 dnl    More frequent updates are unnecessary, and only guarantee that the current
  36 dnl    interface number gets larger faster.
  37 dnl 3. If the library source code has changed at all since the last update, then increment
  38 dnl    revision (`c:r:a' becomes `c:r+1:a').
  39 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  40 dnl    increment current, and set revision to 0.
  41 dnl 5. If any interfaces have been added since the last public release, then increment age.
  42 dnl 6. If any interfaces have been removed since the last public release, then set age
  43 dnl    to 0.
  44 LIBGLABELS_C=6
  45 LIBGLABELS_R=2
  46 LIBGLABELS_A=1
  47
  48 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  49 AC_SUBST(LIBGLABELS_VERSION_INFO)
  50
  51
  52 dnl ---------------------------------------------------------------------------
  53 dnl - Library dependencies
  54 dnl ---------------------------------------------------------------------------
  55 GLIB_REQUIRED=2.12.0
  56 GTK_REQUIRED=2.10.0
  57 LIBGNOME_REQUIRED=2.16.0
  58 LIBGNOMEUI_REQUIRED=2.16.0
  59 LIBXML_REQUIRED=2.6.0
  60 LIBGLADE_REQUIRED=2.6.0
  61 LIBEBOOK_REQUIRED=1.8.0
  62
  63 dnl Make above strings available for packaging files (e.g. rpm spec files)
  64 AC_SUBST(GLIB_REQUIRED)
  65 AC_SUBST(GTK_REQUIRED)
  66 AC_SUBST(LIBGNOME_REQUIRED)
  67 AC_SUBST(LIBGNOMEUI_REQUIRED)
  68 AC_SUBST(LIBXML_REQUIRED)
  69 AC_SUBST(LIBGLADE_REQUIRED)
  70 AC_SUBST(LIBEBOOK_REQUIRED)
  71
  72
  73 dnl ---------------------------------------------------------------------------
  74 dnl - Check for evolution data server
  75 dnl ---------------------------------------------------------------------------
  76 AC_ARG_WITH(libebook,
  77             [AC_HELP_STRING([--without-libebook],
  78                             [build without Evolution Data Server support])])
  79 have_libebook=no
  80 if test "x$with_libebook" != xno; then
  81         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  82                           [have_libebook=yes], [have_libebook=no])
  83 fi
  84
  85 if test "x$have_libebook" = "xyes"; then
  86         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  87         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  88 fi
  89
  90
  91 dnl ---------------------------------------------------------------------------
  92 dnl - GLABELS prerequisites
  93 dnl ---------------------------------------------------------------------------
  94 PKG_CHECK_MODULES(GLABELS, \
  95 glib-2.0 >= $GLIB_REQUIRED \
  96 gtk+-2.0 >= $GTK_REQUIRED \
  97 libgnome-2.0 >= $LIBGNOME_REQUIRED \
  98 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
  99 libxml-2.0 >= $LIBXML_REQUIRED \
 100 libglade-2.0 >= $LIBGLADE_REQUIRED \
 101 $OPTIONAL_MODULES \
 102 )
 103
 104 AC_SUBST(GLABELS_CFLAGS)
 105 AC_SUBST(GLABELS_LIBS)
 106
 107
 108 dnl ---------------------------------------------------------------------------
 109 dnl - LIBGLABELS more modest prerequisites
 110 dnl ---------------------------------------------------------------------------
 111 PKG_CHECK_MODULES(LIBGLABELS, \
 112 glib-2.0 >= $GLIB_REQUIRED \
 113 libxml-2.0 >= $LIBXML_REQUIRED \
 114 )
 115
 116 AC_SUBST(LIBGLABELS_CFLAGS)
 117 AC_SUBST(LIBGLABELS_LIBS)
 118
 119
 120 dnl ---------------------------------------------------------------------------
 121 dnl - MYGAL prerequisites
 122 dnl ---------------------------------------------------------------------------
 123 PKG_CHECK_MODULES(MYGAL, \
 124 gtk+-2.0 >= $GTK_REQUIRED \
 125 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
 126 )
 127
 128 AC_SUBST(MYGAL_CFLAGS)
 129 AC_SUBST(MYGAL_LIBS)
 130
 131
 132 dnl ---------------------------------------------------------------------------
 133 dnl - Is XML_PARSE_HUGE available?
 134 dnl ---------------------------------------------------------------------------
 135 PKG_CHECK_MODULES(XML_PARSE_HUGE, libxml-2.0 >= 2.7.0,
 136                   HAVE_XML_PARSE_HUGE="-DHAVE_XML_PARSE_HUGE",
 137                   HAVE_XML_PARSE_HUGE="-UHAVE_XML_PARSE_HUGE")
 138 AC_SUBST(HAVE_XML_PARSE_HUGE)
 139
 140
 141 dnl ---------------------------------------------------------------------------
 142 dnl - Enable deprecation testing
 143 dnl ---------------------------------------------------------------------------
 144 AC_ARG_ENABLE(deprecations,
 145               [AC_HELP_STRING([--enable-deprecations],
 146                               [warn about deprecated usages [default=no]])],,
 147               [enable_deprecations=no])
 148
 149 if test "x$enable_deprecations" = "xyes"; then
 150    DISABLE_DEPRECATED_CFLAGS="\
 151 -DG_DISABLE_DEPRECATED \
 152 -DGDK_DISABLE_DEPRECATED \
 153 -DGTK_DISABLE_DEPRECATED \
 154 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 155 -DGNOME_DISABLE_DEPRECATED \
 156 -DLIBGLADE_DISABLE_DEPRECATED"
 157    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 158 fi
 159
 160
 161 dnl ---------------------------------------------------------------------------
 162 dnl - Is freedesktop mime dbase available?
 163 dnl ---------------------------------------------------------------------------
 164 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 165 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 166
 167 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 168 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 169
 170 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 171               [disable the update-mime-database after install [default=no]]),,
 172               enable_update_mimedb=yes)
 173 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 174
 175 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 176               [disable the update-desktop-database after install [default=no]]),,
 177               enable_update_desktopdb=yes)
 178 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 179
 180
 181 dnl ---------------------------------------------------------------------------
 182 dnl - Supported languages
 183 dnl ---------------------------------------------------------------------------
 184 GETTEXT_PACKAGE=glabels
 185 AC_SUBST(GETTEXT_PACKAGE)
 186 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 187
 188 AM_GLIB_GNU_GETTEXT
 189
 190
 191 dnl ---------------------------------------------------------------------------
 192 dnl - Makefiles, etc.
 193 dnl ---------------------------------------------------------------------------
 194 AC_OUTPUT([
 195 Makefile
 196 barcode-0.98/Makefile
 197 iec16022-0.2.1/Makefile
 198 libglabels/Makefile
 199 libglabels/libglabels.pc
 200 src/Makefile
 201 src/pixmaps/Makefile
 202 src/stock-pixmaps/Makefile
 203 src/mygal/Makefile
 204 data/Makefile
 205 data/templates/Makefile
 206 data/pixmaps/Makefile
 207 data/mime/Makefile
 208 data/glade/Makefile
 209 data/desktop/Makefile
 210 data/dtd/Makefile
 211 data/man/Makefile
 212 po/Makefile.in
 213 help/Makefile
 214 docs/Makefile
 215 docs/libglabels/Makefile
 216 glabels.spec
 217 ])
 218
 219
 220 dnl ---------------------------------------------------------------------------
 221 dnl - Print configuration information
 222 dnl ---------------------------------------------------------------------------
 223 echo "
 224 Configuration:
 225
 226         Package:                        ${PACKAGE}-${VERSION}:
 227         Installation prefix             ${prefix}
 228         Source code location:           ${srcdir}
 229         Compiler:                       ${CC}
 230         Evolution Data Server support:  ${have_libebook}
 231
 232 "
 233
 234 dnl cat ${srcdir}/MESSAGE-OF-DOOM