git.sur5r.net Git - glabels/blob - glabels2/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8 GNOME_DOC_INIT
   9
  10 AM_MAINTAINER_MODE
  11 AM_CONFIG_HEADER(config.h)
  12
  13 AC_PROG_INTLTOOL([0.21])
  14 PKG_PROG_PKG_CONFIG
  15
  16 AM_PROG_LIBTOOL
  17
  18 AC_ISC_POSIX
  19 AC_PROG_CC
  20 AM_PROG_CC_STDC
  21 AC_HEADER_STDC
  22
  23 GNOME_COMPILE_WARNINGS
  24
  25 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  26 AC_PATH_PROG(GTK_BUILDER_CONVERT, gtk-builder-convert)
  27
  28 GTK_DOC_CHECK(1.0)
  29
  30 dnl ---------------------------------------------------------------------------
  31 dnl - LIBGLABELS API versioning
  32 dnl ---------------------------------------------------------------------------
  33 dnl From the libtool manual:
  34 dnl 1. Start with version information of `0:0:0' for each libtool library.
  35 dnl 2. Update the version information only immediately before a public release.
  36 dnl    More frequent updates are unnecessary, and only guarantee that the current
  37 dnl    interface number gets larger faster.
  38 dnl 3. If the library source code has changed at all since the last update, then increment
  39 dnl    revision (`c:r:a' becomes `c:r+1:a').
  40 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  41 dnl    increment current, and set revision to 0.
  42 dnl 5. If any interfaces have been added since the last public release, then increment age.
  43 dnl 6. If any interfaces have been removed since the last public release, then set age
  44 dnl    to 0.
  45 LIBGLABELS_C=5
  46 LIBGLABELS_R=1
  47 LIBGLABELS_A=0
  48
  49 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  50 AC_SUBST(LIBGLABELS_VERSION_INFO)
  51
  52
  53 dnl ---------------------------------------------------------------------------
  54 dnl - Library dependencies
  55 dnl ---------------------------------------------------------------------------
  56 GLIB_REQUIRED=2.18.0
  57 GTK_REQUIRED=2.14.0
  58 LIBXML_REQUIRED=2.7.0
  59 LIBEBOOK_REQUIRED=2.24.0
  60
  61 dnl Make above strings available for packaging files (e.g. rpm spec files)
  62 AC_SUBST(GLIB_REQUIRED)
  63 AC_SUBST(GTK_REQUIRED)
  64 AC_SUBST(LIBXML_REQUIRED)
  65 AC_SUBST(LIBEBOOK_REQUIRED)
  66
  67
  68 dnl ---------------------------------------------------------------------------
  69 dnl - Check for evolution data server
  70 dnl ---------------------------------------------------------------------------
  71 AC_ARG_WITH(libebook,
  72             [AC_HELP_STRING([--without-libebook],
  73                             [build without Evolution Data Server support])])
  74 have_libebook=no
  75 if test "x$with_libebook" != xno; then
  76         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  77                           [have_libebook=yes], [have_libebook=no])
  78 fi
  79
  80 if test "x$have_libebook" = "xyes"; then
  81         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  82         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  83 fi
  84
  85
  86 dnl ---------------------------------------------------------------------------
  87 dnl - GLABELS prerequisites
  88 dnl ---------------------------------------------------------------------------
  89 PKG_CHECK_MODULES(GLABELS, \
  90 glib-2.0 >= $GLIB_REQUIRED \
  91 gtk+-2.0 >= $GTK_REQUIRED \
  92 libxml-2.0 >= $LIBXML_REQUIRED \
  93 $OPTIONAL_MODULES \
  94 )
  95
  96 AC_SUBST(GLABELS_CFLAGS)
  97 AC_SUBST(GLABELS_LIBS)
  98
  99
 100 dnl ---------------------------------------------------------------------------
 101 dnl - LIBGLABELS more modest prerequisites
 102 dnl ---------------------------------------------------------------------------
 103 PKG_CHECK_MODULES(LIBGLABELS, \
 104 glib-2.0 >= $GLIB_REQUIRED \
 105 libxml-2.0 >= $LIBXML_REQUIRED \
 106 )
 107
 108 AC_SUBST(LIBGLABELS_CFLAGS)
 109 AC_SUBST(LIBGLABELS_LIBS)
 110
 111
 112 dnl ---------------------------------------------------------------------------
 113 dnl - Enable deprecation testing
 114 dnl ---------------------------------------------------------------------------
 115 AC_ARG_ENABLE(deprecations,
 116               [AC_HELP_STRING([--enable-deprecations],
 117                               [warn about deprecated usages [default=no]])],,
 118               [enable_deprecations=no])
 119
 120 if test "x$enable_deprecations" = "xyes"; then
 121    DISABLE_DEPRECATED_CFLAGS="\
 122 -DG_DISABLE_DEPRECATED \
 123 -DGDK_DISABLE_DEPRECATED \
 124 -DGTK_DISABLE_DEPRECATED \
 125 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 126 "
 127    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 128 fi
 129
 130
 131 dnl ---------------------------------------------------------------------------
 132 dnl - Is freedesktop mime dbase available?
 133 dnl ---------------------------------------------------------------------------
 134 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 135 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 136
 137 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 138 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 139
 140 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 141               [disable the update-mime-database after install [default=no]]),,
 142               enable_update_mimedb=yes)
 143 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 144
 145 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 146               [disable the update-desktop-database after install [default=no]]),,
 147               enable_update_desktopdb=yes)
 148 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 149
 150
 151 dnl ---------------------------------------------------------------------------
 152 dnl - Supported languages
 153 dnl ---------------------------------------------------------------------------
 154 GETTEXT_PACKAGE=glabels
 155 AC_SUBST(GETTEXT_PACKAGE)
 156 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 157
 158 AM_GLIB_GNU_GETTEXT
 159
 160
 161 dnl ---------------------------------------------------------------------------
 162 dnl - Makefiles, etc.
 163 dnl ---------------------------------------------------------------------------
 164 AC_OUTPUT([
 165 Makefile
 166 barcode-0.98/Makefile
 167 iec16022-0.2.1/Makefile
 168 libglabels/Makefile
 169 libglabels/libglabels.pc
 170 src/Makefile
 171 src/pixmaps/Makefile
 172 src/stock-pixmaps/Makefile
 173 data/Makefile
 174 data/templates/Makefile
 175 data/pixmaps/Makefile
 176 data/mime/Makefile
 177 data/builder/Makefile
 178 data/desktop/Makefile
 179 data/dtd/Makefile
 180 data/man/Makefile
 181 po/Makefile.in
 182 help/Makefile
 183 help/C/Makefile
 184 docs/Makefile
 185 docs/libglabels/Makefile
 186 glabels.spec
 187 ])
 188
 189
 190 dnl ---------------------------------------------------------------------------
 191 dnl - Print configuration information
 192 dnl ---------------------------------------------------------------------------
 193 echo "
 194 Configuration:
 195
 196         Package:                        ${PACKAGE}-${VERSION}:
 197         Installation prefix             ${prefix}
 198         Source code location:           ${srcdir}
 199         Compiler:                       ${CC}
 200         Evolution Data Server support:  ${have_libebook}
 201
 202 "
 203
 204 cat ${srcdir}/MESSAGE-OF-DOOM
 205